VPF::Добавление узлов в Treeview - Форум программистов

AndreyZ53

Дата 17.5.2010, 18:17 (ссылка)

(нет голосов)

Загрузка ...

Шустрый

Профиль
Группа: Участник
Сообщений: 138
Регистрация: 22.8.2008

Репутация: нет
Всего: 2

Здравствуйте, помогите пожалуйста разобраться Treeview, как мне для выделенного узла добавить узел и сохранить эту структуру, чтобы при следующем запуске программы, он вылазил в такой же структуре. То есть отображались уже и те добавленные узлы в той же иерархии. Как-то не доводилось мне работать с этим компонентом, а вот сейчас стоит задача такая, что нужно добавить, удалить узел, а также при удалении узла если у него есть подузлы, то автоматом удалять и их, буду очень признателен, если поможете разобраться

--------------------

https://itbases.ru/

Norfonzor

Дата 17.5.2010, 18:28 (ссылка)

(нет голосов)

Загрузка ...

Шустрый

Профиль
Группа: Участник
Сообщений: 121
Регистрация: 17.10.2008

Репутация: нет
Всего: нет

Читай Virtual Treeview там все есть, примеры: http://depositfiles.com/files/8dozcctig

добавление новой:

Код


procedure TfrmMain.N2Click(Sender: TObject);
var
  NewNode: PVirtualNode;
  NewPhone: PPhoneNode;

begin
 NewNode := FrmMain.VT.AddChild(FrmMain.VT.FocusedNode);
  NewPhone := FrmMain.VT.GetNodeData(NewNode);
  if Assigned(NewPhone) then
    with NewPhone^ do
    begin
      Name := Global_Fn; //здесь свои данные из записи
      doc:=Global_Fmht;
      ImageIndex:=findex;
    end;

VTsave.Click;//сохранение

сохранение

Код


procedure TfrmMain.VTsaveClick(Sender: TObject);
var
  XMLDocument: TXMLDocument;

  procedure SaveXML(ANode: PVirtualNode; const AParent: IXMLNode);
  var
    NewNode: IXMLNode;
    NextNode: PVirtualNode;
    NodeData: PPhoneNode;
  begin
    NextNode := ANode.FirstChild;
    if Assigned(NextNode) then
      repeat
        NodeData := VT.GetNodeData(NextNode);
        NewNode := AParent.AddChild('Node');
        with NewNode, NodeData^ do
        begin
          Attributes['Name'] := Name;
          Attributes['doc'] := doc;
          Attributes['ImageIndex'] := ImageIndex;
        end;
        SaveXML(NextNode, NewNode);
        NextNode := NextNode.NextSibling;
      until
        NextNode = nil;
  end;

begin
  XMLDocument := TXMLDocument.Create(Self);
  try
    with XMLDocument do
    begin
      Active := True;
      Encoding := 'UTF-16';
      AddChild('VirtualTreeview');
      Options := Options + [doNodeAutoIndent];
    end;
    SaveXML(VT.RootNode, XMLDocument.DocumentElement);
    XMLDocument.SaveToFile('vt.xml');
  finally
    FreeAndNil(XMLDocument);
  end;
end;

загрузка

Код


procedure TfrmMain.LoadGlavClick(Sender: TObject);
var
  XMLDocument: TXMLDocument;

  procedure LoadXML(const ANodeList: IXMLNodeList; AParent: PVirtualNode);
  var
    i: Integer;
    NewNode: PVirtualNode;
    NodeData: PPhoneNode;
  begin
    for i := 0 to ANodeList.Count - 1 do
    begin
      NewNode := VT.AddChild(AParent);
      NodeData := VT.GetNodeData(NewNode);
      with NodeData^ do
      begin
        Name := VarToWideStr(ANodeList[i].Attributes['Name']);
        doc := VarToWideStr(ANodeList[i].Attributes['doc']);
        ImageIndex:= StrToIntDef(
              VarToStr(
              ANodeList[i].Attributes['ImageIndex']), 0);
      end;
      LoadXML(ANodeList[i].ChildNodes, NewNode);
    end;
  end;

begin
  if not FileExists('vt.xml') then
  begin
    MessageBox(Handle, 'Файл vt.xml не найден.', PChar(Application.Title),
      MB_ICONINFORMATION + MB_OK);
    Exit;
  end;
  XMLDocument := TXMLDocument.Create(Self);
  try
    XMLDocument.LoadFromFile('vt.xml');
    // Для каждой ветки XML дерева создать узел в дереве и зарузить поля
    // для структуры данных из аттрибутов
    // Не забываем использовать блоки Begin/End Update.
    VT.BeginUpdate;
    try
      LoadXML(XMLDocument.DocumentElement.ChildNodes, nil);
    finally
      VT.EndUpdate;
    end;
  finally
    FreeAndNil(XMLDocument);
  end;
end;

удаление

Код


procedure TfrmMain.Del_allClick(Sender: TObject);
begin
  VT.DeleteNode(VT.FocusedNode);
  VTsave.Click;
end;

Это сообщение отредактировал(а) Norfonzor - 17.5.2010, 18:29

Dom

Дата 17.5.2010, 21:20 (ссылка)

(нет голосов)

Загрузка ...

Шустрый

Профиль
Группа: Участник
Сообщений: 121
Регистрация: 7.8.2005

Репутация: 1
Всего: 4

А может вопрос по стандартному компоненту TTreeView?

kami

Дата 17.5.2010, 21:39 (ссылка)

(нет голосов)

Загрузка ...

Эксперт

Профиль
Группа: Завсегдатай
Сообщений: 1806
Регистрация: 25.8.2007
Где: Санкт-Петербург

Репутация: 23
Всего: 72