VPF::TPageControl&OwnerDraw - Форум программистов

VICTAR

Дата 11.10.2007, 23:42 (ссылка)

(нет голосов)

Загрузка ...

Эксперт

Профиль
Группа: Участник
Сообщений: 1108
Регистрация: 6.10.2006

Репутация: 37
Всего: 80

Всем привет.
Столкнулся со следующей проблемой:
Имеем: TPageControl с OwnerDraw=true и с одним или несколькими невидимыми листами (TTabSheet).
Суть проблемы: в обработчик OnDrawTab передается не PageIndex(индекс из массива Pages, что было бы логично!), a TabIndex(индекс из массива Tabs).
Вот небольшой пример:

Код


unit Unit1;

interface

uses
  Windows, Messages, SysUtils, Variants, Classes, Graphics, Controls, Forms,
  Dialogs, ComCtrls, StdCtrls;

type
  TForm1 = class(TForm)
    pag1: TPageControl;
    procedure FormCreate(Sender: TObject);
    procedure pag1Change(Sender: TObject);
  private
    { Private declarations }
  public
    { Public declarations }
    procedure DrawTabEx(Control: TCustomTabControl; TabIndex: Integer;
      const Rect: TRect; Active: Boolean);
  end;

var
  Form1: TForm1;

implementation

{$R *.dfm}


procedure TForm1.DrawTabEx(Control: TCustomTabControl; TabIndex: Integer;
  const Rect: TRect; Active: Boolean);
begin
  with Control.Canvas do
  begin
    FillRect(Rect);
    TextOut(Rect.Left + 4, Rect.Top + 4, pag1.Pages[TabIndex].Caption);
  end;
end;

procedure TForm1.FormCreate(Sender: TObject);
var
  i: integer;
begin
  with pag1 do
  begin
    OwnerDraw := true;
    OnDrawTab := DrawTabEx;
  end;
  for i := 1 to 5 do
    with TTabSheet.Create(pag1) do
    begin
      PageControl := pag1;
      Caption := Format('Закладка %d', [i]);
    end;
  pag1.Pages[0].TabVisible := false;
  pag1.Pages[2].TabVisible := false;
end;

procedure TForm1.pag1Change(Sender: TObject);
begin
  Caption := pag1.ActivePage.Caption;
end;

end.

При смене текущего листа, Caption формы будет содержать реальный заголовок листа, а что будет отображаться в заголовке самого листа поглядите сами.
Сначала я долго ломал голову, пытаясь понять почему у меня в заголовках листов отображается не то что надо... Пока наконец не заметил разницу в TabIndex и PageIndex.
Решение проблемы: создадим наследника TPageControl и откроем property Tabs.
Теперь проект будет выглядеть выглядить так:

Код


unit Unit1;

interface

uses
  Windows, Messages, SysUtils, Variants, Classes, Graphics, Controls, Forms,
  Dialogs, ComCtrls, StdCtrls;

type
  TPageControl = class(ComCtrls.TPageControl)
  public
    property Tabs;
  end;

  TForm1 = class(TForm)
    pag1: TPageControl;
    procedure FormCreate(Sender: TObject);
    procedure pag1Change(Sender: TObject);
  private
    { Private declarations }
  public
    { Public declarations }
    procedure DrawTabEx(Control: TCustomTabControl; TabIndex: Integer;
      const Rect: TRect; Active: Boolean);
  end;

var
  Form1: TForm1;

implementation

{$R *.dfm}

procedure TForm1.DrawTabEx(Control: TCustomTabControl; TabIndex: Integer;
  const Rect: TRect; Active: Boolean);
begin
  with Control.Canvas do
  begin
    FillRect(Rect);
    TextOut(Rect.Left + 4, Rect.Top + 4, pag1.Tabs[TabIndex]);
  end;
end;

procedure TForm1.FormCreate(Sender: TObject);
var
  i: integer;
begin
  with pag1 do
  begin
    OwnerDraw := true;
    OnDrawTab := DrawTabEx;
  end;
  for i := 1 to 5 do
    with TTabSheet.Create(pag1) do
    begin
      PageControl := pag1;
      Caption := Format('Закладка %d', [i]);
    end;
  pag1.Pages[0].TabVisible := false;
  pag1.Pages[2].TabVisible := false;
end;

procedure TForm1.pag1Change(Sender: TObject);
begin
  Caption := pag1.ActivePage.Caption;
end;

end.

PS Спасибо aktuba, за участие в решении данной проблемы
PSS Сразу хочу извинится, если где-то данная проблема уже решалась. Я перерыл пол инета, но так и не смог найти решения.

0 Пользователей читают эту тему (0 Гостей и 0 Скрытых Пользователей)
0 Пользователей:
« Предыдущая тема \| Delphi: Общие вопросы \| Следующая тема »