VPF::IP адрес - Форум программистов

f0nt

Дата 14.8.2004, 18:42 (ссылка)

(нет голосов)

Загрузка ...

Новичок

Профиль
Группа: Участник
Сообщений: 2
Регистрация: 14.8.2004

Репутация: нет
Всего: нет

Хочу спросить как получить текущий ip адрес и сделать таймер с проверкой находиться ли комп в онлайне?

oleg1973

Дата 14.8.2004, 19:29 (ссылка)

(нет голосов)

Загрузка ...

asm fanat

Профиль
Группа: Экс. модератор
Сообщений: 3283
Регистрация: 16.7.2003
Где: Italy

Репутация: 7
Всего: 34

1) ну к асму вопрос ну вовсе не относится
2) есть InternetGetConnectedState оно и возврашает статус соеденения

--------------------

SST 465555
icq 200-512-712

f0nt

Дата 14.8.2004, 19:58 (ссылка)

(нет голосов)

Загрузка ...

Новичок

Профиль
Группа: Участник
Сообщений: 2
Регистрация: 14.8.2004

Репутация: нет
Всего: нет

мне это на асме сделать надо!

Jin X

Дата 14.8.2004, 21:40 (ссылка)

(нет голосов)

Загрузка ...

Бывалый

Профиль
Группа: Участник
Сообщений: 157
Регистрация: 5.3.2004

Репутация: 1
Всего: 1

Делал я когда-то такую штукенцию

Код

; ml /c /coff GetIP.asm
; link /subsystem:console GetIP.obj

.586P
.MODEL Flat,StdCall
OPTION CASEMAP:NONE

INCLUDE         WINDOWS.INC
INCLUDE         KERNEL32.INC
INCLUDE         WSOCK32.INC
INCLUDELIB      KERNEL32.LIB
INCLUDELIB      WSOCK32.LIB

WS_VERSION_REQD =       101h
MAX_HNAME_LEN   =       1024

.DATA

GreetingString  db      (lGreetingString-1),'---------------------------------------------------',13,10
                db                          'IP-address determination program (written by Jin X)',13,10
                db                          '---------------------------------------------------',13,10
lGreetingString =       $-GreetingString

Error1String    db      (lError1String-1),'The 32bit Windows Socket is not responding!',7,13,10
lError1String   =       $-Error1String
Error2String    db      (lError1String-2),'Can''t get Host Name!',7,13,10
lError2String   =       $-Error2String
Error3String    db      (lError1String-3),'Can''t get Host information!',7,13,10
lError3String   =       $-Error3String

HeaderString    db      0,13,10,'Current IP: '
IPString        label   byte

HostNameString  db      100,' Host Name: '
WSA             WSADATA <?>
ORG WSA
HostName        db      MAX_HNAME_LEN dup (?)
Result          dd      ?

.CODE


Start:

                cld

                mov     esi,offset GreetingString
                call    WriteString

                invoke  WSAStartup, WS_VERSION_REQD, addr WSA
                mov     esi,offset Error1String
                cmp     eax,ERROR_SUCCESS
                jne     Error

                invoke  gethostname, addr HostName, MAX_HNAME_LEN
                mov     esi,offset Error2String
                cmp     eax,SOCKET_ERROR
                je      Error

                mov     edi,offset HostName
                xor     al,al
                mov     ecx,MAX_HNAME_LEN
                repne   scasb
                mov     esi,offset HostNameString
                xchg    eax,edi
                sub     eax,esi
                dec     eax
                dec     eax
                mov     HostNameString,al
                call    WriteString

                invoke  gethostbyname, addr HostName
                mov     esi,offset Error3String
                or      eax,eax
                jz      Error

                movzx   ecx,[eax+hostent.h_len]
                mov     esi,[eax+hostent.h_list]
                mov     esi,[esi]
                mov     edi,offset IPString
@@NextDigit:
                lodsb
                aam
                mov     bl,al
                mov     al,ah
                aam                   ; AH:AL:BL
                or      ah,ah
                jz      @@NoFirst
                xchg    al,ah
                add     al,'0'
                stosb
                xchg    al,ah
@@NoFirst:      or      al,al
                jz      @@NoSecond
                add     al,'0'
                stosb
@@NoSecond:     mov     al,bl
                add     al,'0'
                stosb
                mov     al,'.'
                stosb
                loop    @@NextDigit

                dec     edi
                mov     ax,0A0Dh
                stosw

                mov     esi,offset HeaderString
                xchg    eax,edi
                sub     eax,esi
                dec     eax
                mov     [esi],al

Error:
                call    WriteString

                invoke  WSACleanup

                invoke  ExitProcess, NULL

WriteString     proc
                lodsb
                movzx   ecx,al
                invoke  GetStdHandle, STD_ERROR_HANDLE
                invoke  WriteConsole, eax, esi, ecx, addr Result, 0
                ret
WriteString     endp

END             Start

--------------------

Бойся своей мечты, ибо она осуществима!

0 Пользователей читают эту тему (0 Гостей и 0 Скрытых Пользователей)
0 Пользователей:
« Предыдущая тема \| Asm: Общие вопросы \| Следующая тема »