VPF::[Pascal] Расстановка элементов в массиве

merch

Дата 15.5.2011, 17:17 (ссылка)

(нет голосов)

Загрузка ...

Новичок

Профиль
Группа: Участник
Сообщений: 2
Регистрация: 15.5.2011

Репутация: нет
Всего: нет

Задача:

В массиве X(3.5,-7.4,1.7,12.9,-5.6,21.3,-8.6,4.5,0.6,2.5) переставить элементы так, чтобы сначала стояли отридцательные элемены, а затем положительные. Группу положительных элементов расставьте в убывающем порядке. Напечатать исходный и измененный массивы.

Дальше этого у меня дело не идет:

Код


Program l;

const n=10;

a:array[1..n] of real=(3.5,-7.4,1.7,12.9,-5.6,21.3,-8.6,4.5,0.6,2.5);
 var i:integer;
 min:real;
begin
for i:=1 to 10 do
if a[i]<0 then write(' ',a[i]);


for i:=1 to 10 do
if a[i]>0 then
begin
if(a[i])>min then write(' ',a[i]);




end;
end.

Помогите пожалуста! Если возможно, уписать положительные и отридцательные элементы в новые разные массивы, и после этого уже там редактировать порядок расположения элементов в положительном массиве, то было бы очень круто.

t_gran

Дата 16.5.2011, 06:46 (ссылка)

(нет голосов)

Загрузка ...

Опытный

Профиль
Группа: Участник
Сообщений: 621
Регистрация: 13.11.2007
Где: г.Усть-Илимск

Репутация: 33
Всего: 37

Код


const
   CSize = 10;

type
   TArray = array[1..CSize] of real;

{-----------------------------------------------}
procedure ArrayCopy(theFromArray: TArray; var theToArray: TArray);
var
   i: integer;
begin
   for i:= 1 to CSize do
      theToArray[i]:= theFromArray[i];
end;
{-----------------------------------------------}
procedure ArrayPrint(theArray: TArray);
var
   i: integer;
begin
  for i:= 1 to CSize do
     write(theArray[i]:2:1, ' ');
  writeln;
end;
{-----------------------------------------------}
procedure Swap(var theFirst, theSecond: real);
var
   buff: real;
begin
   buff:= theFirst;
   theFirst:= theSecond;
   theSecond:= buff;
end;
{-----------------------------------------------}
procedure ArrayFirstNegativeNumber(var theArray: TArray);
var
   L, R: integer;
begin
   L:= 1;
   R:= CSize;

   while (L < R) do
   begin
      while ((L < R) and (theArray[L] < 0)) do
         inc(L);
      while ((L < R) and (0 <= theArray[R])) do
         dec(R);
      if (L < R) then
         Swap(theArray[L], theArray[R]);
   end;
end;
{-----------------------------------------------}
procedure ArraySortByDiminution(var theArray: TArray; thePosBegin, thePosEnd: integer);
var
   i, j: integer;
begin
   for i:= thePosBegin to thePosEnd do
      for j:= i to thePosEnd do
         if (theArray[i] < theArray[j]) then
            Swap(theArray[i], theArray[j]);
end;
{-----------------------------------------------}
function FindFirstPositiveNumber(theArray: TArray): integer;
var
   i: integer;
begin
   i:= 1;
   while ((i <= CSize) and (theArray[i] < 0)) do
      inc(i);

   if (i <= CSize) then
      FindFirstPositiveNumber:= i
   else
      FindFirstPositiveNumber:= 0;
end;
{-----------------------------------------------}

const
   CArr: TArray = (3.5, -7.4, 1.7, 12.9, -5.6, 21.3, -8.6, 4.5, 0.6, 2.5);

var
   arr: TArray;
   pos: integer;
begin
   {Копируем константные значения в массив}
   ArrayCopy(CArr, arr);

   {Печатаем на экран исходный массив}
   ArrayPrint(arr);

   {Перекидыаем а начало массива отрицательные элементы}
   ArrayFirstNegativeNumber(arr);

   {Ищем в массиве первое вхождение положительного числа}
   pos:= FindFirstPositiveNumber(arr);

   {В том случае если положительное число найдено, то}
   if (pos <> 0) then
      {Сортируем массив по убыванию с начала первого
       входжения положительного числа и до конца}
      ArraySortByDiminution(arr, pos, CSize);

   {Печатаем на экран исходный массив}
   ArrayPrint(arr);
end.

Это сообщение отредактировал(а) t_gran - 16.5.2011, 06:50

Присоединённый файл ( Кол-во скачиваний: 3 )

arr.7z 18,90 Kb

--------------------

Я знаю, что ничего не знаю© Сократ
user posted image

merch

Дата 16.5.2011, 17:45 (ссылка)

(нет голосов)

Загрузка ...

Новичок

Профиль
Группа: Участник
Сообщений: 2
Регистрация: 15.5.2011

Репутация: нет
Всего: нет

Большое спасибо, будем разбираться.

0 Пользователей читают эту тему (0 Гостей и 0 Скрытых Пользователей)
0 Пользователей:
« Предыдущая тема \| Центр помощи \| Следующая тема »