VPF::данные из запроса в отчет вывести в строчку

Masja

Дата 16.2.2009, 17:16 (ссылка)

(нет голосов)

Загрузка ...

Новичок

Профиль
Группа: Участник
Сообщений: 38
Регистрация: 24.4.2005
Где: Челябинск

Репутация: нет
Всего: 3

Подскажите, пожалуйста.

Есть препод ИВАНОВ, который может выполнять определенные работы. Данные из запроса берутся.

Вопрос: как можно в отчете вывести работы в строчку (перечислить через запятую) в виде:
.....бла-бла-бла может выполнять следующие работы: работа1, работа2, работа3

как реализовать?

Это сообщение отредактировал(а) Masja - 16.2.2009, 18:56

Akina

Дата 16.2.2009, 17:56 (ссылка)

(нет голосов)

Загрузка ...

Советчик

Профиль
Группа: Модератор
Сообщений: 20581
Регистрация: 8.4.2004
Где: Зеленоград

Репутация: 30
Всего: 454

Да. Напишите пользовательскую функцию, которая соберёт данные в строку, и используйте её в источнике данных контрола

--------------------

О(б)суждение моих действий - в соответствующей теме, пожалуйста. Или в РМ. И высшая инстанция - Администрация форума.

Masja

Дата 16.2.2009, 18:57 (ссылка)

(нет голосов)

Загрузка ...

Новичок

Профиль
Группа: Участник
Сообщений: 38
Регистрация: 24.4.2005
Где: Челябинск

Репутация: нет
Всего: 3

можно конкретный пример?

bopoha

Дата 16.2.2009, 19:18 (ссылка)

(нет голосов)

Загрузка ...

Эксперт

Профиль
Группа: Завсегдатай
Сообщений: 1283
Регистрация: 10.5.2006
Где: Беларусь, Минск

Репутация: 21
Всего: 21

Вот работающая фукния:

Код


Public Function MC_RecsInStrExt(ByVal stSQL As String _
                                , ByVal stFieldName As String _
                                , Optional ByVal SimvRazd As String = ", ") As String
' Скоков С.А.
' формирут строку из записей таблицы, разделяя их разделителями (запятыми)
' stSQL - запрос (может быть и именем таблицы или сохраненного запроса)
' stFieldName - имя поле, из которого брать данные
' SimvRazd - символ разделитель значений
On Error GoTo Err_
    
    Dim stRet As String
    Dim rstTable As Recordset
    
    Set rstTable = CurrentDb.OpenRecordset(stSQL, dbOpenDynaset)
    ' если есть записи то
    If rstTable.RecordCount > 0 Then
        ' это потому что эти значения разделяются запятыми и ставятся перед присваиванием _
            знач-я из таблицы (см. цикл ниже), _
            а перед первым значением запятую ставить не нужно
        stRet = Nz(rstTable(stFieldName))
        rstTable.MoveNext
    End If
    
    Do While Not rstTable.EOF
        stRet = stRet & SimvRazd & Nz(rstTable(stFieldName))
        rstTable.MoveNext
    Loop
    
    rstTable.Close
    
    MC_RecsInStrExt = stRet

Exit_:
    Exit Function

Err_:
    'MsgBox Err.Description
    Resume Exit_
End Function

Пример использования:

Код


'-- выводит через запятую технику для клиента с кодом 123
MsgBox MC_RecsInStrExt("SELECT T_TEHNIKA FROM b_klient_tehnika WHERE K_KLIENT = " & 123, "T_TEHNIKA")

--------------------

Как создавать приложения на MS Access

1 Пользователей читают эту тему (1 Гостей и 0 Скрытых Пользователей)
0 Пользователей:
« Предыдущая тема \| MS Access \| Следующая тема »