VPF::Полоса прокрутки в TWebBrowser - Форум программистов

SAVANE

Дата 18.1.2008, 17:02 (ссылка)

(нет голосов)

Загрузка ...

Шустрый

Профиль
Группа: Участник
Сообщений: 118
Регистрация: 20.7.2006
Где: Украина, Полтава

Репутация: 1
Всего: 1

Как убрать вертикальную полосу прокрутки в ВебБраузере. Она появляется даже если размер HTML странички меньше размеров экрана.
Спасибо за любые идеи так как своих нет

--------------------

Be not afraid of growing slowly, be afraid only of standing still!

Rennigth

Дата 18.1.2008, 18:27 (ссылка)

(нет голосов)

Загрузка ...

Эксперт

Профиль
Группа: Участник Клуба
Сообщений: 1708
Регистрация: 21.6.2004
Где: Moscow

Репутация: нет
Всего: 76

SAVANE, доберись до интерфейса IHTMLStyle2 у Body документа. У него есть св-во
overflowY. Установи ему значение 'hidden'

Добавлено через 13 минут и 13 секунд
вот примерчик:

Код


unit Unit27;

interface

uses
  Windows, Messages, SysUtils, Variants, Classes, Graphics, Controls, Forms,
  Dialogs, SHDocVw, MSHTML, OleCtrls;

type
  TForm27 = class(TForm)
    WebBrowser1: TWebBrowser;
    procedure FormCreate(Sender: TObject);
    procedure WebBrowser1DocumentComplete(ASender: TObject;
      const pDisp: IDispatch; var URL: OleVariant);
  private
    procedure HideWBScrolls;
  end;

var
  Form27: TForm27;

implementation

{$R *.dfm}

procedure TForm27.FormCreate(Sender: TObject);
begin
  WebBrowser1.Navigate('http:\\www.google.com');
end;

procedure TForm27.HideWBScrolls;
var
  lDocument: IHTMLDocument2;
  lBody: IHTMLElement;
  lStyle: IHTMLStyle2;
begin
  if Assigned(WebBrowser1.Document) and
    (Succeeded(WebBrowser1.Document.QueryInterface(IHTMLDocument2,
    lDocument))) then
  begin
    lBody := lDocument.Body;
    if Assigned(lBody) and Assigned(lBody.style) and
      Succeeded(lBody.Style.QueryInterface(IID_IHTMLStyle2, lStyle)) then
    begin
      lStyle.overflowX := 'hidden'; //убираем горизонтальный скрол
      lStyle.overflowY := 'hidden'; //убираем вертикальный скрол
    end;
  end;
end;

procedure TForm27.WebBrowser1DocumentComplete(ASender: TObject;
  const pDisp: IDispatch; var URL: OleVariant);
begin
  HideWBScrolls;
end;

end.

--------------------

(* Honesta mors turpi vita potior *)

SAVANE

Дата 18.1.2008, 18:59 (ссылка)

(нет голосов)

Загрузка ...

Шустрый

Профиль
Группа: Участник
Сообщений: 118
Регистрация: 20.7.2006
Где: Украина, Полтава

Репутация: 1
Всего: 1

То что доктор прописал. Большое спасибо. smile

--------------------

Be not afraid of growing slowly, be afraid only of standing still!

YPCom

Дата 21.11.2008, 21:59 (ссылка)

(нет голосов)

Загрузка ...

Новичок

Профиль
Группа: Участник
Сообщений: 1
Регистрация: 18.11.2008

Репутация: нет
Всего: нет

У меня почему-то вертикальный скролл не исчезает, т.е. бегунка нет, а полоса остается. Как сделать, чтобы работало как в примере:

procedure TForm1.Button1Click(Sender: TObject);
begin
WebBrowser1.OleObject.Document.Body.Style.OverflowX := 'hidden';
WebBrowser1.OleObject.Document.Body.Style.OverflowY := 'hidden';
end;

Исчезают обе полосы прокрутки, но нужно чтобы это происходило только когда документ умещается в окно.

0 Пользователей читают эту тему (0 Гостей и 0 Скрытых Пользователей)
0 Пользователей:
« Предыдущая тема \| Delphi: ActiveX/СОМ/CORBA \| Следующая тема »