VPF::[Pascal] Выстроить строки матрицы в зависимости от

InviZible

Дата 28.1.2007, 20:32 (ссылка)

(нет голосов)

Загрузка ...

Шустрый

Профиль
Группа: Участник
Сообщений: 63
Регистрация: 13.9.2006

Репутация: нет
Всего: нет

У меня такое задание: нужно найти макс элемент в каждой строке матрицы, среди макс. элементов найти мин. элемент, среди оставшихся ещё миним. элем-т и т.д.
И напечатать строки так, чтобы первая была та, в которой был найдем первый мин. элемент, во второй строке второй мин. эле-т и т.д. Пример:
123 2 1
1 1 22
244 5 1
на выходе
1 1 22
123 2 1
244 5 1
Я сделал, только вот если ввести матр-цу
1 0 0
0 1 0
0 0 1
то он выводит несколько раз эту матрицу. Думаю ошибка при сравнении элементов.

Код


program matr_min_sredi_max;
uses crt;
const n=3;
var
 a:array[1..n,1..n] of integer;
 max,pmax:array[1..n] of integer;
 t,i,j,p,q,min:integer;
begin
 clrscr;
 for i:=1 to n do
  for j:=1 to n do
   read(a[i,j]);
 readln;
 for i:=1 to n do
  max[i]:=a[i,1];
 for i:=1 to n do
  for j:=1 to n do begin
   if (a[i,j]>max[i]) then max[i]:=a[i,j];
  end;
 writeln('===all max===');
 for i:=1 to n do
  write(max[i],' ');

 for i:=1 to n do
  pmax[i]:=max[i];

 writeln;
 writeln('===all min===');
 for i:=1 to n-1 do
  for j:=i+1 to n do
   if pmax[i]>pmax[j] then begin
    t:=pmax[i];
    pmax[i]:=pmax[j];
    pmax[j]:=t;
   end;
  for i:=1 to n do
   write(pmax[i],' ');

  writeln;
  writeln('===new matr====');
  for i:=1 to n do begin
   for j:=1 to n do begin
    if (pmax[i]=max[j]) then begin  {Скорее всего, что тут надо переделать}
     p:=j;
     for q:=1 to n do begin
      write(a[p,q],' ');
     end;
     writeln;
    end;
   end;
  end;
 readln;
end.

volvo877

Дата 28.1.2007, 21:05 (ссылка)

(нет голосов)

Загрузка ...

Эксперт

Профиль
Группа: Комодератор
Сообщений: 2073
Регистрация: 15.11.2004

Репутация: 34
Всего: 116

InviZible, я правильно понимаю, что программа сводится к сортировке матрицы по немного более сложному признаку, чем обычно?

Вот такой вариант не устроит?

Код

uses crt;
const
  n = 3;
type
  vector = array[1 .. n] of integer;

function get_max(arr: vector): integer;
var i, max: integer;
begin
  max := arr[1];
  for i := 2 to n do
    if arr[i] > max then max := arr[i];
  get_max := max;
end;

const
  { Для теста задано константой }
  a: array[1 .. n] of vector = (
        (123, 2, 1),
        (1, 1, 22),
        (244, 5, 1)
      );

var
  i, j: integer;
  T: vector;
begin
  clrscr;
  { Здесь будет ввод матрицы А }

  { Первоначальная матрица }
  for i := 1 to n do begin
    for j := 1 to n do write(a[i, j]:4);
    writeln;
  end;

  { Сортировка матрицы по максимуму в строке }
  for i := 1 to n do
    for j := n downto i + 1 do
      if get_max(a[j - 1]) > get_max(a[j]) then begin
        T := a[j - 1]; a[j - 1] := a[j]; a[j] := T
      end;

  { Результирующая матрица }
  for i := 1 to n do begin
    for j := 1 to n do write(a[i, j]:4);
    writeln;
  end;
  readln;
end.

InviZible

Дата 28.1.2007, 22:19 (ссылка)

(нет голосов)

Загрузка ...

Шустрый

Профиль
Группа: Участник
Сообщений: 63
Регистрация: 13.9.2006

Репутация: нет
Всего: нет

Большое Спасибо,устроит.

0 Пользователей читают эту тему (0 Гостей и 0 Скрытых Пользователей)
0 Пользователей:
« Предыдущая тема \| Центр помощи \| Следующая тема »