VPF::Снова про PrintScreen - Форум программистов

ИгнатьевАлексей

Дата 27.10.2006, 14:16 (ссылка)

(нет голосов)

Загрузка ...

Опытный

Профиль
Группа: Участник
Сообщений: 369
Регистрация: 18.11.2005

Репутация: нет
Всего: 3

Друзья! Помогите, плиз!
Вот пытаюсь модифицировать код, который взял с нашего замечательного форума.
Мне хотелось бы, чтобы прога сохраняла в .bmp активное окно, и чтобы прога не имела своего окна, т.е. только MainSub().
Вот беру код

Код


Option Explicit

Private Declare Function GetDesktopWindow Lib "user32" () As Long
Private Declare Function GetDC Lib "user32" (ByVal hwnd As Long) As Long
Private Declare Function DeleteDC Lib "gdi32" (ByVal hdc As Long) As Long
Private Declare Function BitBlt Lib "gdi32" _
    (ByVal hDestDC As Long, ByVal x As Long, _
    ByVal y As Long, ByVal nWidth As Long, _
    ByVal nHeight As Long, ByVal hSrcDC As Long, _
    ByVal xSrc As Long, ByVal ySrc As Long, ByVal dwRop As Long) As Long
Private Declare Function GetForegroundWindow Lib "user32" () As Long
Private Declare Function GetWindowRect Lib "user32" (ByVal hwnd As Long, _
                                          lpRect As RECT) As Long
Private Type RECT
        Left As Long
        Top As Long
        Right As Long
        Bottom As Long
End Type


Private Sub ScreenShot()
    Dim hDesk&, hDeskDC&, pNew As IPicture, myRect As RECT
    'hDesk = GetDesktopWindow
    hDesk = GetForegroundWindow
    hDeskDC = GetDC(hDesk)
    Set pNew = Me.Image
   
    GetWindowRect hDesk, myRect
    'BitBlt pNew.CurDC, 0, 0, 1024, 768, hDeskDC, 0, 0, vbSrcCopy
    BitBlt pNew.CurDC, myRect.Left, _
                       myRect.Top, _
                       myRect.Right - myRect.Left, _
                       myRect.Bottom - myRect.Top, _
                                 hDeskDC, 0, 0, vbSrcCopy
    SavePicture pNew, "C:\Screen.bmp"
    DeleteDC hDeskDC
    Set pNew = Nothing
End Sub

Private Sub Command1_Click()
  ScreenShot
End Sub

И пытаюсь для начала его оформить в MainSub(). Получаю проблему в строке

Код


Set pNew = Me.Image

Подскажите, пожалуйста, как можно обойти эту операцию. Что можно указать вместо Me?

Заранее благодарен!

--------------------

Vingrad - FOREVER !!!

"Как вы яхту назовете - так она и поплывет!"
Капитан Врунгель

Naghual

Дата 27.10.2006, 15:05 (ссылка)

(нет голосов)

Загрузка ...

Эксперт

Профиль
Группа: Завсегдатай
Сообщений: 1893
Регистрация: 15.5.2004
Где: Украина, Днепр

Репутация: 26
Всего: 49

чтобы сильно не заморачиватся - создай форму, загружай ее в память (но не показывай), рисуй на ней объект Image.
вот этот и используй

--------------------

Я желаю всем Счастья!

ИгнатьевАлексей

Дата 27.10.2006, 15:28 (ссылка)

(нет голосов)

Загрузка ...

Опытный

Профиль
Группа: Участник
Сообщений: 369
Регистрация: 18.11.2005

Репутация: нет
Всего: 3

Спасибо за ответ! Именно это я и предполагал, ну ладно! Форма эта мешать особо не будет!
А можно еще вопрос, да простит меня модератор за это!
Как можно "обрезать" получившуюся картинку?
После строки с функцией BitBlt я получаю почти то, что нужно, но нужное мне (активное) окно как правило меньше, чем дектоп, и я получаю ненужную часть серого цвета. Можно ли убрать его?
Заранее благодарен!

--------------------

