VPF::[Паскаль]Найти норму матрицы по формуле

dizel003

Дата 16.10.2008, 11:57 (ссылка)

(нет голосов)

Загрузка ...

Бывалый

Профиль
Группа: Участник
Сообщений: 211
Регистрация: 7.11.2007

Репутация: нет
Всего: нет

Помогите написать программу!!!
не пойму как сделать!
в начале тапа вводим число строк и столбцов, затем заполняем её числами, потом наверное в цикле считываем сумму элементов, переберать максимум сравнивать, а потом непонимаю!!!

формулу прикрепил PS - я её быстро нарисовал не ругайтесь пожалуйста=)

Присоединённый файл ( Кол-во скачиваний: 15 )

_________1.jpg 16,62 Kb

darkart

Дата 17.10.2008, 13:18 (ссылка)

(нет голосов)

Загрузка ...

Опытный

Профиль
Группа: Участник
Сообщений: 379
Регистрация: 9.11.2005

Репутация: 26
Всего: 31

Код


program NormOfMatrix;

const
  MAX_ROWS = 10;{максимальное количество строк в матрице}
  MAX_COLS = 10;{максимальное количество столбцов в матрице}

type
  TMatrix = array[ 1..MAX_ROWS, 1..MAX_COLS ] of real;{тип матрица вещественных чисел}

procedure InputMatrix( var Matrix : TMatrix; iRows, iCols : integer );
{процедура ввода матрицы Matrix размерности iRows на iCols}
var
  i, j : integer;{счетчики}
begin
  for i := 1 to iRows do{для каждой строки матрицы}
  begin
    for j := 1 to iCols - 1 do{для каждого элемента строки, кроме последнего}
      read( Matrix[ i ][ j ] );{читаем элемент матрицы}
    readln( Matrix[ i ][ iCols ] );{читаем последний элемент строки матрицы с переводом курсора на новую строку}
  end
end;

procedure PrintMatrix( var Matrix : TMatrix; iRows, iCols : integer );
{процедура печати матрицы Matrix размерности iRows на iCols}
var
  i, j : integer;{счетчики}
begin
  for i := 1 to iRows do{для каждой строки матрицы}
  begin
    for j := 1 to iCols do{для каждого элемента строки}
      write( Matrix[ i ][ j ]:5:2,' ' );{печатаем элемент матрицы с форматированием}
    writeln;{переводим курсор на новую строку}
  end;
end;

function GetNorm( var Matrix : TMatrix; iRows, iCols : integer ) : real;
{функция возвращает норму матрицы Matrix размерности iRows на iCols}
{Норма матрицы = максимуму по строкам из квадратного корня суммы квадратов элементов строки}
var
  i, j : integer;{счетчики}
  fRes, fSum : real;{fSum - текущий результат для очередной строки, fRes - резуьтат}
begin
  fRes := 0.0;{инициализация}

  for i := 1 to iRows do{для каждой строки}
  begin
    fSum := 0.0;{инициализация}
    {далее считаем сумму квадратов элементов строки}
    for j := 1 to iCols do
      fSum := fSum + sqr( Matrix[ i ][ j ] );
    fSum := sqrt( fSum );{вычисление корня}
    if( fSum > fRes ) then{если текущий результат больше запомненного ранее, то запоминаем новое значение}
      fRes := fSum;
  end;
  GetNorm := fRes;{возврат результата}
end;

var
  iRows, iCols : integer;{переменные отвечающие за размерность матрицы}
  Matrix : TMatrix;{собственно матрица}

begin
  {ввод количества строк в матрице, если ввели неверное значение просим переввести}
  repeat
    writeln( 'Please enter rows number:' );
    readln( iRows );
    if( ( iRows <= 0 ) or ( iRows > MAX_ROWS) ) then
      writeln( 'Rows number must be in [ 1..', MAX_ROWS, ' ].' );
  until( ( iRows > 0 ) and ( iRows <= MAX_ROWS ) );

  {ввод количества столбцов в матрице, если ввели неверное значение просим переввести}
  repeat
    writeln( 'Please enter columns number:' );
    readln( iCols );
    if( ( iCols <= 0 ) or ( iCols > MAX_COLS ) ) then
      writeln( 'Columns number must be in [ 1..', MAX_COLS, ' ].' );
  until( ( iCols > 0 ) and ( iCols <= MAX_COLS ) );

  writeln( 'Please enter matrix [ ', iRows, 'x', iCols, ' ]:' );

  InputMatrix( Matrix, iRows, iCols );{ввод матрицы}

  writeln( 'Source matrix:' );

  PrintMatrix( Matrix, iRows, iCols );{печать исходной матрицы}

  {вывод результата}
  writeln( 'Norm of matrix = ', GetNorm( Matrix, iRows, iCols ):5:2 );

  readln;{ожидание ввода}

end.

1 Пользователей читают эту тему (1 Гостей и 0 Скрытых Пользователей)
0 Пользователей:
« Предыдущая тема \| Центр помощи \| Следующая тема »