VPF::InputBox() задать координаты - Форум программистов

simsmann

Дата 31.1.2008, 20:55 (ссылка)

(нет голосов)

Загрузка ...

Шустрый

Профиль
Группа: Участник
Сообщений: 75
Регистрация: 26.11.2006

Репутация: нет
Всего: нет

Возможноли для стандарного InputBox() задать эго появление не в центре экрана, а в определенном месте. Или обязательно придется создавать свое окно.

Sanchezzz

Дата 31.1.2008, 21:15 (ссылка)

(нет голосов)

Загрузка ...

Эксперт

Профиль
Группа: Завсегдатай
Сообщений: 1670
Регистрация: 19.11.2006
Где: Voronezh

Репутация: 5
Всего: 60

вот так можно но пороше создать тогда свое окно одинаковое количество ресурсов хавает

Код


public
   function InputQuery1(const ACaption, APrompt: string;
   var Value: string): Boolean;
   function GetAveCharSize1(Canvas: TCanvas): TPoint;
   function InputBox1(const ACaption, APrompt, ADefault: string): string;

  end;

var
  Form1: TForm1;

implementation

{$R *.dfm}

function TForm1.InputBox1(const ACaption, APrompt, ADefault: string): string;
begin
  Result := ADefault;
  InputQuery1(ACaption, APrompt, Result);
end;

function TForm1.GetAveCharSize1(Canvas: TCanvas): TPoint;
var
  I: Integer;
  Buffer: array[0..51] of Char;
begin
  for I := 0 to 25 do Buffer[I] := Chr(I + Ord('A'));
  for I := 0 to 25 do Buffer[I + 26] := Chr(I + Ord('a'));
  GetTextExtentPoint(Canvas.Handle, Buffer, 52, TSize(Result));
  Result.X := Result.X div 52;
end;

function TForm1.InputQuery1(const ACaption, APrompt: string;
  var Value: string): Boolean;
var
  Form: TForm;
  Pr: TLabel;
  Edit: TEdit;
  DialogUnits: TPoint;
  ButtonTop, ButtonWidth, ButtonHeight: Integer;
begin
  Result := False;
  Form := TForm.Create(Application);
  with Form do
    try
      Canvas.Font := Font;
      DialogUnits := GetAveCharSize1(Canvas);
      BorderStyle := bsDialog;
      Caption := ACaption;
      ClientWidth := MulDiv(180, DialogUnits.X, 4);
      Position := poMainFormCenter;//тут меняй на какое нужно
      Pr := TLabel.Create(Form);
      with Pr do
      begin
        Parent := Form;
        Caption := APrompt;
        Left := MulDiv(8, DialogUnits.X, 4);
        Top := MulDiv(8, DialogUnits.Y, 8);
        Constraints.MaxWidth := MulDiv(164, DialogUnits.X, 4);
        WordWrap := True;
      end;
      Edit := TEdit.Create(Form);
      with Edit do
      begin
        Parent := Form;
        Left := Pr.Left;
        Top := Pr.Top + Pr.Height + 5;
        Width := MulDiv(164, DialogUnits.X, 4);
        MaxLength := 255;
        Text := Value;
        SelectAll;
      end;
      ButtonTop := Edit.Top + Edit.Height + 15;
      ButtonWidth := MulDiv(50, DialogUnits.X, 4);
      ButtonHeight := MulDiv(14, DialogUnits.Y, 8);
      with TButton.Create(Form) do
      begin
        Parent := Form;
        Caption := 'Ok';
        ModalResult := mrOk;
        Default := True;
        SetBounds(MulDiv(38, DialogUnits.X, 4), ButtonTop, ButtonWidth,
          ButtonHeight);
      end;
      with TButton.Create(Form) do
      begin
        Parent := Form;
        Caption := 'Cancel';
        ModalResult := mrCancel;
        Cancel := True;
        SetBounds(MulDiv(92, DialogUnits.X, 4), Edit.Top + Edit.Height + 15,
          ButtonWidth, ButtonHeight);
        Form.ClientHeight := Top + Height + 13;
      end;
      if ShowModal = mrOk then
      begin
        Value := Edit.Text;
        Result := True;
      end;
    finally
      Form.Free;
    end;
end;

Это сообщение отредактировал(а) Sanchezzz - 31.1.2008, 21:19

--------------------

Понравился ответ "+" по репе, не забываем закрывать тему, заказы в LS.

0 Пользователей читают эту тему (0 Гостей и 0 Скрытых Пользователей)
0 Пользователей:
« Предыдущая тема \| Delphi: Общие вопросы \| Следующая тема »