Vingrad - FOREVER !!!

"Как вы яхту назовете - так она и поплывет!"
Капитан Врунгель

mihanik

Дата 27.10.2006, 15:46 (ссылка)

(нет голосов)

Загрузка ...

-=Белый Медведь=-

Профиль
Группа: Комодератор
Сообщений: 4054
Регистрация: 24.4.2006
Где: г. Тверь

Репутация: 11
Всего: 109

Зачем так сложно?

Вот. У меня всё работает...

Код


Option Explicit

Public Declare Sub keybd_event Lib "user32" (ByVal bVk As Byte, ByVal bScan As Byte, ByVal dwFlags As Long, ByVal dwExtraInfo As Long)

Private Sub Main()
Dim Pict As IPictureDisp
    
    ' эмитируем нажатие клавиши "PrintScreen"
    keybd_event 44, 69, &H1, 0
    
    ' Помещаем всё, что лежит в буфере обмена в переменную Pict
    Set Pict = Clipboard.GetData
    
    ' Сохраняем всё в нужный файл
    SavePicture Pict, "C:\111.bmp"
    
End Sub

Добавлено @ 15:55
А для того, чтобы "сфотографировать" только активное окно необходимо послать не {PrintScreen},
а {ALT}+{PrintScreen}

--------------------

Программистами не рождаются, - это родовая травма...

ИгнатьевАлексей

Дата 27.10.2006, 15:59 (ссылка)

(нет голосов)

Загрузка ...

Опытный

Профиль
Группа: Участник
Сообщений: 369
Регистрация: 18.11.2005

Репутация: нет
Всего: 3

Спасибо, дорогой mihanik, но дело в том, что на данном компе (Винда 2000) почему-то не работает Clipboard.GetData. "Не могу мол сделать это" - комп говорит! В буфер инфу забирает - я проверял, а GetData сделать не может!
Может кто знает, почему такое может быть?
На этом компе установлен специальный софт. Это вообще операторская станция. Подозреваю, что при установке софта что-то обрезается! Бывает такое?
Вот, mihanik, я и ищу другие пути!
А вот вышеуказанный код работает, да вот подправить кое что надо и не получается...

Это сообщение отредактировал(а) ИгнатьевАлексей - 27.10.2006, 16:00

--------------------

Vingrad - FOREVER !!!

"Как вы яхту назовете - так она и поплывет!"
Капитан Врунгель

mihanik

Дата 27.10.2006, 16:21 (ссылка)

(нет голосов)

Загрузка ...

-=Белый Медведь=-

Профиль
Группа: Комодератор
Сообщений: 4054
Регистрация: 24.4.2006
Где: г. Тверь

Репутация: 11
Всего: 109

Попробуй вот так...

Код


Option Explicit

Public Declare Sub keybd_event Lib "user32" (ByVal bVk As Byte, ByVal bScan As Byte, ByVal dwFlags As Long, ByVal dwExtraInfo As Long)

Private Sub Main()
Dim Pict As IPictureDisp
    
    ' эмитируем нажатие клавиши "PrintScreen"
    keybd_event 44, 69, &H1, 0
    
    ' Помещаем всё, что лежит в буфере обмена в переменную Pict
    Set Pict = Clipboard.GetData (vbCFBitmap )
    
    ' Сохраняем всё в нужный файл
    SavePicture Pict, "C:\111.bmp"
    
End Sub

--------------------

Программистами не рождаются, - это родовая травма...

Naghual

Дата 27.10.2006, 16:33 (ссылка)

(нет голосов)

Загрузка ...

Эксперт

Профиль
Группа: Завсегдатай
Сообщений: 1893
Регистрация: 15.5.2004
Где: Украина, Днепр

Репутация: 26
Всего: 49

Вы изначально получаете контекст Десктопа, а нужно Активного Окна.
Т.е. Апи GetDC нужно заменить на GetCurrentWindowDC (или как-то подобно, не помню)

--------------------

Я желаю всем Счастья!

ИгнатьевАлексей

Дата 27.10.2006, 17:08 (ссылка)

(нет голосов)

