VPF::Вторая копия программы и данные из файла

MacTep

Дата 9.2.2006, 10:55 (ссылка)

(нет голосов)

Загрузка ...

Эксперт

Профиль
Группа: Завсегдатай
Сообщений: 1292
Регистрация: 4.8.2003
Где: г. Самара

Репутация: 4
Всего: 4

Программа работает из трея. С этой программой я ассоциировал свой тип файла. Если программа в данный момент не загружена, то двойным щелчком по данному файлу я открываю программу и работаю с ней и теми данными, которые есть в этом файле. Но что делать, если программа уже запущена и мне не нужно запускать ее второй раз. Я использую мьютексы для того, чтобы блокировать вторую копию программы. Но как мне сделать, чтобы уже запущенной первой копии программы была известна информация из ассоциированного файла?

Код OnCreate главной формы программы:

Код

procedure TForm1.FormCreate(Sender: TObject);
var hMutex: THandle;
    reg:TRegistry;
    f:textfile;
    s:string;
begin
 hMutex:=CreateMutex(nil, False, MUTEX_NAME);
 if GetLastError = ERROR_ALREADY_EXISTS then
   begin
     // если вторая копия программы запущена, то что?????
   end
 else
   begin
     // какие -либо действия
     if ParamCount>0 then
       begin
         // какие - либо действия с данными из файла       
       end;
   end;
end;

--------------------

(A)bort, (R)etry, (I)gnore = Haфиг, Heфиг, Пoфиг ... :)

sexton

Дата 9.2.2006, 11:32 (ссылка)

(нет голосов)

Загрузка ...

sexton=Пономарь (eng)

Профиль
Группа: Участник
Сообщений: 503
Регистрация: 5.5.2004
Где: Ульяновск

Репутация: 1
Всего: 9

Оригинальная задача... может сделать некое подобие autoexec, чтобы при запуске программы по щелчку, данные копировались в файл, из которого программа будет читать данные по умолчанию при каждом запуске.

--------------------

Поставить +

ЖЖ
Рассылка Рассылок

Snowy

Дата 9.2.2006, 11:42 (ссылка)

(нет голосов)

Загрузка ...

Эксперт

Профиль
Группа: Модератор
Сообщений: 11363
Регистрация: 13.10.2004
Где: Питер

Репутация: 192
Всего: 484

Найди копию программы по FindWindow и отправь ей WM_COPYDATA, а в нем путь к файлу.

MacTep

Дата 9.2.2006, 14:35 (ссылка)

(нет голосов)

Загрузка ...

Эксперт

Профиль
Группа: Завсегдатай
Сообщений: 1292
Регистрация: 4.8.2003
Где: г. Самара

Репутация: 4
Всего: 4

Цитата(Snowy @ 9.2.2006, 11:42

)

отправь ей WM_COPYDATA, а в нем путь к файлу

Можно небольшой пример по этому делу, а то что-то недогоню никак...

--------------------

(A)bort, (R)etry, (I)gnore = Haфиг, Heфиг, Пoфиг ... :)

Rennigth

Дата 9.2.2006, 15:37 (ссылка)

(нет голосов)

Загрузка ...

Эксперт

Профиль
Группа: Участник Клуба
Сообщений: 1708
Регистрация: 21.6.2004
Где: Moscow

Репутация: 49
Всего: 76

Цитата(MacTep @ 9.2.2006, 14:35

)

Можно небольшой пример по этому делу, а то что-то недогоню никак...

Поиск по форуму, довольно часто проскакивали темы по WM_COPYDATA.

--------------------

(* Honesta mors turpi vita potior *)

MacTep

Дата 10.2.2006, 00:04 (ссылка)

(нет голосов)

Загрузка ...

Эксперт

Профиль
Группа: Завсегдатай
Сообщений: 1292
Регистрация: 4.8.2003
Где: г. Самара

Репутация: 4
Всего: 4

Нашел в темах форума следующее:

Код


var
cds:TCopyDataStruct;
begin
//Любое 32-х битное число
cds.dwData:=10;
//Количество передаваемых байт
cds.cbData:=len;
//Указатель на данные
cds.lpData:=@buf;
//Посылаешь сообщение нужному окну, wParam - хендл посылающего окна, lParam - указатель на структуру с данными
SendMessage(FindWindow('TForm2',nil), WM_COPYDATA, Handle, Integer(@cds));
end;

