VPF::Работа с файлами. Через TFileStream.

Teleport

Дата 16.3.2009, 19:07 (ссылка)

(нет голосов)

Загрузка ...

Опытный

Профиль
Группа: Участник
Сообщений: 557
Регистрация: 5.7.2008
Где: Прибалтика

Репутация: 1
Всего: 6

не могу прочитать файл. Необходимо поместить содержимое файла 1.tel в поле Edit2.

Код


unit Unit1;

interface

uses
  Windows, Messages, SysUtils, Variants, Classes, Graphics, Controls, Forms,
  Dialogs, StdCtrls, Grids;

type
  TForm1 = class(TForm)
    Edit1: TEdit;
    Button1: TButton;
    Button2: TButton;
    Edit2: TEdit;
    procedure Button1Click(Sender: TObject);
    procedure Button2Click(Sender: TObject);
  private
    { Private declarations }
  public
    { Public declarations }
  end;

var
  Form1: TForm1;
  FS: TFileStream;
  FileName: string;
  mystring: string;
  mystring1: string;

implementation

{$R *.dfm}
 //сохранить
procedure TForm1.Button1Click(Sender: TObject);
begin
  mystring:= Edit1.Text;
  FS := TFileStream.Create('1.tel', fmOpenWrite or fmShareExclusive);
   try
     FS.Write(mystring, length(mystring));
   finally
     FS.Free;
   end;
end;

//открыть
procedure TForm1.Button2Click(Sender: TObject);
begin
  FS := TFileStream.Create('1.tel', FmOpenRead);
   try
     FS.Read();  //тут что??? как в Edit2 поместить содержимое файла?
     Edit2.Text:= mystring1;
   finally
     FS.Free;
   end;
end;

end.

--------------------

MetalFan

Дата 16.3.2009, 19:10 (ссылка)

(нет голосов)

Загрузка ...

Аццкий Сотона

Профиль
Группа: Комодератор
Сообщений: 3815
Регистрация: 2.10.2006
Где: Moscow

Репутация: 22
Всего: 128

у тебя и сохранение работать не будет...

--------------------

There are always someone smarter than you...

Matematik

Дата 16.3.2009, 19:17 (ссылка)

(нет голосов)

Загрузка ...

Эксперт

Профиль
Группа: Завсегдатай
Сообщений: 1027
Регистрация: 11.3.2006

Репутация: 7
Всего: 50

Код


function LoadStringFromFile(const AFileName:AnsiString):AnsiString;
var f : TFileStream;
begin
  f := TFileStream.Create(AFileName, fmOpenRead or fmShareDenyWrite); // открыть файл
  try
    SetLength(Result, f.Size); // взять память под стринг
    f.Read(Pointer(result)^, f.Size); // читать из файла в стринг
  finally
    f.Free // мало ли что случится, файл закроется
  end;
end;

procedure SaveStringToFile(const AFileName,ABuffer:AnsiString);
var f : TFileStream;
begin
  f := TFileStream.Create(AFileName, fmCreate); // создать файл
  try
    f.Write(Pointer(ABuffer)^, Length(ABuffer)); // записать стринг
  finally
    f.Free; // закрыть файл
  end;
end;

{...}

edit1.text := LoadStringFromFile('file');
SaveStringToFile('file', edit1.text)

Teleport

Дата 16.3.2009, 19:18 (ссылка)

(нет голосов)

Загрузка ...

Опытный

Профиль
Группа: Участник
Сообщений: 557
Регистрация: 5.7.2008
Где: Прибалтика

Репутация: 1
Всего: 6

Сохранение работает.

--------------------

Teleport

Дата 16.3.2009, 19:37 (ссылка)

(нет голосов)

Загрузка ...

Опытный

Профиль
Группа: Участник
Сообщений: 557
Регистрация: 5.7.2008
Где: Прибалтика

Репутация: 1
Всего: 6

1 Matematik - да. тема smile

работает.

А вот как быть если у меня несколько полей Edit? Вот вбил я в edit'ы данные и сохранил. Как потом прочитать данные из файла так чтобы они правильно рампределились по edita'ам?

--------------------

THandle

Дата 16.3.2009, 19:55 (ссылка)

(голосов:1)

Загрузка ...

Хранитель Клуба
Group Icon

Награды: 1

Профиль
Группа: Админ
Сообщений: 3639
Регистрация: 31.7.2007
Где: Moscow, Dubai

Репутация: 50
Всего: 372

/me горько плачет

Teleport, ну ведь ты же читал мою статью, да?

http://forum.vingrad.ru/forum/topic-250409.html

Вот это вообще к чему там было написано?

Цитата

В TStream'ах все пишется одним методом. И часто возникают вопросы, например, по записи строки. Человек подсовывает в Write сам указатель на строку, а не данные, которые начинаются с String[1], и получается, что строка в файл у него не пишется. Таких тем на форумах очень много и возникают они довольно часто.

Цитата(Teleport @ 16.3.2009, 19:37

)

А вот как быть если у меня несколько полей Edit?

Беги по ним и читай/пиши. Ну или не все Edit'ы надо, то просто записывай в нужном порядке и читай в таком же.

И хватит вам мучить бедный TStream. Есть же TReader/TWriter...
Вот пример для 3 TEdit'ов.

Запись:

Код


procedure TForm2.Button1Click(Sender: TObject);
var
  FS: TFileStream;
begin
  FS := TFileStream.Create('E:\TestEditsFile', fmCreate or fmOpenWrite);
  try
    with TWriter.Create(FS, 64) do
    try
      WriteListBegin;
      WriteString(Edit1.Text);
      WriteString(Edit2.Text);
      WriteString(Edit3.Text);
      WriteListEnd;
    finally
      Free;
    end;
  finally
    FS.Free;
  end;
end;

Чтение:

Код


procedure TForm2.Button2Click(Sender: TObject);
var
  FS: TFileStream;
begin
  FS := TFileStream.Create('E:\TestEditsFile', fmOpenRead);
  try
    with TReader.Create(FS, 64) do
    try
      ReadListBegin;
      Edit1.Text := ReadString;
      Edit2.Text := ReadString;
      Edit3.Text := ReadString;
      ReadListEnd;
    finally
      Free;
    end;
  finally
    FS.Free;
  end;
end;

Teleport

Дата 16.3.2009, 21:35 (ссылка)

(нет голосов)

Загрузка ...

Опытный

Профиль
Группа: Участник
Сообщений: 557
Регистрация: 5.7.2008
Где: Прибалтика

Репутация: 1
Всего: 6

2 THandle

Цитата

Teleport, ну ведь ты же читал мою статью, да?

Вот твоими советами я всегда пользуюсь. smile

Но ведь мало прочитать, надо еще и осознать же и научиться работать с этим. А я там ничего почти не понял. А почему? Да потому что не умею работать с файлами. Вот и начал издалека. Понял как работать с file и теперь как с TfileStream. по-крайней мере некоторые основы применения понятны. + твоя цитата

Цитата

и твой пример мне очень многое дали. smile

Спасибо

Вот теперь пора мучать твою статью и тебя smile

Отдельное спасибо для Matematik за пример, который легко понять smile

Данную тему считаю закрытой.

--------------------

0 Пользователей читают эту тему (0 Гостей и 0 Скрытых Пользователей)
0 Пользователей:
« Предыдущая тема \| Delphi: Для новичков \| Следующая тема »