Загрузка ...

Опытный

Профиль
Группа: Участник
Сообщений: 369
Регистрация: 18.11.2005

Репутация: нет
Всего: 3

mihanik, я делал так

Код


Private Sub Command1_Click()
On Error Resume Next
Clipboard.Clear
DoEvents
keybd_event NIM_ALT, 0, 0, 0
keybd_event VK_SNAPSHOT, 0, 0, 0
keybd_event NIM_ALT, 0, KEYEVENTF_KEYUP, 0
DoEvents
SavePicture Clipboard.GetData(vbCFBitmap), "C:\SCRIN_TEST.bmp"
Clipboard.Clear
End Sub

Но попробую и по-твоему в скором времени. Спасибо!

Naghual, Спасибо! Попробую завтра!

--------------------

Vingrad - FOREVER !!!

"Как вы яхту назовете - так она и поплывет!"
Капитан Врунгель

mihanik

Дата 27.10.2006, 19:06 (ссылка)

(нет голосов)

Загрузка ...

-=Белый Медведь=-

Профиль
Группа: Комодератор
Сообщений: 4054
Регистрация: 24.4.2006
Где: г. Тверь

Репутация: 11
Всего: 109

ИгнатьевАлексей, по большому счёту - это видоизменённый мой способ. smile

Цитата(mihanik @ 27.10.2006, 15:46

)

Добавлено @ 15:55
А для того, чтобы "сфотографировать" только активное окно необходимо послать не {PrintScreen},
а {ALT}+{PrintScreen}

Что , в принципе, ты и сделал. smile

1. Прижал Альт - keybd_event NIM_ALT, 0, 0, 0
2. Нажал принтскрин - keybd_event VK_SNAPSHOT, 0, 0, 0
3. Отжал Альт - keybd_event NIM_ALT, 0, KEYEVENTF_KEYUP, 0

И, кроме того, ты не использовал промежуточную переменную.

Согласен? smile

--------------------

Программистами не рождаются, - это родовая травма...

ИгнатьевАлексей

Дата 28.10.2006, 10:47 (ссылка)

(нет голосов)

Загрузка ...

Опытный

Профиль
Группа: Участник
Сообщений: 369
Регистрация: 18.11.2005

Репутация: нет
Всего: 3

mihanik, smile

спасибо за подробное разьяснение. Я понимаю, что это "те же штаны, только наперёд гашником" smile

.
Смысл моего к тебе последнего обращения и заключался в предположении: может ли промежуточная переменная с волшебным названием Pict что то изменить?

--------------------

Vingrad - FOREVER !!!

"Как вы яхту назовете - так она и поплывет!"
Капитан Врунгель

mihanik

Дата 30.10.2006, 08:04 (ссылка)

(нет голосов)

Загрузка ...

-=Белый Медведь=-

Профиль
Группа: Комодератор
Сообщений: 4054
Регистрация: 24.4.2006
Где: г. Тверь

Репутация: 11
Всего: 109

Цитата(ИгнатьевАлексей @ 28.10.2006, 10:47

)

может ли промежуточная переменная с волшебным названием Pict что то изменить?

По-большому счёту, - нет.

Едиственное замечание.
Мой способ срабатывает на "быстрых" машинах.
На медленных же происходит вот что.

Ты "фотографируешь" экран. Т.к. машина медленная, то этот процесс должен занимать некоторое время.
В это время машина начинает пытаться сфотографированный образ экрана запихнуть в файл, что ей, естесственно, не удаётся по причине того, что образ в это время только-только формируется.

И вот тут ты правильно вставил DoEvents после команды PrintScreen.
Т.е. Щи отдельно, мухи отдельно. smile

Сначала, мол, сфотографируй, а уж потом пиши в файл.

Молодец!

(Но и я молодец, что придумал более простой способ... smile

)

--------------------

Программистами не рождаются, - это родовая травма...

ИгнатьевАлексей

Дата 31.10.2006, 14:41 (ссылка)

(нет голосов)

Загрузка ...

Опытный

