Модераторы: Poseidon
  

Поиск:

Ответ в темуСоздание новой темы Создание опроса
> [Asm] резидентная прога.(недопустимая команда) 
V
    Опции темы
DeathKnight
Дата 15.4.2010, 19:21 (ссылка) | (нет голосов) Загрузка ... Загрузка ... Быстрая цитата Цитата


Шустрый
*


Профиль
Группа: Участник
Сообщений: 107
Регистрация: 12.10.2007
Где: Минск

Репутация: нет
Всего: нет
есть такой вот простенький скринсейвер под дос, который гасит монитор по прошествии определенного времени.
Код

; tasm /m scrsaver.asm
; tlink /t /x scrsaver.obj

.MODEL Tiny
.486
.CODE
ORG     100h

Start:

    jmp     main                   ; на начало программы
    Counter         dw      0       ; Счётчик времени
    Time            dw      70      ; Время для гашения экрана в 0.55 мсек тиках (минута)
    
;    ==8h==
Handler8    proc    far                ; Обработчик прерывания
    inc     cs:Counter              ; Увеличиваем на 1
    mov        ax, cs:Counter
    mov        bx, cs:Time
    cmp     ax, bx                    ; Прошло нужное время?
    jb      cs:RealInt8
    mov        ax, cs:Time
    mov     cs:Counter, ax            ; Чтоб не было переполнения через час
    mov     ax,1201h
    mov     bl,36h
    int     10h                     ; Гасим экран
    
RealInt8:       db      0EAh        ; jmp far
RealAddr8       dd      ?           ; Адрес старого обработчика
endp    Handler8


;    ==9h==
Handler9    proc    far
    ;push    ax bx di si
    mov        ax, cs:Time
    cmp     cs:Counter, ax            ; Экран погашен?
    jb      Reset
    mov     ax,1200h
    mov     bl,36h
    int     10h                     ; Врубаем экран
Reset:
    mov     cs:Counter,0            ; При нажатии клавиши сбрасываем счётчик в 0
    jmp        cs:RealAddr9
    ;pop        si di bx ax
RealInt9        db      0EAh        ; jmp far
RealAddr9       dd      ?           ; Адрес старого обработчика
endp    Handler9
TSREnd          =       $           ; Конец резидентной части
;--------------------------------------------------------------

Mess_hello    db    'Скринсейвер запущен. Спустя указанное время "неработы" он потушит экран.', 0Ah, 0Dh, '$'
cmd_wrong    db    'Ошибка. Параметр запуска: Dk_laba4.com [время_в_минутах(не более 60 минут)]', 0Ah, 0Dh, '$'

main    proc
    mov        si, 80h
    mov        ah, 0
    lodsb
    cmp        al, 4
    jg        mistake
    cmp        al, 1
    jbe        mistake
    mov        ch, 0
    mov        cl, al
    dec        cx
    inc        si
    call    str_to_bin
    mov        si, 444h
    mul        si
    mov        Time, ax
    lea        dx, Mess_hello
    mov        ah, 9h
    int    21h
    jmp        SetIntVec

    
mistake:
    lea        dx, cmd_wrong
    mov        ah, 9h
    int    21h
    mov        al, 0
    mov        ah, 4ch
    int    21h
endp    main

str_to_bin    proc    near    ; перевод строкового десятичного числа в двоичное представление
    push    di dx
    xor        ax, ax
    xor        dx, dx
    mov        di, 10
    
cycle:
    mul        di
    mov        dl, [si]
    sub        dl, 30h
    add        ax, dx
    inc        si
    loop    cycle    
    
    pop        dx di
    ret
endp    str_to_bin


SetIntVec    proc    near
    mov        ax,3508h                ; 08 - номер прерывания (здесь - таймер)
    int     21h                     ; Получаем адрес старого обработчика (в ES:BX)
    mov     word ptr RealAddr8[0],bx ; Сохраняем...
    mov     word ptr RealAddr8[2],es ; ...его в RealAddr8
    mov     ah,25h
    lea     dx,Handler8
    int     21h                     ; Устанавливаем наш обработчик

    mov     ax,3509h                ; 09 - номер прерывания (здесь - клава)
    int     21h                     ; Получаем адрес старого обработчика (в ES:BX)
    mov     word ptr RealAddr9[0],bx ; Сохраняем...
    mov     word ptr RealAddr9[2],es ; ...его в RealAddr9
    mov     ah,25h
    lea     dx,Handler9
    int     21h                     ; Устанавливаем наш обработчик

    lea     dx,TSREnd
    int     27h                     ; Выходим, но остаёмся резидентно
endp    SetIntVec
END Start



