VPF::[Delphi] Задачи на список. - Форум программистов

aleksandrdss

Дата 12.4.2009, 05:14 (ссылка)

(нет голосов)

Загрузка ...

Новичок

Профиль
Группа: Участник
Сообщений: 10
Регистрация: 8.12.2008

Репутация: нет
Всего: нет

1).Сформировать список группы студентов, каждая запись которого имеет следующую структуру: фамилия, имя, отчество, пол. Напечатать список студентов одного роста.
2).Сформировать массив сведений о наличии учебников в библиотеке следующей структуры: автор, название, шифр книги, количество экземпляров, год издания. Получить список новых изданий.

v4v4n

Дата 12.4.2009, 16:03 (ссылка)

(нет голосов)

Загрузка ...

Новичок

Профиль
Группа: Участник
Сообщений: 45
Регистрация: 26.9.2008

Репутация: 2
Всего: 4

1) Если это то, что требовалось

Код


unit Unit1;

interface

uses
  Windows, Messages, SysUtils, Variants, Classes, Graphics, Controls, Forms,
  Dialogs, StdCtrls, ComCtrls;

type
  TForm1 = class(TForm)
    Memo1: TMemo;
    Button1: TButton;
    Button2: TButton;
    Edit1: TEdit;
    RadioButton1: TRadioButton;
    RadioButton2: TRadioButton;
    TrackBar1: TTrackBar;
    Button3: TButton;
    Button4: TButton;
    procedure FormCreate(Sender: TObject);
    procedure Button1Click(Sender: TObject);
    procedure Button2Click(Sender: TObject);
    procedure Button3Click(Sender: TObject);
    procedure Button4Click(Sender: TObject);
    procedure FormClose(Sender: TObject; var Action: TCloseAction);
  private
    { Private declarations }
  public
    { Public declarations }
  end;
  PElem =^TElem;
  TElem = record
    FIO : String;
    Pol : char;
    Rost : byte;
    Next : PElem;
  end;

var
  Form1: TForm1;
  First : PElem;

implementation

{$R *.dfm}

procedure TForm1.FormCreate(Sender: TObject);
begin
    First:=nil;
    Memo1.Clear;
    Edit1.Text:='';
    RadioButton1.Checked:=true;
    TrackBar1.Max:=210;
    TrackBar1.Min:=50;
    TrackBar1.Frequency:=10;
    TrackBar1.Position:=175;
end;

procedure TForm1.Button1Click(Sender: TObject);
var Elem : PElem;
    count : integer;
begin
    if First=nil then MessageDlg('Список пустой',mtInformation,[mbOK],0)
    else begin
         count:=0;
         Elem:=First;
         Memo1.Lines.Add('Список студентов группы');
         While Elem<>nil do begin
             inc(count);
             Memo1.Lines.Add(IntToStr(count)+'.'+Elem.FIO+' пол:'+Elem.pol
                                         +' рост:'+IntToStr(Elem.rost));
             Elem:=Elem.Next;
         end;
         Memo1.Lines.Add('Всего: '+IntToStr(count)+' записей');
    end;
end;

procedure TForm1.Button2Click(Sender: TObject);
var Elem : PElem;
begin
    try
       new(Elem);
       Elem.Next:=First;
       Elem.FIO:=Edit1.Text;
       Elem.Rost:=TrackBar1.Position;
       if RadioButton1.Checked then Elem.Pol:='М' else Elem.Pol:='Ж';
       First:=Elem;
       Memo1.Lines.Add('Добавлен '+Elem.FIO+' пол:'+Elem.pol
                                         +' рост:'+IntToStr(Elem.rost));
    except messageDlg('Ошибка размещения элемента списка',mtError,[mbOK],0); end;
end;

procedure TForm1.Button3Click(Sender: TObject);
var Elem : PElem;
    count : integer;
begin
    if First=nil then MessageDlg('Список пустой',mtInformation,[mbOK],0)
    else begin
         count:=0;
         While First<>nil do begin
             Elem:=First;
             First:=First.Next;
             Dispose(Elem);
             inc(count);
         end;
         Memo1.Lines.Add('Удалено: '+IntToStr(count)+' записей');
    end;
end;

procedure TForm1.Button4Click(Sender: TObject);
var Elem1, Elem2, Elem3 : PElem;
    count, countg : integer;
    s : string;
begin
    if First=nil then MessageDlg('Список пустой',mtInformation,[mbOK],0)
    else begin
         countg:=0;
         Elem1:=First;
         Memo1.Lines.Add('Список студентов одного роста');
         While Elem1<>nil do begin
             count:=0;
             Elem2:=Elem1;
             Elem3:=First;
             While (Elem3<>Elem1)and(Elem3<>nil) do begin
                   if Elem3.Rost=Elem2.Rost then inc(count);
                   Elem3:=Elem3.Next;
             end;
             if count=0 then begin
                s:='';
                While Elem2<>nil do begin
                      if Elem1.Rost=Elem2.Rost then begin
                         inc(count);
                         s:=Elem2.FIO+';'+s;
                      end;
                      Elem2:=Elem2.Next;
                end;
                if count>1 then begin
                   Memo1.Lines.Add(IntToStr(Elem1.Rost)+'>> '+S);
                   inc(countg)
                end;
             end;
             Elem1:=Elem1.Next;
         end;
         if countg>0 then Memo1.Lines.Add('Всего: '+IntToStr(countg)+' групп роста')
         else Memo1.Lines.Add('студентов одного роста в списке нет');
    end;
end;

procedure TForm1.FormClose(Sender: TObject; var Action: TCloseAction);
begin
    Button3.Click;
end;

end.

0 Пользователей читают эту тему (0 Гостей и 0 Скрытых Пользователей)
0 Пользователей:
« Предыдущая тема \| Центр помощи \| Следующая тема »