VPF::От имени какого пользоавтеля запущен процесс?

Digit

Дата 13.2.2007, 17:50 (ссылка)

(нет голосов)

Загрузка ...

Шустрый

Профиль
Группа: Участник
Сообщений: 54
Регистрация: 3.7.2005

Репутация: нет
Всего: нет

Как узнать от имени какого пользователя запущен процесс? Известно только имя *.exe файла (например 'notepad.exe').

Yanis

Дата 13.2.2007, 17:55 (ссылка)

(нет голосов)

Загрузка ...

Эксперт

Профиль
Группа: Участник Клуба
Сообщений: 2937
Регистрация: 9.2.2004
Где: Москва

Репутация: 13
Всего: 111

Это тема, всё же для раздела WinAPI больше подходит....
Ближе к телу. Сначала надо перечислить процессы, найти нужный (notepad.exe к примеру), открыть его (OpenProcess), открыть его токен (OpenProcessToken), прочитать о нём инфу (GetTokenInformation).

Добавлено @ 17:55
Будет время, то завтра попробую накатать пример. А пока, пока.

--------------------

*щёлк*

Digit

Дата 13.2.2007, 18:42 (ссылка)

(нет голосов)

Загрузка ...

Шустрый

Профиль
Группа: Участник
Сообщений: 54
Регистрация: 3.7.2005

Репутация: нет
Всего: нет

Пернес в WinAPI

Это сообщение отредактировал(а) Digit - 13.2.2007, 18:48

Romikgy

Дата 13.2.2007, 21:53 (ссылка)

(нет голосов)

Загрузка ...

Любитель-программер

Профиль
Группа: Участник Клуба
Сообщений: 7326
Регистрация: 11.5.2005
Где: Porto Franco Odes sa

Репутация: 13
Всего: 146

имхо OpenProcessToken+GetTokenInformation(TokenUser)+LookupAccountSid
PS но я не проверял...

--------------------

Владение русской орфографией это как владение кунг-фу — истинные мастера не применяют его без надобности.

Rennigth

Дата 14.2.2007, 11:12 (ссылка)

(нет голосов)

Загрузка ...

Эксперт

Профиль
Группа: Участник Клуба
Сообщений: 1708
Регистрация: 21.6.2004
Где: Moscow

Репутация: 8
Всего: 76

Digit,

Примерно, так.

Код


type
  PTokenUser = ^TTokenUser;
  TTokenUser = record
    User: _SID_AND_ATTRIBUTES;
  end;

function ConvertSidToStringSid (Sid : PSID; var StringSid : PChar) : BOOL; stdcall; external 'advapi32.dll' name 'ConvertSidToStringSidA';

function GetLastErrorString: string;
var
  lz: Cardinal;
  lErr: array[0..512] of Char;
begin
  lz := GetLastError;
  FormatMessage(FORMAT_MESSAGE_FROM_SYSTEM, nil, lz, 0, @lErr, 512, nil);
  Result := string(lErr);
end;


procedure TForm1.Button1Click(Sender: TObject);
var
  hToken, hRetUserSize: DWord;
  pBuffer: PTokenUser;
  pSID: Pointer;
  lpSID: PChar;
begin
  if OpenProcessToken(GetCurrentProcess, TOKEN_ALL_ACCESS, hToken) then
  begin
    GetTokenInformation(hToken, TokenUser, nil, 0, hRetUserSize); (* Get Buffer Size *)

    pBuffer := GetMemory(hRetUserSize);
    try
      if GetTokenInformation(hToken, TokenUser, pBuffer, hRetUserSize, hRetUserSize) then
      begin
        if ConvertSidToStringSid(pBuffer^.User.Sid, lpSID) then
        begin
          try
            ShowMessage(lpSID);
          finally
            LocalFree(DWord(lpSID));
          end;
        end else
          ShowMessage(GetLastErrorString);
      end else
        ShowMessage(GetLastErrorString);
    finally
      FreeMemory(pBuffer);
    end;

  end else
    ShowMessage(GetLastErrorString);
end;

Только это будет бинарное представление юзера, надо переводить.
PS: У меня MSDN что-то не открывается, на локале у меня статья называется:
"Converting a Binary SID to String Format in C++" поищи, там пример на C.

--------------------

(* Honesta mors turpi vita potior *)

Yanis

Дата 14.2.2007, 11:51 (ссылка)

(нет голосов)

Загрузка ...

Эксперт

Профиль
Группа: Участник Клуба
Сообщений: 2937
Регистрация: 9.2.2004
Где: Москва

Репутация: 13
Всего: 111

Код

(*******************************************************************************
* Функция вовращает имя пользователя от которого
* запущен процесс с PID dwPID
*******************************************************************************)
function GetProcessUser(dwPID: DWORD): string; overload;
type
  PTOKEN_USER = ^TOKEN_USER;
  _TOKEN_USER = record
    User : TSidAndAttributes;
  end;
  TOKEN_USER = _TOKEN_USER;

var
  hProcess, hToken: DWORD;
  cbBuf, chName, chDomain: DWORD;
  ptiUser: PTOKEN_USER;
  szName, szDomain: PAnsiChar;
  snu: SID_NAME_USE;
begin
  Result := '';
  if dwPID > 0 then
    begin
      // открываем процесс
      hProcess := OpenProcess(PROCESS_QUERY_INFORMATION, False, dwPID);
      if hProcess > 0 then
        begin
          if OpenProcessToken(hProcess, TOKEN_QUERY, hToken) then
            begin
              // узнаём размер буфера под структуру
              if not GetTokenInformation(hToken, TokenUser, nil, 0, cbBuf) then
                if GetLastError() <> ERROR_INSUFFICIENT_BUFFER then
                  begin
                    CloseHandle(hToken);
                    CloseHandle(hProcess);
                    Exit;
                  end;

              if cbBuf = 0 then
                begin
                  CloseHandle(hToken);
                  CloseHandle(hProcess);
                  Exit;
                end;

              // выделяем память под буфер
              ptiUser := GetMemory(cbBuf);
              // получаем инфу по токену
              if GetTokenInformation(hToken, TokenUser, ptiUser, cbBuf, cbBuf) then
                begin
                  chName := 200; szName := GetMemory(chName);
                  chDomain := 200; szDomain := GetMemory(chDomain);
                  if LookupAccountSid(nil, ptiUser.User.Sid, szName, chName, szDomain, chDomain, snu) then
                    Result := szName;

                  FreeMemory(szDomain);
                  FreeMemory(szName);
                end;
              FreeMemory(ptiUser);
              CloseHandle(hToken);
            end; // OpenProcessToken
          CloseHandle(hProcess);
        end; // hProcess > 0
    end; // dwProcessId > 0
end;

(*******************************************************************************
* Функция вовращает имя пользователя от которого
* запущен процесс с именем sFileName
*******************************************************************************)
function GetProcessUser(const sFileName: string): string; overload;
begin
  Result := GetProcessUser(FindProcess(sFileName));
end;

Использование:

Код

begin
  WinExec('notepad.exe', SW_SHOWNORMAL);
  ShowMessage(GetProcessUser('notepad.exe'));
end;

P. S. Код функции FindProcess я уже приводил.

--------------------

*щёлк*

0 Пользователей читают эту тему (0 Гостей и 0 Скрытых Пользователей)
0 Пользователей:
« Предыдущая тема \| Delphi: WinAPI и системное программирование \| Следующая тема »