проблемы небольшие две:
-достаточно долго под ntdosvm работают прерывания. можно ли как-то ускорить обработку?
-не могу поймать причину ошибки, которую выдает система.(что-то про недопустимую команду из-за обработчиков). похоже что проблема в обработчике прерывания клавиатуры.(Handler9)

подскажите что не так. за ранее спасибо.


Это сообщение отредактировал(а) DeathKnight - 15.4.2010, 19:29
PM   Вверх
airyashov
Дата 16.4.2010, 10:27 (ссылка) | (нет голосов) Загрузка ... Загрузка ... Быстрая цитата Цитата


Опытный
**


Профиль
Группа: Участник
Сообщений: 284
Регистрация: 1.7.2008

Репутация: 1
Всего: 6
регистры в обработчиках нужно сохранять


--------------------
icq:3(один)7748666
mail:airyashov( а )inbox.ru
PM MAIL   Вверх
DeathKnight
Дата 16.4.2010, 10:31 (ссылка) | (нет голосов) Загрузка ... Загрузка ... Быстрая цитата Цитата


Шустрый
*


Профиль
Группа: Участник
Сообщений: 107
Регистрация: 12.10.2007
Где: Минск

Репутация: нет
Всего: нет
тогда при самом запуске обработчика выдает ошибку.
ругается на push/pop
не пойму чего так %)

Добавлено через 14 минут и 26 секунд
pusha/popa пропустил, попытка сохранить остальные регистры не привела ни к чему хорошему.
и ошибка переехала на другой адрес. cs:00ee ip:0474
PM   Вверх
airyashov
Дата 16.4.2010, 21:18 (ссылка) | (нет голосов) Загрузка ... Загрузка ... Быстрая цитата Цитата


Опытный
**


Профиль
Группа: Участник
Сообщений: 284
Регистрация: 1.7.2008

Репутация: 1
Всего: 6
в Handler8  такого кода не видел, завтра посмотрю подробно
может и 1200h на современных видеокартах не работает

Это сообщение отредактировал(а) airyashov - 16.4.2010, 21:27


--------------------
icq:3(один)7748666
mail:airyashov( а )inbox.ru
PM MAIL   Вверх
airyashov
Дата 17.4.2010, 09:11 (ссылка) | (нет голосов) Загрузка ... Загрузка ... Быстрая цитата Цитата


Опытный
**


Профиль
Группа: Участник
Сообщений: 284
Регистрация: 1.7.2008

Репутация: 1
Всего: 6
Код

.MODEL Tiny
.486
.CODE
ORG     100h
Start:
    jmp     main                   ; на начало программы
    Counter         dw      0       ; Счётчик времени
    Time            dw      70      ; Время для гашения экрана в 0.55 мсек тиках (минута)
    
;    ==8h==
Handler8    proc    far                ; Обработчик прерывания
    push  ax bx
    inc     cs:Counter              ; Увеличиваем на 1
    mov     ax, cs:Counter
    mov     bx, cs:Time
    cmp     ax, bx                    ; Прошло нужное время?
    jb      l8
    mov     cs:Counter, bx            ; Чтоб не было переполнения через час
    mov     ax,1201h
    mov     bl,36h
    int     10h                     ; Гасим экран
l8:
    pop bx ax
RealInt8:       db      0EAh        ; jmp far
RealAddr8       dd      ?           ; Адрес старого обработчика
endp    Handler8
;    ==9h==
Handler9    proc    far
    push    ax bx
    mov     ax, cs:Time
    cmp     cs:Counter, ax            ; Экран погашен?
    jb      Reset
    mov     ax,1200h
    mov     bl,36h
    int     10h                     ; Врубаем экран
Reset:
    mov     cs:Counter,0            ; При нажатии клавиши сбрасываем счётчик в 0
l9:
    pop     bx ax
RealInt9        db      0EAh        ; jmp far
RealAddr9       dd      ?           ; Адрес старого обработчика
endp    Handler9
TSREnd          =       $           ; Конец резидентной части
;--------------------------------------------------------------
Mess_hello    db    'Скринсейвер запущен. Спустя указанное время "неработы" он потушит экран.', 0Ah, 0Dh, '$'
cmd_wrong    db    'Ошибка. Параметр запуска: Dk_laba4.com [время_в_минутах(не более 60 минут)]', 0Ah, 0Dh, '$'
main    proc
    mov        si, 80h
    mov        ah, 0
    lodsb
    cmp        al, 4
    jg        mistake
    cmp        al, 1
    jbe        mistake
    mov        ch, 0
    mov        cl, al
    dec        cx
    inc        si
    call    str_to_bin

;    int 3
;mov ax, 4c00h
;int 21h
    
    mov        si, 444h
    mul        si
    mov        Time, ax
    lea        dx, Mess_hello
    mov        ah, 9h
    int    21h
    jmp        SetIntVec
    
