VPF::[Pascal]Задача с матрицами - Форум программистов

12Yarik

Дата 3.11.2007, 14:15 (ссылка)

(нет голосов)

Загрузка ...

Новичок

Профиль
Группа: Участник
Сообщений: 6
Регистрация: 31.10.2007

Репутация: нет
Всего: нет

Задача:
Дано три целых матрицы, размером 9х4. Вывести ту из них, где больше нульевых рядов (если таких матриц несколько, вывести их ).
Какое её решение ?

zkv

Дата 3.11.2007, 15:04 (ссылка)

(нет голосов)

Загрузка ...

Профиль
Группа: Участник Клуба
Сообщений: 2133
Регистрация: 23.7.2006
Где: Санкт-Петербург

Репутация: 21
Всего: 92

12Yarik,

M
zkv

Неужели трудно оформить тему как требуют правила.

Ripper

Дата 3.11.2007, 16:14 (ссылка)

(нет голосов)

Загрузка ...

Lonely soul...

Профиль
Группа: Участник
Сообщений: 920
Регистрация: 30.6.2004
Где: г. Москва

Репутация: 6
Всего: 23

Не совсем понял т.е. например
1234
0000
1234
0000
1234
1234
0000
0000
0000
Вот матрица 9х4. Ряд это строка или столбец? Допустим строка, и нужно посчитать у кого больше таких строк а если несколько с одинаковым количеством то вывести все? Если да, то можно например написать процеду которая получает строку и возвращает 1 если все элементы строки нулевые. И можно обходить каждую строку и проверять, если ф-ия вернула 1 то добавить в какую нить переменную +1. Т.к. матрицы три то можно сделать 3 переменные или массив какой нибудь. Ну и потом сравнить

--------------------

"Он знает: надо смеяться над тем, что тебя мучит, иначе не сохранишь равновесия, иначе мир сведет тебя с ума" - Над кукушкиным гнездом

12Yarik

Дата 3.11.2007, 21:44 (ссылка)

(нет голосов)

Загрузка ...

Новичок

Профиль
Группа: Участник
Сообщений: 6
Регистрация: 31.10.2007

Репутация: нет
Всего: нет

Ряд - ето строка

darkart

Дата 4.11.2007, 14:05 (ссылка)

(нет голосов)

Загрузка ...

Опытный

Профиль
Группа: Участник
Сообщений: 379
Регистрация: 9.11.2005

Репутация: 26
Всего: 31

Код


program Matrix_3_9x4;
uses crt;
const
     MATRIX_AMOUNT=3;{количество матриц}
     MATRIX_STRINGS=9;{количество строк в матрие}
     MATRIX_COLUMNS=4;{количество столбцов в матрице}
type
    TMatrix=array[1..MATRIX_STRINGS,1..MATRIX_COLUMNS] of integer;{описание типа матрицы}
    TArr=array [1..MATRIX_AMOUNT] of TMatrix;{описание типа массива матриц}
procedure InputMatrix(var Matrix:TMatrix);
{процедура ввода матрицы}
var
   i,j:integer;{i,j - счетчики}
begin
  for i:=1 to MATRIX_STRINGS do{для каждой строки матрицы}
  begin
    for j:=1 to MATRIX_COLUMNS-1 do{для каждого элемента строки, кроме последнего}
      read(Matrix[i,j]);{читаем очередной элемент матрицы}
    readln(Matrix[i,MATRIX_COLUMNS]);{читаем последний элемент матрицы с переходом на следующую строку}
  end;
end;

procedure PrintMatrix(var Matrix:TMatrix);
{процедура печати матрицы}
var
  i,j:integer;{i,j - счетчики}
begin
  for i:=1 to MATRIX_STRINGS do{для каждой строки матрицы}
  begin
      for j:=1 to MATRIX_COLUMNS-1 do{для каждого элемента строки матрицы, кроме последнего}
        write(Matrix[i,j],' ');{печатаем очередной элемент строки с отступом}
      writeln(Matrix[i,MATRIX_COLUMNS]);{печатаем послледний элемент строки матрицы с переходом на следующую строку}
  end;
end;

function GetNullStringsAmount(var Matrix:TMatrix):integer;
{функция возвращает количество нулевых строк в матрице}
var
  i,j,res:integer;{i,j - счетчики, res - возвращаемый результат}
begin
  res:=0;{инициализация результата}
  for i:=1 to MATRIX_STRINGS do{для каждой строки матрицы}
  begin
    j:=1;{счетчик в начало строки}
    while((j<=MATRIX_COLUMNS) and (Matrix[i,j]=0)) do
    {пока не перешли последний элемент и очередной элемент строки = 0}
      inc(j);{увеличение счетчика на 1}
    if(j>MATRIX_COLUMNS) then
    {если счетчик к моменту выхода из цикла перешел последний элемент, то строка нулевая}
      inc(res);{увеличение количества нулевых строк}
  end;
  GetNullStringsAmount:=res;{возвращаем количество нулевых строк}
end;

var
  Arr:TArr;{массив матриц}
  ArrNullStringsAmount:array[1..MATRIX_AMOUNT] of integer;{массив для хранения количества нулевых строк}
  MaxNullStringsAmount:integer;{максимальное количество нулевых строк}
  i:integer;{i - счетчик}
begin
  clrscr;{очистка экрана}
  writeln('Please enter ',MATRIX_AMOUNT,' matrix[',MATRIX_STRINGS,'x',MATRIX_COLUMNS,']:');
  for i:=1 to MATRIX_AMOUNT do{для каждой матрицы}
  begin
    writeln('Matrix[',i,']:');{печать сообщения}
    InputMatrix(Arr[i]);{ввод матрицы}
  end;

  writeln('Source matrixs:');{печать сообщения}
  MaxNullStringsAmount:=0;{инициализация максимального количества строк}
  for i:=1 to MATRIX_AMOUNT do{для каждой матрицы}
  begin
    ArrNullStringsAmount[i]:=GetNullStringsAmount(Arr[i]);{получаем количество нулевых строк в матрице}
    if(ArrNullStringsAmount[i]>MaxNullStringsAmount) then
    {если количество нулевых строк в текущей матрице больше максимального}
      MaxNullStringsAmount:=ArrNullStringsAmount[i];{запоминаем новый максимум количества строк}
    PrintMatrix(Arr[i]);{печать матрицы}
  end;
  writeln('Result:');{печать сообщения}
  writeln;
  if(MaxNullStringsAmount>0) then {если есть хотя бы 1 нулевая строка хотя бы в 1 матрице}
  begin
    for i:=1 to MATRIX_AMOUNT do{для каждой матрицы}
      if ArrNullStringsAmount[i]=MaxNullStringsAmount then
      {если количество строк в текущей матрице равно максимальному}
      begin
        PrintMatrix(Arr[i]);{печатаем текущую матрицу}
        writeln;
      end;
  end
  else{иначе}
    writeln('No null strings');{печать сообщения}
  readln;{ожидание ввода}
end.

0 Пользователей читают эту тему (0 Гостей и 0 Скрытых Пользователей)
0 Пользователей:
« Предыдущая тема \| Центр помощи \| Следующая тема »