VPF::Фон в ListView - Windows Vista & 7 - Форум программистов

Keeper89

Дата 27.12.2009, 15:49 (ссылка)

(нет голосов)

Загрузка ...

Эксперт

Профиль
Группа: Завсегдатай
Сообщений: 2580
Регистрация: 26.2.2009

Репутация: 14
Всего: 58

Доброго времени суток!

Устанавливаю изображение в качестве фона ListView следующим образом:

Код


...
type
  TLVBKIMAGE = packed record
    ulFlags : longint;
    hbm     : HBitmap;
    pszImage: PChar;
    cchImageMax : word;
    xOffsetPercent : integer;
    yOffsetPercent : integer;
  end;
const
  CLR_NONE = $FFFFFFFF;
  LVM_FIRST = $1000;
  LVM_SETTEXTBKCOLOR = (LVM_FIRST + 38);
  LVM_SETBKIMAGE = (LVM_FIRST + 68);
  LVBKIF_SOURCE_NONE = 0;
  LVBKIF_SOURCE_HBITMAP = 1;
  LVBKIF_SOURCE_URL = 2;
  LVBKIF_SOURCE_MASK = 3;
  LVBKIF_STYLE_NORMAL = 0;
  LVBKIF_STYLE_TILE = 16;
  LVBKIF_STYLE_MASK = 16;
var
  BKimg : TLVBKIMAGE;
begin
  FillChar(BKimg, SizeOf(BKimg), 0);
  BKimg.ulFlags := LVBKIF_SOURCE_URL or LVBKIF_STYLE_TILE;
  BKimg.pszImage := PChar('C:\1.jpg');
  SendMessage(ListView1.Handle, LVM_SETTEXTBKCOLOR, 0, CLR_NONE);
  SendMessage(ListView1.Handle, LVM_SETBKIMAGE, 0, integer(@BKimg));
end;

Но, это отказывается работать в Vist'е и Windows 7.

В чем может быть загвоздка?

--------------------

Cogito, ergo sum

Keeper's blog
CnWizards Downloads

user posted image

Rrader

Дата 31.12.2009, 17:46 (ссылка)

(голосов:2)

Загрузка ...

Inspired =)

Профиль
Группа: Экс. модератор
Сообщений: 1535
Регистрация: 7.5.2005

Репутация: 29
Всего: 191

Keeper89, структура неверно описана (зачем вообще было ее самому определять?). Тем не менее, с ошибкой код тоже заработает.
WM_ERASEBKGND обрабатывается? CoInitialize есть? Я такой код прогнал на Windows 7, работает:

Код


unit Unit1;

interface

uses
  Windows, Messages, SysUtils, Variants, Classes, Graphics, Controls, Forms,
  Dialogs, StdCtrls, XPMan, ComCtrls, ActiveX, CommCtrl;

type
  TListView = class(ComCtrls.TListView)
  protected
    procedure WndProc(var Message: TMessage); override;
  end;

  TForm1 = class(TForm)
    ListView1: TListView;
    Button1: TButton;
    procedure Button1Click(Sender: TObject);
    procedure FormCreate(Sender: TObject);
  private
    { Private declarations }
  public
    { Public declarations }
  end;

var
  Form1: TForm1;

implementation

{$R *.dfm}

procedure TForm1.Button1Click(Sender: TObject);
var
  BKImg: TLVBKImage;
begin
  FillChar(BKImg, SizeOf(BKImg), 0);
  BKImg.ulFlags := LVBKIF_SOURCE_URL or LVBKIF_STYLE_TILE;
  BKImg.pszImage := PChar('C:\1.jpg');
  SendMessage(ListView1.Handle, LVM_SETTEXTBKCOLOR, 0, CLR_NONE);
  SendMessage(ListView1.Handle, LVM_SETBKIMAGE, 0, LPARAM(@BKImg));
end;

procedure TForm1.FormCreate(Sender: TObject);
begin
  CoInitialize(nil);
end;

{ TListView }

procedure TListView.WndProc(var Message: TMessage);
begin
  if Message.Msg = WM_ERASEBKGND then
    DefaultHandler(Message)
  else
    inherited;
end;

end.

--------------------

Let's do this quickly!
Rest in peace, Vit!

Keeper89

Дата 8.1.2010, 15:27 (ссылка)

(нет голосов)

Загрузка ...

Эксперт

Профиль
Группа: Завсегдатай
Сообщений: 2580
Регистрация: 26.2.2009

Репутация: 14
Всего: 58

Цитата(Rrader @ 31.12.2009, 17:46

)

структура неверно описана

Точно, взял ее из модуля - все заработало. Спасибо!

--------------------

Cogito, ergo sum

Keeper's blog
CnWizards Downloads

user posted image

0 Пользователей читают эту тему (0 Гостей и 0 Скрытых Пользователей)
0 Пользователей:
« Предыдущая тема \| Delphi: WinAPI и системное программирование \| Следующая тема »