VPF::[Pascal] Уплотнение заданной матрицы

TMC

Дата 2.11.2007, 23:40 (ссылка)

(нет голосов)

Загрузка ...

Новичок

Профиль
Группа: Участник
Сообщений: 6
Регистрация: 2.11.2007

Репутация: нет
Всего: нет

Здравствуйте , уважаемые программисты !

Очень прошу вас помочь в решени следующей задачи:

Условие задачи :
Уплотнить заданную матрицу, удаляя из неё строки и столбцы, заполненные нулями. (Оформить в виде процедуры)

Буду очень вам благодарен.
Заранее большое спасибо.
С уважением.

darkart

Дата 4.11.2007, 15:59 (ссылка)

(нет голосов)

Загрузка ...

Опытный

Профиль
Группа: Участник
Сообщений: 379
Регистрация: 9.11.2005

Репутация: 26
Всего: 31

Неплохо бы писать, что такое уплотнение, удаление и прочее. Вариант со смещением элементов и фиктивной сменой размерности:

Код


program MatrixCondensation;{Уплотнение матрицы путем смещения элементов}
uses
  crt;
const
  MATRIX_STRINGS=4;{количество строк матрицы}
  MATRIX_COLUMNS=3;{количество столбцов матрицы}
type
  TMatrix=array[1..MATRIX_STRINGS,1..MATRIX_COLUMNS] of integer;{описание типа матрицы}
procedure InputMatrix(var Matrix:TMatrix; height,width:integer);
{процедураа ввода матрицы размера height на width}
var
  i,j:integer;{i,j - счетчики}
begin
  for i:=1 to height do{для каждой строки матрицы}
  begin
    for j:=1 to width-1 do{для каждого элемента строки, кроме последнего}
      read(Matrix[i,j]); {читаем очередной элемент матрицы}
    readln(Matrix[i,width]);{читаем последний элемент с переходом на новую строку}
  end;
end;
procedure PrintMatrix(var Matrix:TMatrix; height,width:integer);
{проедура печати матрицы height на width}
var
  i,j:integer;{i,j - счетчики}
begin
  for i:=1 to height do{для каждой строки матрицы}
  begin
    for j:=1 to width-1 do{для каждого элемента строки, кроме последнего}
      write(Matrix[i,j],' ');{печатаем элемент + отступ}
    writeln(Matrix[i,width]);{печать последнего элемента строки с переходом на новую строку}
  end;
end;

procedure CondensateMatrixByStrings(var Matrix:TMatrix; var height,width:integer);
{процедура уплотнения матрицы по строкам}
var
  i,j,k:integer;{i,j,k - счетчики}
begin
  i:=1;{иницализация счетчика(текущая строка)}
  while i<=height do{пока не перешли последнюю строку}
  begin
    j:=1;{инициализация счетчика(текущей элемент строки)}
    while((j<=width) and (Matrix[i,j]=0)) do
    {пока не перешли последний элемент строки и очередной элемет = 0}
      inc(j);{увеличение счетчика}
    if(j>width) then{если перешли за последний элемент, значит строка нулевая}
    begin
      dec(height);{уменьшение размерности матрицы по строкам}
      {смещение строк}
      for k:=i to height do
        for j:=1 to width do
          Matrix[k,j]:=Matrix[k+1,j];
    end
    else inc(i);{увеличение счетчика - переход к следующей строке}

  end;
end;

procedure CondensateMatrixByColumns(var Matrix:TMatrix; var height,width:integer);
{процедура уплотнения матрицы по столбцам}
var
  i,j,k:integer;{i,j,k - счетчики}
begin
  i:=1;{инициализация счетчика(текущий столбец)}
  while i<=width do{пока не перешли последний столбец}
  begin
    j:=1;{инициализация счетчика(текущий элемент столбца)}
    while((j<=height) and (Matrix[j,i]=0)) do
    {пока не перешли последний элемент столбца и очередной элемент = 0}
      inc(j);{увеличение счетчика}
    if(j>height) then
    {если перешли за последний элемент, значит столбец нулевой}
    begin
      dec(width);{уменьшение размерности матрицы по столбцам}
      {смещение столбцов}
      for k:=i to width do
        for j:=1 to height do
          Matrix[j,k]:=Matrix[j,k+1];
    end
    else inc(i);{увеличение счетчика - переход к следующему столбцу}
  end;
end;

procedure CondensateMatrix(var Matrix:TMatrix;var height,width:integer);
{процедура уплотнения матрицы}
begin
  CondensateMatrixByStrings(Matrix,height,width);{уплотнение по строкам}
  CondensateMatrixByColumns(matrix,height,width);{уплотнение по столбцам}
end;

var
  width,height:integer;{ширина и высота матрицы}
  Matrix:Tmatrix;{матрриа}
begin
  clrscr;{очистка экрана}
  height:=MATRIX_STRINGS;{высота равна количеству строк матрицы}
  width:=MATRIX_COLUMNS;{ширина равнв количеству столбцов матрицы}
  writeln('Please enter matrix[',height,'x',width,']:');
  InputMatrix(Matrix,height,width);{ввод матрицы}
  writeln('Source matrix:');
  PrintMatrix(Matrix,height,width);{вывод исходной матрицы}
  CondensateMatrix(Matrix,height,width);{уплотнение матрицы}
  writeln('Result matrix:');
  PrintMatrix(Matrix,height,width);{вывод матрицы-результата}
  readln;{ожидание ввода}
end.

TMC

Дата 4.11.2007, 17:14 (ссылка)

(нет голосов)

Загрузка ...

Новичок

Профиль
Группа: Участник
Сообщений: 6
Регистрация: 2.11.2007

Репутация: нет
Всего: нет

darkart, большое спасибо.

Всё отлично работает.
smile

Ещё раз выражаю особую благодарность в решении этой задачи !
Есть же всё таки умные и отзывчие люди в этом мире smile

Это сообщение отредактировал(а) TMC - 4.11.2007, 17:18

0 Пользователей читают эту тему (0 Гостей и 0 Скрытых Пользователей)
0 Пользователей:
« Предыдущая тема \| Центр помощи \| Следующая тема »