Профиль
Группа: Участник
Сообщений: 369
Регистрация: 18.11.2005

Репутация: нет
Всего: 3

mihanik, мухи-то отдельно - это верно, да только код то этот не работает на нужной мне машине, вот беда!

Но тучи расступились! Я пошел в местную библиотеку и на свое удивление увидел там неплохой технический отдел с неплохой подборочкой книжек по программированию. Там нашел прекрасную книжечку про VB и VBA из серии "Для профессионалов" и на ее волшебных страницах нашел почти готовый код! Немного модификации - и счастье привалило.....

Так что всем спасибо за помощь!!!

--------------------

Vingrad - FOREVER !!!

"Как вы яхту назовете - так она и поплывет!"
Капитан Врунгель

mihanik

Дата 31.10.2006, 15:13 (ссылка)

(нет голосов)

Загрузка ...

-=Белый Медведь=-

Профиль
Группа: Комодератор
Сообщений: 4054
Регистрация: 24.4.2006
Где: г. Тверь

Репутация: 11
Всего: 109

Цитата(ИгнатьевАлексей @ 31.10.2006, 14:41

)

почти готовый код

А поделиться с коллегами! smile

--------------------

Программистами не рождаются, - это родовая травма...

ИгнатьевАлексей

Дата 1.11.2006, 11:47 (ссылка)

(нет голосов)

Загрузка ...

Опытный

Профиль
Группа: Участник
Сообщений: 369
Регистрация: 18.11.2005

Репутация: нет
Всего: 3

Нет проблем

Код


Option Explicit

Global Const INVERSE = 6
Const SOLID = 0
Const DOT = 2

Global HoldX As Single
Global HoldY As Single
Global StartX As Single
Global StartY As Single
Global SavedDrawStyle
Global SavedMode


Option Base 0

Private Type PALETTEENTRY
peRed As Byte
peGreen As Byte
peBlue As Byte
peFlags As Byte
End Type

Private Type LOGPALETTE
palVersion As Integer
palNumEntries As Integer
'Enough for 256 colors
palPalEntry(255) As PALETTEENTRY
End Type

Private Type GUID
Data1 As Long
Data2 As Integer
Data3 As Integer
Data4(7) As Byte
End Type


Private Const RASTERCAPS As Long = 38
Private Const RC_PALETTE As Long = &H100
Private Const SIZEPALETTE As Long = 104

Private Type RECT
   Left As Long
   Top As Long
   Right As Long
   Bottom As Long
End Type

Private Type PicBmp
   Size As Long
   Type As Long
   hBmp As Long
   hPal As Long
   Reserved As Long
End Type

Private Declare Function BitBlt Lib "GDI32" ( _
    ByVal hDCDest As Long, ByVal XDest As Long, _
    ByVal YDest As Long, ByVal nWidth As Long, _
    ByVal nHeight As Long, ByVal hDCSrc As Long, _
    ByVal XSrc As Long, ByVal YSrc As Long, ByVal dwRop As Long) _
    As Long
Private Declare Function CreateCompatibleBitmap Lib _
    "GDI32" (ByVal hDC As Long, ByVal nWidth As Long, _
    ByVal nHeight As Long) As Long
Private Declare Function CreateCompatibleDC Lib "GDI32" ( _
    ByVal hDC As Long) As Long
Private Declare Function CreatePalette Lib "GDI32" ( _
    lpLogPalette As LOGPALETTE) As Long
Private Declare Function DeleteDC Lib "GDI32" ( _
    ByVal hDC As Long) As Long
Private Declare Function GetDesktopWindow Lib "user32" () As Long
Private Declare Function GetDeviceCaps Lib "GDI32" ( _
    ByVal hDC As Long, ByVal iCapabilitiy As Long) As Long
Private Declare Function GetForegroundWindow Lib "user32" () _
    As Long
Private Declare Function GetSystemPaletteEntries Lib _
    "GDI32" (ByVal hDC As Long, ByVal wStartIndex As Long, _
    ByVal wNumEntries As Long, lpPaletteEntries _
    As PALETTEENTRY) As Long