Только все равно понятного мало. Говорят, что SendMessage отправляет только числа, а не текст. Второе, не могу понять, что такое dwData, cbData, lpData, какие нужно данные туда подставить? Все равно было бы классно примерчик увидеть...
Добавлено @ 00:07
И еще нашел следующее:

Цитата

сообщение WM_COPYDATA, чрезвычайно удобное дл пересылки блоков данных из одной программы в другую

. А мне же не нужно из программы в программу посылать. Мне нужно в одной программе все провернуть. Или я не догоняю? Разъясните непонятливому...

--------------------

(A)bort, (R)etry, (I)gnore = Haфиг, Heфиг, Пoфиг ... :)

Snowy

Дата 10.2.2006, 00:20 (ссылка)

(нет голосов)

Загрузка ...

Эксперт

Профиль
Группа: Модератор
Сообщений: 11363
Регистрация: 13.10.2004
Где: Питер

Репутация: 192
Всего: 484

Цитата(MacTep @ 10.2.2006, 00:04

)

Говорят, что SendMessage отправляет только числа, а не текст.

Передает абсолютно любые данные.

Цитата(MacTep @ 10.2.2006, 00:04

)

Все равно было бы классно примерчик увидеть...

Это и есть пример.

Цитата(MacTep @ 10.2.2006, 00:04

)

А мне же не нужно из программы в программу посылать. Мне нужно в одной программе все провернуть. Или я не догоняю?

Если говорить более точно, то это сообщение передает данные между разными процессами. Две копии твоей программы это 2 разных процесса.

Вот этот пример со строкой.

Код


var    
  cds:TCopyDataStruct;
  s: string;
begin    
  s := 'Это строка, которую мы отправляем';
  //Любое 32-х битное число    
  cds.dwData:=10;
  //Количество передаваемых байт    
  cds.cbData:=Length(s);
  //Указатель на данные    
  cds.lpData:=pointer(s);    
  //Посылаешь сообщение нужному окну, wParam - хендл посылающего окна, lParam - указатель на структуру с данными    
  SendMessage(FindWindow('TForm2',nil), WM_COPYDATA, Handle, Integer(@cds));    
end;

MacTep

Дата 10.2.2006, 00:41 (ссылка)

(нет голосов)

Загрузка ...

Эксперт

Профиль
Группа: Завсегдатай
Сообщений: 1292
Регистрация: 4.8.2003
Где: г. Самара

Репутация: 4
Всего: 4

А что это за dwData и почему в примере стоит именно 10? smile

И последнее... После того, как я передал сообщение, я могу закрыть вторую копию и принять сообщение в первой копии, так? То есть код моей программы будет включать как функцию для отправки сообщения, так и для его принятия? А как принять данное сообщение посланное мне?

--------------------

(A)bort, (R)etry, (I)gnore = Haфиг, Heфиг, Пoфиг ... :)

Snowy

Дата 10.2.2006, 00:49 (ссылка)

(нет голосов)

Загрузка ...

Эксперт

Профиль
Группа: Модератор
Сообщений: 11363
Регистрация: 13.10.2004
Где: Питер

Репутация: 192
Всего: 484

Цитата(MacTep @ 10.2.2006, 00:41

)

А что это за dwData и почему в примере стоит именно 10?

Там же написано - любое 32-битное число.
Можешь вообще в него ничего не писать.
Сделано на случай, если ты будешь посылать разные данные.
Тогда ты сможешь различать их по данному числу.
Но в твоем случае данные только одни - строка с именем файла.
Так что тебе оно не нужно. Хотя для надежности можешь все же вставить проверку - вдруг это другая программа отправила тебе это сообщение по ошибке. По своему числу сможешь отличить свое от не своего.

Цитата(MacTep @ 10.2.2006, 00:41

)

После того, как я передал сообщение, я могу закрыть вторую копию и принять сообщение в первой копии, так?

Примерно так. Только порядок немного другой. Ты отправляешь сообщение, первая копия его принимает и потом уже вторая завершается. Но это не так важно. Порядок действий для тебя тот же.

Цитата(MacTep @ 10.2.2006, 00:41

)

То есть код моей программы будет включать как функцию для отправки сообщения, так и для его принятия?

Сходи в топик, из которого ты взял этот пример. Там же написано как это сообщение ловить.

MacTep

