VPF::[VBA] Колонтитулы - Форум программистов

parfenon

Дата 29.10.2006, 16:50 (ссылка)

(нет голосов)

Загрузка ...

Новичок

Профиль
Группа: Участник
Сообщений: 1
Регистрация: 29.10.2006

Репутация: нет
Всего: нет

Колонтитулы

Помогите, плз, с решением задачи.
Суть: есть многостраничный вордовский документ,
как программно сделасть так, чтобы на каждой странице
вставлялись разные по значению колонтитулы, как верхние,
так и нижние.

Если кто знает, подскажите.

Aloha

Дата 30.10.2006, 16:15 (ссылка)

(нет голосов)

Загрузка ...

Профиль
Группа: Участник Клуба
Сообщений: 351
Регистрация: 14.5.2006

Репутация: 97
Всего: 165

parfenon

Если отвлечься от встроенных возможностей Word’а создавать уникальные (в смысле отличные от других) колонтитулы первой страницы и четных (нечетных) страниц, то, мне кажется, вариант может быть такой: побить многостраничный документ на разделы, каждый из которых соответствовал бы отдельной странице, и для каждого раздела создавать верхние (нижние) колонтитулы. Здесь нужно учесть, что если начало страницы не совпадает с началом очередного параграфа (т.е. параграф начинается в конце предыдущей страницы и продолжается на следующей) то в этом случае после добавления в начало страницы разрыва раздела, параграф будет разорван и нужно будет убрать отступ первой строки (если он есть).

Бьем на разделы:

Код

Sub s_BreakToPages()
  Dim v_Doc As Document
  Dim v_PagesCount As Integer
  Dim v_ChangeIndent As Boolean
  Dim n As Integer
  
  Set v_Doc = ActiveDocument
  Application.ScreenUpdating = False
  ' снимаем различия в колонтитулах первой страницы и четных(нечетных) страниц
  With v_Doc.PageSetup
    .OddAndEvenPagesHeaderFooter = False
    .DifferentFirstPageHeaderFooter = False
  End With
  ' читаем число страниц документа
  v_PagesCount = v_Doc.BuiltInDocumentProperties(wdPropertyPages)
  With Selection
  ' ставим курсор в начало документа
    .HomeKey (wdStory)
    ' цикл по числу страниц
    Do While n < v_PagesCount - 1
      n = n + 1
      ' ставим курсор в начало следующей страницы
      .GoTo wdGoToPage, wdGoToNext, 1
      ' если начало страницы приходится на середину параграфа, то "поднимем" флаг
      If .Paragraphs(1).Range.Characters.Count <> _
         .EndOf(wdParagraph, wdExtend) _
         Then v_ChangeIndent = True Else v_ChangeIndent = False
      ' добавляем разрыв раздела
      .InsertBreak (wdSectionBreakContinuous)
      ' убираем отступ первой строки, если это необходимо
      If v_ChangeIndent Then Selection.ParagraphFormat.FirstLineIndent = 0
    Loop
  End With
  Application.ScreenUpdating = True
End Sub

Так как нужный тебе алгоритм именования колонтитулов мне неведом, то пока так:

Код

Sub s_CreateHeadersFooters()
  Dim v_Doc As Document
  Dim n As Integer
  
  Set v_Doc = ActiveDocument
  Application.ScreenUpdating = False
  ' добавляем колонтитулы
  For n = 1 To v_Doc.Sections.Count
    With v_Doc.Sections(n)
      .Headers(wdHeaderFooterPrimary).LinkToPrevious = False
      .Headers(wdHeaderFooterPrimary).Range.Text = "Верхний колонтитул раздела " & n
      .Footers(wdHeaderFooterPrimary).LinkToPrevious = False
      .Footers(wdHeaderFooterPrimary).Range.Text = "Нижний колонтитул раздела " & n
    End With
  Next n
  Application.ScreenUpdating = True
End Sub

parfenon, на мой взгляд ты напрасно разместил свой пост именно в этой теме ([VBA] Найти слово):

тема другого участника;
тема помечена как решенная;
тема достаточно древняя;
существуют правила создания и именования тем, которые, как это не удивительно, призваны облегчить жизнь вопрошающих (а не усложнить).

Это сообщение отредактировал(а) Aloha - 30.10.2006, 17:36

Alexeis

Дата 30.10.2006, 17:02 (ссылка)

(нет голосов)

Загрузка ...

Амеба

Профиль
Группа: Админ
Сообщений: 11743
Регистрация: 12.10.2005
Где: Зеленоград

Репутация: 23
Всего: 459

Модератор: Тема выделена из "[VBA] Найти слово встречающееся в каждом предложении"

--------------------

Vit вечная память.

Обсуждение действий администрации форума производятся только в этом форуме

гениальность идеи состоит в том, что ее невозможно придумать

0 Пользователей читают эту тему (0 Гостей и 0 Скрытых Пользователей)
0 Пользователей:
« Предыдущая тема \| Центр помощи \| Следующая тема »