Private Declare Function GetWindowDC Lib "user32" ( _
    ByVal hwnd As Long) As Long
Private Declare Function GetDC Lib "user32" ( _
    ByVal hwnd As Long) As Long
Private Declare Function GetWindowRect Lib "user32" ( _
    ByVal hwnd As Long, lpRect As RECT) As Long
Private Declare Function OleCreatePictureIndirect _
    Lib "olepro32.dll" (PicDesc As PicBmp, RefIID As GUID, _
    ByVal fPictureOwnsHandle As Long, IPic As IPicture) As Long
Private Declare Function RealizePalette Lib "GDI32" ( _
    ByVal hDC As Long) As Long
Private Declare Function ReleaseDC Lib "user32" ( _
    ByVal hwnd As Long, ByVal hDC As Long) As Long
Private Declare Function SelectObject Lib "GDI32" ( _
    ByVal hDC As Long, ByVal hObject As Long) As Long
Private Declare Function SelectPalette Lib "GDI32" ( _
    ByVal hDC As Long, ByVal hPalette As Long, _
    ByVal bForceBackground As Long) As Long
    


           
Public Function CaptureForm() As Picture
    On Error GoTo ErrorRoutineErr
    Dim frmHWnd As Long
    Dim frmSize As RECT

    frmHWnd = GetForegroundWindow
    GetWindowRect frmHWnd, frmSize
    
    Set CaptureForm = CaptureWindow(frmHWnd, 0, 0, _
       frmSize.Right - frmSize.Left, _
       frmSize.Bottom - frmSize.Top)

ErrorRoutineResume:
    Exit Function
ErrorRoutineErr:
    'MsgBox "Project1.Module1.CaptureForm" & Err & Error
    Resume Next
End Function

Public Function CaptureWindow(ByVal hWndSrc As Long, _
    ByVal LeftSrc As Long, _
    ByVal TopSrc As Long, ByVal WidthSrc As Long, _
    ByVal HeightSrc As Long) As Picture
    
    On Error GoTo ErrorRoutineErr
    
    Dim hDCMemory As Long
    Dim hBmp As Long
    Dim hBmpPrev As Long
    Dim rc As Long
    Dim hDCSrc As Long
    Dim hPal As Long
    Dim hPalPrev As Long
    Dim RasterCapsScrn As Long
    Dim HasPaletteScrn As Long
    Dim PaletteSizeScrn As Long
    
    Dim LogPal As LOGPALETTE
    
    'Get device context for the window
    hDCSrc = GetWindowDC(hWndSrc)
    
    'Create a memory device context for the copy process
    hDCMemory = CreateCompatibleDC(hDCSrc)
    'Create a bitmap and place it in the memory DC
    hBmp = CreateCompatibleBitmap(hDCSrc, WidthSrc, HeightSrc)
    hBmpPrev = SelectObject(hDCMemory, hBmp)
    
    'Get screen properties
    'Raster capabilities
    RasterCapsScrn = GetDeviceCaps(hDCSrc, RASTERCAPS)
    'Palette support
    HasPaletteScrn = RasterCapsScrn And RC_PALETTE
    'Size of palette
    PaletteSizeScrn = GetDeviceCaps(hDCSrc, SIZEPALETTE)
    
    'If the screen has a palette, make a copy
    If HasPaletteScrn And (PaletteSizeScrn = 256) Then
        'Create a copy of the system palette
        LogPal.palVersion = &H300
        LogPal.palNumEntries = 256
        rc = GetSystemPaletteEntries(hDCSrc, 0, 256, _
        LogPal.palPalEntry(0))
        hPal = CreatePalette(LogPal)
        'Select the new palette into the memory
        'DC and realize it
        hPalPrev = SelectPalette(hDCMemory, hPal, 0)
        rc = RealizePalette(hDCMemory)
    End If
    
    'Copy the image into the memory DC
    rc = BitBlt(hDCMemory, 0, 0, WidthSrc, HeightSrc, _
    hDCSrc, LeftSrc, TopSrc, vbSrcCopy)

    'Remove the new copy of the  on-screen image
    'hBmp = SelectObject(hDCMemory, hBmpPrev)
    
    'If the screen has a palette get back the palette that was
    'selected in previously
    If HasPaletteScrn And (PaletteSizeScrn = 256) Then
    hPal = SelectPalette(hDCMemory, hPalPrev, 0)
    End If
    
    'Release the device context resources back to the system
    rc = DeleteDC(hDCMemory)
    rc = ReleaseDC(hWndSrc, hDCSrc)
    
    'Call CreateBitmapPicture to create a picture
    'object from the bitmap and palette handles.
    'Then return the resulting picture object.
    Set CaptureWindow = CreateBitmapPicture(hBmp, hPal)
    