Дата 10.2.2006, 01:06 (ссылка)

(нет голосов)

Загрузка ...

Эксперт

Профиль
Группа: Завсегдатай
Сообщений: 1292
Регистрация: 4.8.2003
Где: г. Самара

Репутация: 4
Всего: 4

Спасибо, за терпение к глупым вопросам повышаю репутацию! smile

--------------------

(A)bort, (R)etry, (I)gnore = Haфиг, Heфиг, Пoфиг ... :)

MacTep

Дата 10.2.2006, 13:55 (ссылка)

(нет голосов)

Загрузка ...

Эксперт

Профиль
Группа: Завсегдатай
Сообщений: 1292
Регистрация: 4.8.2003
Где: г. Самара

Репутация: 4
Всего: 4

Не знаю, парни, или я такой или лыжи такие странные! smile

Не получается у меня почти ничего. Вот код.

Код

type
  TForm1 = class(TForm)
    ...
  private
    { Private declarations }
    procedure CopyData(var Msg:TWMCopyData); message WM_COPYDATA;
  public
    { Public declarations }
  end;
// Действия, выполняемые при запуске приложения
procedure TForm1.FormCreate(Sender: TObject);
var hMutex: THandle;
    t:integer;
    cds:TCopyDataStruct;
begin
 hMutex:=CreateMutex(nil, False, MUTEX_NAME);
 if GetLastError = ERROR_ALREADY_EXISTS then
   begin
     // берем имя файла из командной строки
     if ParamCount>0 then
       begin
         s:=ParamStr(1);
         //Любое 32-х битное число для распознавания своего сообщения WM_COPYDATA
         cds.dwData:=10;
         //Количество передаваемых байт
         cds.cbData:=Length(s);
         //Указатель на данные
         cds.lpData:=pointer(s);
         //Посылаем сообщение нужному окну
         //wParam - хендл посылающего окна
         //lParam - указатель на структуру с данными
         SendMessage(FindWindow('TForm1',nil),WM_COPYDATA,Handle,Integer(@cds));
       end;
     Halt;
   end
 else
   begin
     // ...
   end;
end;

procedure TForm1.CopyData(var Msg:TWMCopyData);
var cds:PCopyDataStruct;
    f:textfile;
    s:string;
begin
  cds:=Msg.CopyDataStruct;
  // записываем данные из файла в ListBox
  AssignFile(f,PChar(cds.lpData));
  Reset(f);
  ListBox1.Clear;
  FileNames.Clear;
  while not eof(f) do
    begin
      readln(f,s);
      ListBox1.Items.Add(s);
    end;
  CloseFile(f);
end;

Так вот беда в чем: вроде бы как данные передаются. Но если в первой процедурке строчку "Halt;" закомментировать, то вторая копия приложения не завершит свою работу. Так вот при этом происходит, что все действия, которые выполняются во второй процедуре, выполняются именно со второй копией приложения, а не с первой. Как сделать так, чтобы данные действия были применимы только лишь к первой инстанции приложения??? Уже из сил выбился. Кучу информации перечитал, а так ничего ин е добился... smile

Это сообщение отредактировал(а) MacTep - 10.2.2006, 13:58

--------------------

(A)bort, (R)etry, (I)gnore = Haфиг, Heфиг, Пoфиг ... :)

Snowy

Дата 10.2.2006, 14:29 (ссылка)

(нет голосов)

Загрузка ...

Эксперт

Профиль
Группа: Модератор
Сообщений: 11363
Регистрация: 13.10.2004
Где: Питер

Репутация: 192
Всего: 484

Код

program Project1;

uses
  Forms, Windows, Messages,
  Unit1 in 'Unit1.pas' {CoolForm54};

{$R *.res}

function AppExist: boolean;
var
  wnd: HWND;
  cd:  TCopyDataStruct;
  s:   string;
begin
  wnd := FindWindow('TCoolForm54',nil);
  if wnd <> 0 then begin
    result := true;
    if ParamCount = 0 then Exit;
    s := ParamStr(1);
    cd.dwData := $BEBE;
    cd.cbData := Length(s);
    cd.lpData := pointer(s);
    SendMessage(wnd, WM_COPYDATA, 0, Integer(@cd));
  end else result := false;
end;

begin
  if AppExist then Exit;
  Application.Initialize;
  Application.CreateForm(TCoolForm54, CoolForm54);
  Application.Run;
