VPF::OnChange и RichEdit - Форум программистов

CHERRY

Дата 18.3.2010, 00:15 (ссылка)

(нет голосов)

Загрузка ...

Прохожий

Профиль
Группа: Участник
Сообщений: 150
Регистрация: 17.6.2002
Где: Одесса

Репутация: нет
Всего: -2

В наследнике от RichEdit требуется отслеживать количество строк.
В зависимости от количества строк в RichEdit выполняем какие-либо действия.
Думалось использовать OnChange.

Код


unit RETest;

interface

uses
  SysUtils, Classes, Controls, StdCtrls, ComCtrls, Graphics;

type
  TREdit = class(TRichEdit)
  private
    { Private declarations }
  protected
    { Protected declarations }
    procedure Change(Sender: TObject);
  public
    { Public declarations }
    constructor Create(AOwner: TComponent); override;
    destructor  Destroy; override;
  published
    { Published declarations }
  end;

procedure Register;

implementation

procedure Register;
begin
  RegisterComponents('CherryLib', [TREdit]);
end;


constructor TREdit.Create(AOwner: TComponent);
begin
  inherited Create(aOwner);
  OnChange:=Change;
end;

destructor TREdit.Destroy;
begin
  inherited Destroy;
end;

procedure TREdit.Change(Sender: TObject);
Begin
 Try
  if Lines.Count>5 then Color:=clRed Else Color:=clWhite;
 Except
   Exit
 End;
End;


end.

И все было хорошо (роцедура Change при превышении количества строк закрашивала REdit в красный цвет) до тех пор, пока пользователь компонента не создал событие OnChange.

Код


unit re;
interface
uses
  Windows, Messages, SysUtils, Variants, Classes, Graphics, Controls, Forms,
  Dialogs, StdCtrls, ComCtrls, RETest;

type
  TForm1 = class(TForm)
    REdit1: TREdit;
    procedure REdit1Change(Sender: TObject);
  private
    { Private declarations }
  public
    { Public declarations }
  end;

var
  Form1: TForm1;

implementation

{$R *.dfm}

procedure TForm1.REdit1Change(Sender: TObject);
begin
 Form1.Caption:=IntToStr(REdit1.Lines.Count);
end;

end.

После этого процедура Chane внутри компонента перестала работать.
И если я правильно понимаю, для других событий будет тоже самое.
Как Быть?

--------------------

Трясу надежды ветвь, но где желанный плод?

Rennigth

Дата 18.3.2010, 04:17 (ссылка)

(нет голосов)

Загрузка ...

Эксперт

Профиль
Группа: Участник Клуба
Сообщений: 1708
Регистрация: 21.6.2004
Где: Moscow

Репутация: 49
Всего: 76

Зачем этот изврат если у рича Change виртуальный?
Все что нужно это переопределить его...

Код


  TREdit = class(TRichEdit)
  protected
    procedure Change; override;
  end;
//...................
procedure TREdit.Change;
begin
  inherited;
  if Lines.Count > 5 then
    Color := clRed
  else
    Color := clWhite;
end;

--------------------

(* Honesta mors turpi vita potior *)

CHERRY

Дата 18.3.2010, 13:57 (ссылка)

(нет голосов)

Загрузка ...

Прохожий

Профиль
Группа: Участник
Сообщений: 150
Регистрация: 17.6.2002
Где: Одесса

Репутация: нет
Всего: -2

Огромное спасибо!

Добавлено через 1 минуту и 20 секунд
ОК!

--------------------

Трясу надежды ветвь, но где желанный плод?

0 Пользователей читают эту тему (0 Гостей и 0 Скрытых Пользователей)
0 Пользователей:
« Предыдущая тема \| Delphi: Общие вопросы \| Следующая тема »