ErrorRoutineResume:
    Exit Function
ErrorRoutineErr:
    'MsgBox "Project1.Module1.CaptureWindow" & Err & Error
    Resume Next
End Function

Public Function CreateBitmapPicture(ByVal hBmp As Long, _
    ByVal hPal As Long) As Picture
    
    On Error GoTo ErrorRoutineErr
    
    Dim r As Long
        Dim Pic As PicBmp
    'IPicture requires a reference to "Standard OLE Types"
    Dim IPic As IPicture
    Dim IID_IDispatch As GUID
    
    'Fill in with IDispatch Interface ID
    With IID_IDispatch
        .Data1 = &H20400
        .Data4(0) = &HC0
        .Data4(7) = &H46
    End With
    
    'Fill Pic with necessary parts
    With Pic
        'Length of structure
        .Size = Len(Pic)
        'Type of Picture (bitmap)
        .Type = vbPicTypeBitmap
        'Handle to bitmap
        .hBmp = hBmp
        'Handle to palette (may be null)
        .hPal = hPal
    End With
    
    'Create Picture object
    r = OleCreatePictureIndirect(Pic, IID_IDispatch, 1, IPic)
    
    'Return the new Picture object
    Set CreateBitmapPicture = IPic
    
ErrorRoutineResume:
    Exit Function
ErrorRoutineErr:
    'MsgBox "Project1.Module1.CreateBitmapPicture" & Err & Error
    Resume Next
End Function

Sub Main()
On Error GoTo ErrorRoutineErr
    
    Set pictureForm.Picture1.Picture = CaptureForm
    
    'SavePicture pictureForm.Picture1.Picture, _
     '"\\A1-eas01\d\OPS_Скриншоты\DDD.bmp"
     
     SavePicture pictureForm.Picture1.Picture, _
     "Z:\DDD.bmp"
     
    Unload pictureForm
    
ErrorRoutineResume:
    Unload pictureForm
    End
ErrorRoutineErr:
    'User pressed cancel
    'If Err = 32755 Then
     '   Resume ErrorRoutineResume
    'End If
    'MsgBox "Project1.Form1.Command7_Click" & Err & Error
    Resume Next

End Sub

End Sub

Но это уже после моей "модификации", исходник сейчас дома и прислать не могу.
Кстати, к книге прилагается диск с очень интересными семпликами.
Книга называется "VB-6 и VBA", один из авторов Петроциус (сорри за невежество, если неверно написал, пишу по памяти).

Это сообщение отредактировал(а) ИгнатьевАлексей - 1.11.2006, 11:49

--------------------

Vingrad - FOREVER !!!

"Как вы яхту назовете - так она и поплывет!"
Капитан Врунгель

mihanik

Дата 1.11.2006, 11:50 (ссылка)

(нет голосов)

Загрузка ...

-=Белый Медведь=-

Профиль
Группа: Комодератор
Сообщений: 4054
Регистрация: 24.4.2006
Где: г. Тверь

Репутация: 11
Всего: 109

Цитата

Петроциус

Наверное Евангелос Петрусос ?

А за пример спасибо!!!

--------------------

Программистами не рождаются, - это родовая травма...

0 Пользователей читают эту тему (0 Гостей и 0 Скрытых Пользователей)
0 Пользователей:
« Предыдущая тема \| VB6 \| Следующая тема »