end.

Код

unit Unit1;

interface

uses
  Windows, Messages, SysUtils, Variants, Classes, Graphics, Controls, Forms,
  Dialogs;

type
  TCoolForm54 = class(TForm)
  private
    procedure CopyData(var Msg:TWMCopyData); message WM_COPYDATA;
  public
    { Public declarations }
  end;

var
  CoolForm54: TCoolForm54;

implementation

{$R *.dfm}

procedure TCoolForm54.CopyData(var Msg:TWMCopyData);
var
  s: string;
begin
  SetLength(s, Msg.CopyDataStruct.cbData);
  move(pointer(Msg.CopyDataStruct.lpData)^, s[1], Length(s));
  SetForegroundWindow(Handle);
  if Msg.CopyDataStruct.dwData = $BEBE then
    ShowMessage(s);
end;

end.

Добавлено @ 14:31
Вот пример программы, которая ищет себя запущенную.
Если находит, то отправляет себе ParamStr(1) и умирает.
Если не находит - запускается.
Обрати внимание, что у Form1 Name оставлен не стандартный, а сделан уникальным, чтобы не перепутать себя с другими.
В примере я просто сделал вывод полученной строки в ShowMessage.
Замени на любой свой код и все.

MacTep

Дата 10.2.2006, 14:47 (ссылка)

(нет голосов)

Загрузка ...

Эксперт

Профиль
Группа: Завсегдатай
Сообщений: 1292
Регистрация: 4.8.2003
Где: г. Самара

Репутация: 4
Всего: 4

А вот теперь действительно все... smile

Получилось. Оказывается, действительно нужно было имя формы сделать уникальным. И мьютексы использовать вовсе не обязательно было. Метод Snowy мне понравился больше, мне кажется он более красивым. Спасибо всем за обсуждение и помощь!

Это сообщение отредактировал(а) MacTep - 11.5.2006, 21:09

--------------------

(A)bort, (R)etry, (I)gnore = Haфиг, Heфиг, Пoфиг ... :)

MacTep

Дата 11.5.2006, 21:12 (ссылка)

(нет голосов)

Загрузка ...

Эксперт

Профиль
Группа: Завсегдатай
Сообщений: 1292
Регистрация: 4.8.2003
Где: г. Самара

Репутация: 4
Всего: 4

Еще одна проблема с этим вопросом. Все отлично работает, если запускать программу при помощи ассоциированного с ней файла. Но если просто запустить программу из экзехи, потом второй раз, потом третий, то будут созданы и второй и третий и т.д. экземпляры программы. Как нужно изменить процедурку AppExist, чтобы она даже при таком запуске позволяла запустить программу только 1 раз?

--------------------

(A)bort, (R)etry, (I)gnore = Haфиг, Heфиг, Пoфиг ... :)

Демо

Дата 12.5.2006, 08:45 (ссылка)

(нет голосов)

Загрузка ...

Эксперт

Профиль
Группа: Завсегдатай
Сообщений: 1278
Регистрация: 3.11.2005

Репутация: 30
Всего: 50

MacTep,
Неправильно искать второй экземпляр по имени окна.
В топике было праильное решение - использовать мьютекс.

Код


 if GetLastError = ERROR_ALREADY_EXISTS then    
   begin    
     // если вторая копия программы запущена, то что?????    
   end

Вместо комментариев - либо Exit, либо Halt.

Но у тебя 2 задачи. КРоме того, чтобы не допустить второго запуска программы, тебе надо еще и передать параметры уже запущенной копии.

Для этого проще воспользоваться MMF - Memory Mapped File.
Запущенное приложение первым делом создает MMF, записывает туда нужную информаци, например - дескриптор окна, которому можно посылать сообщения, параметры пли запуске, и вообще любую информацию.

При запуске второй копии приложение также пытается создать MMF, но, так как MMF уже существует, просто открывает его, записывает нужную информацию и посылает сообщение первой копии.

--------------------

MacTep

Дата 12.5.2006, 11:19 (ссылка)

(нет голосов)

Загрузка ...

Эксперт

Профиль
Группа: Завсегдатай
Сообщений: 1292
Регистрация: 4.8.2003
Где: г. Самара

Репутация: 4
Всего: 4

Цитата(Демо @ 12.5.2006, 08:45

)

Для этого проще воспользоваться MMF - Memory Mapped File.

