Модераторы: MetalFan
  

Поиск:

Ответ в темуСоздание новой темы Создание опроса
> Определение события возникшего в IE 
:(
    Опции темы
Luceus
  Дата 7.2.2007, 10:39 (ссылка) | (голосов:1) Загрузка ... Загрузка ... Быстрая цитата Цитата


Шустрый
*


Профиль
Группа: Участник
Сообщений: 105
Регистрация: 24.3.2006

Репутация: нет
Всего: 1
Здравствуйте!


Столкнулся со следующей задачей. Необходимо определить ссылку или объект, на котором произошел щелчок мыши в браузере (браузер может и не перегружаться, а просто выполниться JavaScript), с последующим анализом тега (какой айди, цвет текста и т.д.).

Например, пользователь щелкнул на ссылке, и появился alert javascript'a. Необходимо определить на какую ссылку нажал пользователь. По сути, программа должна выполнять анализ тега при событии fireevent.

Спасибо.


С уважением.
PM MAIL WWW   Вверх
Alexeyt
Дата 7.2.2007, 13:47 (ссылка) | (нет голосов) Загрузка ... Загрузка ... Быстрая цитата Цитата


Опытный
**


Профиль
Группа: Участник
Сообщений: 332
Регистрация: 15.9.2006
Где: около Москвы

Репутация: 1
Всего: 2
Luceus, 
У WB есть события:
OnBeforeNavigate2
OnDocumentComplete
OnNavigateComplete

Подойдет?
PM WWW   Вверх
Luceus
Дата 7.2.2007, 15:34 (ссылка) | (нет голосов) Загрузка ... Загрузка ... Быстрая цитата Цитата


Шустрый
*


Профиль
Группа: Участник
Сообщений: 105
Регистрация: 24.3.2006

Репутация: нет
Всего: 1
Alexeyt, как я могу узнать в событии OnBeforeNavigate2, что нажата именно эта ссылка? А если ссылка содержит обычный яваскрипт код? Тогда переадресации не будет.
PM MAIL WWW   Вверх
Alexeyt
Дата 7.2.2007, 16:55 (ссылка) | (голосов:1) Загрузка ... Загрузка ... Быстрая цитата Цитата


Опытный
**


Профиль
Группа: Участник
Сообщений: 332
Регистрация: 15.9.2006
Где: около Москвы

Репутация: 1
Всего: 2
Luceus, 
Там же есть пар-р URL. По нему ты не можешь узнать?
PM WWW   Вверх
December
Дата 7.2.2007, 21:16 (ссылка) | (нет голосов) Загрузка ... Загрузка ... Быстрая цитата Цитата


Antitheorist
****


Профиль
Группа: Участник
Сообщений: 4423
Регистрация: 14.8.2002
Где: Харьков

Репутация: 12
Всего: 57
Из "родных" для TWebBrowser событий файрится только OnCommandStateChange. Единственный выход здесь - ловить виндозные мессаги.


--------------------
Для друзей с винграда - скидки на разработку сайтов
PM MAIL WWW ICQ   Вверх
Luceus
Дата 8.2.2007, 10:07 (ссылка) | (нет голосов) Загрузка ... Загрузка ... Быстрая цитата Цитата


Шустрый
*


Профиль
Группа: Участник
Сообщений: 105
Регистрация: 24.3.2006

Репутация: нет
Всего: 1
Будем пробовать. Спасибо за ответ.
PM MAIL WWW   Вверх
phanatos
Дата 26.4.2007, 15:27 (ссылка) | (голосов:1) Загрузка ... Загрузка ... Быстрая цитата Цитата


Новичок



Профиль
Группа: Участник
Сообщений: 13
Регистрация: 9.8.2006

Репутация: 1
Всего: 2
Выход, слава богу, не единственный. Выхода всегда два... =)
Это делается так:

1) Этот незатейливый код - вспомогательный класс, экземпляр которого присваивается некоторому событию.
Тут, по большому счету ничего и нет, кроме реализации IDispatch.

Код

   TEventObject = class(TInterfacedObject, IDispatch)
   private
     FDoc: IHTMLDocument2;
     FOnEvent: TObjectProcedure;
   protected
     function GetTypeInfoCount(out Count: Integer): HResult; stdcall;
     function GetTypeInfo(Index, LocaleID: Integer; out TypeInfo): HResult; stdcall;
     function GetIDsOfNames(const IID: TGUID; Names: Pointer; NameCount, LocaleID: Integer; DispIDs: Pointer): HResult; stdcall;
     function Invoke(DispID: Integer; const IID: TGUID; LocaleID: Integer; Flags: Word; var Params; VarResult, ExcepInfo, ArgErr: Pointer): HResult; stdcall;
   public
     constructor Create(const Doc: IHTMLDocument2; const OnEvent: TObjectProcedure);
     property OnEvent: TObjectProcedure read FOnEvent write FOnEvent;
   end;

constructor TEventObject.Create(const Doc: IHTMLDocument2; const OnEvent: TObjectProcedure);
begin
   inherited Create;
   FOnEvent := OnEvent;
   FDoc := Doc;
end;

function TEventObject.GetIDsOfNames(const IID: TGUID; Names: Pointer; NameCount, LocaleID: Integer; DispIDs: Pointer): HResult;
begin
   Result := E_NOTIMPL;
