При минимизации формы я использую RxTrayIcon, чтобы при этом исчезла
кнопка из Панели задач вызываю ShowWindow(Application.Handle,SW_HIDE).
Но вот незадача - не получается при восстановлении приложения (после клика
на TrayIcon) добиться, чтобы оно становилось поверх других окон и обязательно было активным.
Пересмотрел кучу FAQ-ов, но не нашел реально работающих примеров.
Был бы весьма признателен за помощь.
Drelphi 6, Win98

А так пробовал:

Код

ShowWindow(Application.Handle,SW_HIDE); ShowWindow(Handle,SW_HIDE);

Код

ShowWindow(Application.Handle,SW_restore); ShowWindow(Handle,SW_restore);

Цитата(Vit @ 23.9.2002, 12:30)

А так пробовал: Код ShowWindow(Application.Handle,SW_HIDE); ShowWindow(Handle,SW_HIDE); Код ShowWindow(Application.Handle,SW_restore); ShowWindow(Handle,SW_restore);

Пробовал - наверх при этом окно не выходит.

Если сделать
  Application.MainForm.FormStyle := fsStayOnTop;
  Application.MainForm.FormStyle := fsNormal;

то оно становится верхним, но не активизируется.

Попробуй винапи SetActiveWindow(HWND hWnd);

Должно работать

Клик по значку обрабатываете самостоятельно?
Вообще для того чтобы сделать актинвным окно, используют SetForeGroundWindow()

Пробовал -  те-же пироги ... :-(
Может я чего не так делаю. Вроде собрал минимальный тестовый проект:

type
 TForm1 = class(TForm)
   RxTrayIcon1: TRxTrayIcon;
   procedure FormCreate(Sender: TObject);
   procedure RxTrayIcon1Click(Sender: TObject; Button: TMouseButton;
                                         Shift: TShiftState; X, Y: Integer);
 private
   procedure ApplicationMinimize(Sender : TObject);
 end;

var
 Form1: TForm1;

implementation

{$R *.dfm}
procedure TForm1.ApplicationMinimize(Sender : TObject);
begin
 RxTrayIcon1.Show;
 ShowWindow(Application.Handle,SW_HIDE);
 ShowWindow(Handle,SW_HIDE);
end;

procedure TForm1.FormCreate(Sender: TObject);
begin
 RxTrayIcon1.Icon := Application.Icon;
 Application.OnMinimize := ApplicationMinimize;
end;

procedure TForm1.RxTrayIcon1Click(Sender: TObject; Button: TMouseButton;
         Shift: TShiftState; X, Y: Integer);
begin
 Application.Restore;
 ShowWindow(Application.Handle,SW_SHOW);
 ShowWindow(Handle,SW_SHOW);
 SetActiveWindow(Application.MainForm.Handle);
 RxTrayIcon1.Hide;
end;

По-поводу SetForegroundWindow - действительно это так. Поэтому спасибо!
Все получилось. Хотя ранее я пробовал этот вариант и - глухо...
Хорошо что уважаемый Song напомнил мне об этом, а то я уже закопался в
поисках и стал забывать с чего все началось.
Дело оказалось в следующем : гасить Tray-иконку надо в последнюю очередь,
именно так все работает(ранее сначала гасил Tray-иконку, а уже потом восттанавливал свое приложение).
Таким образом правильно работает следующий код:

procedure TForm1.ApplicationMinimize(Sender : TObject);
begin
 RxTrayIcon1.Show;
 ShowWindow(Application.Handle,SW_HIDE);
end;

procedure TForm1.RxTrayIcon1Click(Sender: TObject; Button: TMouseButton;
         Shift: TShiftState; X, Y: Integer);
begin
 Application.Restore;
 SetForeGroundWindow(Application.MainForm.Handle);
 RxTrayIcon1.Hide;
end;

Спасибо всем, принявшим участие в обсуждении!