mistake:
    lea        dx, cmd_wrong
    mov        ah, 9h
    int    21h
    mov        al, 0
    mov        ah, 4ch
    int    21h
endp    main
str_to_bin    proc    near    ; перевод строкового десятичного числа в двоичное представление
    push    di dx
    xor        ax, ax
    xor        dx, dx
    mov        di, 10
    
cycle:
    mul        di
    mov        dl, [si]
    sub        dl, 30h
    add        ax, dx
    inc        si
    loop    cycle    
    
    pop        dx di
    ret
endp    str_to_bin
SetIntVec    proc    near
    mov     ax,3508h                ; 08 - номер прерывания (здесь - таймер)
    int     21h                     ; Получаем адрес старого обработчика (в ES:BX)
    mov     word ptr RealAddr8[0],bx ; Сохраняем...
    mov     word ptr RealAddr8[2],es ; ...его в RealAddr8
    mov     ah,25h
    lea     dx,Handler8
    int     21h                     ; Устанавливаем наш обработчик
    mov     ax,3509h                ; 09 - номер прерывания (здесь - клава)
    int     21h                     ; Получаем адрес старого обработчика (в ES:BX)
    mov     word ptr RealAddr9[0],bx ; Сохраняем...
    mov     word ptr RealAddr9[2],es ; ...его в RealAddr9
    mov     ah,25h
    lea     dx,Handler9
    int     21h                     ; Устанавливаем наш обработчик
    lea     dx,TSREnd
    int     27h                     ; Выходим, но остаёмся резидентно
endp    SetIntVec
END Start



--------------------
icq:3(один)7748666
mail:airyashov( а )inbox.ru
PM MAIL   Вверх
DeathKnight
Дата 17.4.2010, 16:33 (ссылка) | (нет голосов) Загрузка ... Загрузка ... Быстрая цитата Цитата


Шустрый
*


Профиль
Группа: Участник
Сообщений: 107
Регистрация: 12.10.2007
Где: Минск

Репутация: нет
Всего: нет
благодарю. не заметил эту ошибку... %(
извини, за беспокойство.
PM   Вверх
  
 Ответ в темуСоздание новой темы Создание опроса
Правила форума "Центр помощи"

ВНИМАНИЕ! Прежде чем создавать темы, или писать сообщения в данный раздел, ознакомьтесь, пожалуйста, с Правилами форума и конкретно этого раздела.
Несоблюдение правил может повлечь за собой самые строгие меры от закрытия/удаления темы до бана пользователя!


  • Название темы должно отражать её суть! (Не следует добавлять туда слова "помогите", "срочно" и т.п.)
  • При создании темы, первым делом в квадратных скобках укажите область, из которой исходит вопрос (язык, дисциплина, диплом). Пример: [C++].
  • В названии темы не нужно указывать происхождение задачи (например "школьная задача", "задача из учебника" и т.п.), не нужно указывать ее сложность ("простая задача", "легкий вопрос" и т.п.). Все это можно писать в тексте самой задачи.
  • Если Вы ошиблись при вводе названия темы, отправьте письмо любому из модераторов раздела (через личные сообщения или report).
  • Для подсветки кода пользуйтесь тегами [code][/code] (выделяйте код и нажимаете на кнопку "Код"). Не забывайте выбирать при этом соответствующий язык.
  • Помните: один топик - один вопрос!
  • В данном разделе запрещено поднимать темы, т.е. при отсутствии ответов на Ваш вопрос добавлять новые ответы к теме, тем самым поднимая тему на верх списка.
  • Если вы хотите, чтобы вашу проблему решили при помощи определенного алгоритма, то не забудьте описать его!
  • Если вопрос решён, то воспользуйтесь ссылкой "Пометить как решённый", которая находится под кнопками создания темы или специальным флажком при ответе.

Более подробно с правилами данного раздела Вы можете ознакомится в этой теме.

Если Вам помогли и атмосфера форума Вам понравилась, то заходите к нам чаще! С уважением, Poseidon, Rodman
 
0 Пользователей читают эту тему (0 Гостей и 0 Скрытых Пользователей)
0 Пользователей:
« Предыдущая тема | Центр помощи | Следующая тема »

Подписаться на тему | Подписка на этот форум | Скачать/Распечатать тему


 




[ Время генерации скрипта: 0.0461 ]   [ Использовано запросов: 22 ]   [ GZIP включён ]


Реклама на сайте     Информационное спонсорство

 
 По вопросам размещения рекламы пишите на vladimir(sobaka)vingrad.ru
Отказ от ответственности     Powered by Invision Power Board(R) 1.3 © 2003  IPS, Inc.