end;

function TEventObject.GetTypeInfo(Index, LocaleID: Integer; out TypeInfo): HResult;
begin
   Result := E_NOTIMPL;
end;

function TEventObject.GetTypeInfoCount(out Count: Integer): HResult;
begin
   Result := E_NOTIMPL;
end;

function TEventObject.Invoke(DispID: Integer; const IID: TGUID; LocaleID: Integer; Flags: Word; var Params; VarResult, ExcepInfo, ArgErr: Pointer): HResult;
begin
   if (DispID = DISPID_VALUE) then
   begin
     if Assigned(FOnEvent) then FOnEvent(FDoc);
     Result := S_OK;
   end
   else Result := E_NOTIMPL;
end;




2) Далее, собственно, присваиваешь событию экземпляр TEventObject, в конструкторе которого указываешь нужный тебе метод-обработчик,
в данном случае  procedure Document_OnMouseMove(Doc: IHTMLDocument2);

Код

procedure TForm1.WebBrowser1DocumentComplete(ASender: TObject;
  const pDisp: IDispatch; var URL: OleVariant);
var
  Doc: IHTMLDocument2;
begin
   if Assigned(WebBrowser1.Document) then
   begin
     Doc := WebBrowser1.Document as IHTMLDocument2;
     Doc.onclick := TEventObject.Create(Doc, Document_OnClick) as IDispatch;
     Doc.onmousemove := (TEventObject.Create(Doc, Document_OnMouseMove) as IDispatch);
   end;
end;


3) Уже будет работать. Но не совсеми объектами. Вернее, при работе с IHtmlElement возможно неосвобожение памяти. Так, по крайней мере, сообщали на форуме Bsalsa. Нужно еще использовать приведенные ниже функцедуры:

Код

function ConnectEvSink(elem:IInterface;eventGUID:TGUID; eventSink:IUnknown):integer;
var cpc:IConnectionPointContainer;
    cp:IConnectionPoint;
begin
  result:=0;
  elem.QueryInterface(IConnectionPointContainer,cpc);
  if cpc<>nil then
  begin
    cpc.FindConnectionPoint(eventGUID,cp);
    if cp<>nil then
      cp.Advise(eventSink,result);
  end;
end;

procedure DisconnectEvSink(elem:IInterface;eventGUID:TGUID;
                      const ID:integer);
var cpc:IConnectionPointContainer;
    cp:IConnectionPoint;
begin
  elem.QueryInterface(IConnectionPointContainer,cpc);
  if cpc<>nil then
  begin
    cpc.FindConnectionPoint(eventGUID,cp);
    if cp<>nil then
      cp.UnAdvise(id);
  end;
end;



Например так:

Код


     // при инициализации
     MouseDownEvetSink:=TEventObject.Create(Doc, Document_OnMouseDown);
     Doc.onmousedown := MouseDownEvetSink as IDispatch;
     IDMouseDown:=ConnectEvSink(Doc,DIID_HTMLDocumentEvents2,MouseDownEvetSink);
    
     // при окончании работы
     DisconnectEvSink(Doc,DIID_HTMLDocumentEvents2,IDMouseDown);
     MouseDownEvetSink:=nil;
PM MAIL   Вверх
bashsu
Дата 27.2.2012, 15:22 (ссылка) | (нет голосов) Загрузка ... Загрузка ... Быстрая цитата Цитата


Новичок



Профиль
Группа: Участник
Сообщений: 1
Регистрация: 27.2.2012

Репутация: нет
Всего: нет
Чёт у меня ни че не получается. 
Может кто нить объяснить подробнее
PM MAIL   Вверх
  
 Ответ в темуСоздание новой темы Создание опроса
Правила форума "Delphi: ActiveX/СОМ/CORBA"

Rrader
Girder

Запрещено:

1. Публиковать ссылки на вскрытые компоненты

2. Обсуждать взлом компонентов и делиться вскрытыми компонентами


  • Литературу по Delphi обсуждаем здесь
  • Действия модераторов можно обсудить здесь
  • С просьбами о написании курсовой, реферата и т.п. обращаться сюда
  • Вопросы по реализации алгоритмов рассматриваются здесь
  • 90% ответов на свои вопросы можно найти в DRKB (Delphi Russian Knowledge Base) - крупнейшем в рунете сборнике материалов по Delphi
  • Вопросы по SQL и вопросы по базам данных, не связанные с Delphi, задавать здесь

Если Вам помогли, и атмосфера форума Вам понравилась, то заходите к нам чаще! С уважением, Rrader, Girder.
 
1 Пользователей читают эту тему (1 Гостей и 0 Скрытых Пользователей)
0 Пользователей:
« Предыдущая тема | Delphi: ActiveX/СОМ/CORBA | Следующая тема »

Подписаться на тему | Подписка на этот форум | Скачать/Распечатать тему


 




[ Время генерации скрипта: 0.0711 ]   [ Использовано запросов: 21 ]   [ GZIP включён ]


Реклама на сайте     Информационное спонсорство

 
 По вопросам размещения рекламы пишите на vladimir(sobaka)vingrad.ru
Отказ от ответственности     Powered by Invision Power Board(R) 1.3 © 2003  IPS, Inc.