Примерчик можно? Первый раз слышу о MMF.

Это сообщение отредактировал(а) MacTep - 13.5.2006, 20:06

--------------------

(A)bort, (R)etry, (I)gnore = Haфиг, Heфиг, Пoфиг ... :)

MacTep

Дата 13.5.2006, 20:24 (ссылка)

(нет голосов)

Загрузка ...

Эксперт

Профиль
Группа: Завсегдатай
Сообщений: 1292
Регистрация: 4.8.2003
Где: г. Самара

Репутация: 4
Всего: 4

А вот еще вопрос такой: обязательно что ли использовать WM_COPYDATA. Просто не получится разве при помощи ParamStr(1)?

--------------------

(A)bort, (R)etry, (I)gnore = Haфиг, Heфиг, Пoфиг ... :)

Демо

Дата 14.5.2006, 16:31 (ссылка)

(нет голосов)

Загрузка ...

Эксперт

Профиль
Группа: Завсегдатай
Сообщений: 1278
Регистрация: 3.11.2005

Репутация: 30
Всего: 50

Цитата(MacTep @ 12.5.2006, 11:19

)

Примерчик можно? Первый раз слышу о MMF.

Вот простенький пример, очень схематично и упрощенно, но для демонстрации подойдет:

unit

Код


Unit1;

interface

uses
  Windows, Messages, SysUtils, Variants, Classes, Graphics, Controls, Forms,
  Dialogs, StdCtrls;

type
  TForm1 = class(TForm)
    Button1: TButton;
    Button2: TButton;
    procedure Button2Click(Sender: TObject);
    procedure Button1Click(Sender: TObject);
  private
    { Private declarations }
  public
    procedure OnWM_USER1(var Message: TMessage); message WM_USER+1;
    { Public declarations }
  end;

var
  Form1: TForm1;
  HM: THandle;
  PM: PChar;

implementation

{$R *.dfm}

procedure TForm1.Button1Click(Sender: TObject);
var
  H: THandle;
  GL: Cardinal;
  isDump: Boolean;
  s: String;
begin
  isDump := False;
  HM := CreateFileMapping(0,nil,PAGE_READWRITE,0,100,'MMF1');
  GL := GetLastError;
  if HM=0 then
  begin
    ShowMessage(SysErrorMessage(GL));
    Exit;
  end;

  if GL=ERROR_ALREADY_EXISTS then isDump := True;

  PM := MapViewOfFile(HM,FILE_MAP_ALL_ACCESS,0,0,100);
  if PM=nil then
  begin
    ShowMessage(SysErrorMessage(GetLastError));
    CloseHandle(HM);
    Exit;
  end;
  if not isDump then
  begin
    H := Form1.Handle;
    Move(H,PM[0],SizeOf(THandle));
    s := 'Сообщение для передачи(Первая копия)';
    GL := Length(s);
    Move(GL,PM[SizeOf(THandle)],SizeOf(Cardinal));
    Move(s[1],PM[SizeOf(THandle)+SizeOf(Cardinal)],GL);
  end
  else
  begin
    s := 'Сообщение для передачи(Вторая копия)';
    Move(PM[0],H,SizeOf(THandle));
    GL := Length(s);
    Move(GL,PM[SizeOf(THandle)],SizeOf(Cardinal));
    Move(s[1],PM[SizeOf(THandle)+SizeOf(Cardinal)],GL);
    SendMessage(H,WM_USER+1,0,0);
    Application.Terminate;
  end;
end;

procedure TForm1.Button2Click(Sender: TObject);
begin
  UnMapViewOfFile(PM);
  CloseHandle(HM);
end;

procedure TForm1.OnWM_USER1(var Message: TMessage);
var
  s: String;
  Len: Cardinal;
begin
  Move(PM[SizeOf(THandle)],Len,SizeOf(Cardinal));
  SetLength(s,Len);
  Move(PM[SizeOf(THandle)+SizeOf(Cardinal)],s[1],Len);
  ShowMessage('Приложение уже запущено. Получено сообщение - '+s);
end;

end.

Это сообщение отредактировал(а) Демо - 14.5.2006, 16:33

--------------------

1 Пользователей читают эту тему (1 Гостей и 0 Скрытых Пользователей)
0 Пользователей:
« Предыдущая тема \| Delphi: Общие вопросы \| Следующая тема »