VPF::Передача текста другой программе WM_COPYDATA

Attack

Дата 11.5.2010, 19:20 (ссылка)

(нет голосов)

Загрузка ...

Новичок

Профиль
Группа: Участник
Сообщений: 45
Регистрация: 20.7.2006

Репутация: нет
Всего: нет

Хочу передать текстовую строку из одной программы в другую.
Отправляю так:

Код


var
     aCopyData: TCopyDataStruct;
     hTargetWnd: HWND;
begin
     with aCopyData do
     begin
          dwData := 0;
          cbData := StrLen(PChar(Memo1.Text)) + 1;
          lpData := PChar(Memo1.Text);
     end;
     hTargetWnd := FindWindow(PChar('TSpecialClass'), nil);
     if hTargetWnd <> 0 then
          SendMessage(hTargetWnd, WM_COPYDATA, Longint(Handle), Longint(@aCopyData))
     else
          ShowMessage('No Recipient found!');
end;

Получаю так:

Код


...
type
     TSpecialClass = class(TForm)
          RichEdit1: TRichEdit;
     private
          { Private declarations }
          procedure WMCopyData(var Msg: TWMCopyData); message WM_COPYDATA;
     public
          { Public declarations }
     end;
...

procedure TSpecialClass.WMCopyData(var Msg: TWMCopyData);
var
     sText: array [0 .. 99] of Char;
begin
     StrLCopy(sText, Msg.CopyDataStruct.lpData, Msg.CopyDataStruct.cbData);

     RichEdit1.Lines.Add(sText);
end;

И тут проблема - строка передаётся не полностью.
Пример:
Посылаю - "123456789ТестоваяСтрока!",
приходит - "123456789Тꄵꭓ珤"

Что я делаю не так, и как правильно получать текст?

Delphi 2010
Win7 x64

Решение:
Ответ подсказали на другом форуме, спасибо arj99.

Код


procedure TSpecialClass.SendClick(Sender: TObject);
var
  CopyData: TCopyDataStruct;
  hTargetWnd: HWND;
  MemoText: string;
begin
  MemoText := Memo1.Text;
  with CopyData do
  begin
    dwData := 0;
    cbData := Length(MemoText) * sizeof(Char);
    lpData := PChar(MemoText);
  end;
  hTargetWnd := FindWindow(PChar('TSpecialClass'), nil);
  if (hTargetWnd <> 0) then
    SendMessage(hTargetWnd, WM_COPYDATA, Longint(Handle), Longint(@CopyData))
  else
    ShowMessage('No Recipient found!');
end;

procedure TSpecialClass.WMCopyData(var Msg: TWMCopyData);
var
  ReceivedText: string;
begin
  SetLength(ReceivedText, Msg.CopyDataStruct.cbData div 2);
  Move(Msg.CopyDataStruct.lpData^, PChar(ReceivedText)^, Msg.CopyDataStruct.cbData and (not 1));
  RichEdit1.Text := ReceivedText;
end;

Это сообщение отредактировал(а) Attack - 12.5.2010, 12:55

0 Пользователей читают эту тему (0 Гостей и 0 Скрытых Пользователей)
0 Пользователей:
« Предыдущая тема \| Delphi: WinAPI и системное программирование \| Следующая тема »