VPF::RTF тэги в TRichEdit - Форум программистов

PalychXX

Дата 27.7.2010, 08:57 (ссылка)

(нет голосов)

Загрузка ...

Новичок

Профиль
Группа: Участник
Сообщений: 26
Регистрация: 29.1.2010

Репутация: нет
Всего: нет

В программе имеется TRichEdit в режиме readonly для отображения логов. Для простоты добавления текста используется функция:

Код


procedure TFormMain.PrintMessage(const Msg: string; Err: boolean);
begin
  RichEdit1.SelLength:=0;
  if Err then //цвет ошибок - красный
  begin
    RichEdit1.SelAttributes.Color:=clRed;
  end
  else //остального текста - черный
  begin
    RichEdit1.SelAttributes.Color:=clWindowText;
  end;
  RichEdit1.Lines.Append(Msg);
  RichEdit1.Perform(EM_SCROLLCARET, 0, 0); //прокрутить скроллбар на последнюю строку
end;

Хотелось бы иметь возможность вставлять форматированный текст (как минимум иметь возможность сделать часть текста верхним индексом). Пробовал передавать функции текст с RTF-тэгами (например, "x {\up10 2} + y"), RichEdit не распознает теги. Что посоветуете?

Snowy

Дата 27.7.2010, 11:45 (ссылка)

(нет голосов)

Загрузка ...

Эксперт

Профиль
Группа: Модератор
Сообщений: 11363
Регистрация: 13.10.2004
Где: Питер

Репутация: 192
Всего: 484

Так просто rtf не вставить.
Точне просто, но не так smile

А как-то так:

Код

uses RichEdit;

///////

procedure AddRtf(RichEdit: TRichEdit; Rtf: string);
function AddRtfCallback(dwCookie: Longint; pbBuff: PByte; cb: Longint; var pcb: Longint): Longint; stdcall;
var Stream: TStream;
begin
  Stream := TStream(dwCookie);
  Result := 0;
  with Stream do
  begin
    if (Size = position) then pcb := 0
    else if (Size - Position) <= cb then pcb := Read(pbBuff^, Size)
    else pcb := Read(pbBuff^, cb)
  end;
end;
var
  EditStream: TEditStream;
  Stream: TStringStream;
begin
  RichEdit.SelStart := MAXINT;
  Stream := TStringStream.Create(Rtf);
  try
    EditStream.dwCookie := Longint(Stream);
    EditStream.dwError := 0;
    EditStream.pfnCallback := @AddRtfCallback;
    RichEdit.Perform(EM_STREAMIN, SF_RTF or SFF_SELECTION, Longint(@EditStream));
  finally
    Stream.Free;
  end;
end;

// юзаем 
procedure TForm1.Button1Click(Sender: TObject);
begin
  AddRtf(RichEdit1, '{\rtf1 12345 \up10 89012 \up0 34567}');
end;

PalychXX

Дата 27.7.2010, 13:27 (ссылка)

(нет голосов)

Загрузка ...

Новичок

Профиль
Группа: Участник
Сообщений: 26
Регистрация: 29.1.2010

Репутация: нет
Всего: нет

Большое спасибо!

0 Пользователей читают эту тему (0 Гостей и 0 Скрытых Пользователей)
0 Пользователей:
« Предыдущая тема \| Delphi: Общие вопросы \| Следующая тема »