VPF::Проблема pipe + plink - Форум программистов

Delvish

Дата 11.10.2011, 18:14 (ссылка)

(нет голосов)

Загрузка ...

Профиль
Группа: Участник
Сообщений: 136
Регистрация: 13.12.2006

Репутация: 2
Всего: 4

Добрый день!

Есть такая консольная утилита от создателей PuTTY, называется Plink. Суть ее в том, чтобы можно было использовать PuTTY через пайпы. Проблема состоит в том, что если в качестве параметра моей функции передать просто 'plink', то данные по пайпу читаются (выводится встроенный хелп по использованию plink'а). Но если попробовать передать хоть какие-нибудь параметры, то не возвращается абсолютно ничего.
Есть кто-нибудь, кто уже использовал связку pipe и plink?

Собственно, код функции:

Код


function Check(str : String) : String;
const BUFSIZE = 2000;
var SecAttr    : TSecurityAttributes;
   hReadPipe,
   hWritePipe : THandle;
   StartupInfo: TStartUpInfo;
   ProcessInfo: TProcessInformation;
   Buffer     : Pchar;
   Status,
   BytesRead  : DWord;
   flag : Boolean;

begin
with SecAttr do
begin 
  nlength              := SizeOf(TSecurityAttributes); 
  binherithandle       := true; 
  lpsecuritydescriptor := nil; 
end; 
if Createpipe (hReadPipe, hWritePipe, @SecAttr, 0) then 
begin
  flag := false;
  Buffer  := AllocMem(BUFSIZE + 1); 
  FillChar(StartupInfo, Sizeof(StartupInfo), #0); 
  StartupInfo.cb          := SizeOf(StartupInfo); 
  StartupInfo.hStdOutput  := hWritePipe;
  StartupInfo.hStdInput   := hReadPipe;
  StartupInfo.dwFlags     := STARTF_USESTDHANDLES +
                             STARTF_USESHOWWINDOW;
  StartupInfo.wShowWindow := SW_HIDE;
  if CreateProcess(nil,
     PChar(str),
     @SecAttr,
     @SecAttr,
     true,
     NORMAL_PRIORITY_CLASS,
     nil,
     nil,
     StartupInfo,
     ProcessInfo)
  then
    begin
        Status := WaitForSingleObject(ProcessInfo.hProcess, INVALID_HANDLE_VALUE);
        if Status = WAIT_TIMEOUT then
          begin
          CloseHandle(ProcessInfo.hProcess);
          CloseHandle(ProcessInfo.hThread);
          CloseHandle(hReadPipe);
          CloseHandle(hWritePipe);
          flag := true;
          end;
      Repeat
        BytesRead := 0;
        ReadFile(hReadPipe, Buffer[0], BUFSIZE, BytesRead, nil);
        Buffer[BytesRead]:= #0;
        OemToAnsi(Buffer,Buffer);
        Result := String(Buffer);
      until (BytesRead < BUFSIZE); 
    end;
  FreeMem(Buffer);
  if flag = false then
    begin
    CloseHandle(ProcessInfo.hThread);
    CloseHandle(ProcessInfo.hProcess);
    CloseHandle(hReadPipe);
    CloseHandle(hWritePipe);
    end;
end;
end;

Delvish

Дата 4.11.2011, 09:51 (ссылка)

(нет голосов)

Загрузка ...

Профиль
Группа: Участник
Сообщений: 136
Регистрация: 13.12.2006

Репутация: 2
Всего: 4

хммм, так и думалось что вряд ли кто сталкивался smile

ну да ладно. проблему я давно решил, причем несколько другим способом. меня интересовало как можно общаться с удаленным хостом по SSH-протоколу и я решил этот вопрос. не через платные компоненты. на будущее, если кому понадобится, алгоритм такой: качаем по ссылке http://synapse.ararat.cz/doku.php/download компоненты SSL, а так же http://synapse.ararat.cz/files/crypt/cryptlib-3.2.2.zip и файлик msvcr71.dll (хотел дать на него ссыль, но засомневался - в Инете по разным ссылкам библиотека имеет размер 0.1-0.17 МБ, а у меня она 0.34, так что подберите самостоятельно).
после всего этого нужен небольшой модуль с классом SSH-клиента, и вот он:

Код


unit sshclient;
 
interface
 
uses
  tlntsend, ssl_openssl, ssl_openssl_lib, ssl_cryptlib;
 
type
  TSSHClient = class
  private
    FTelnetSend: TTelnetSend;
  public
    constructor Create(AHost, APort, AUser, APass: string);
    destructor Destroy; override;
    procedure SendCommand(ACommand: string);
    procedure PostCommand(ACommand: string);
    procedure ClearLog;
    procedure LogOut;
    function ReceiveData: string;
    function RcvPkt: string;
    function LogIn: Boolean;
  end;

var pkts : string;
 
implementation
 
{ TSSHClient }
 
constructor TSSHClient.Create(AHost, APort, AUser, APass: string);
begin
  FTelnetSend := TTelnetSend.Create;
  FTelnetSend.TargetHost := AHost;
  FTelnetSend.TargetPort := APort;
  FTelnetSend.UserName := AUser;
  FTelnetSend.Password := APass;
end;
 
destructor TSSHClient.Destroy;
begin
  FTelnetSend.Free;
  inherited;
end;
 
function TSSHClient.LogIn: Boolean;
begin
  Result := FTelnetSend.SSHLogin;
end;
 
procedure TSSHClient.LogOut;
begin
  FTelnetSend.Logout;
end;
 
function TSSHClient.ReceiveData: string;
var
  lPos: Integer;
begin
  Result := '';
  lPos := 1;
  while FTelnetSend.Sock.CanRead(1000) or (FTelnetSend.Sock.WaitingData>0) do
  begin
    FTelnetSend.Sock.RecvPacket(300);
    Result := Result + Copy(FTelnetSend.SessionLog, lPos, Length(FTelnetSend.SessionLog));
    lPos := Length(FTelnetSend.SessionLog)+1;
  end;
end;

function TSSHClient.RcvPkt: string;
var
  lPos: Integer;
begin
  pkts := FTelnetSend.SessionLog;
  FTelnetSend.SessionLog := '';
  Result := '';
  lPos := 1;
  while FTelnetSend.Sock.CanRead(1000) or (FTelnetSend.Sock.WaitingData>0) do
  begin
    FTelnetSend.Sock.RecvPacket(300);
    Result := Result + Copy(FTelnetSend.SessionLog, lPos, Length(FTelnetSend.SessionLog));
    lPos := Length(FTelnetSend.SessionLog)+1;
  end;
  FTelnetSend.SessionLog := pkts + Result;
end;

procedure TSSHClient.ClearLog;
begin
FTelnetSend.SessionLog := '';
end;
 
procedure TSSHClient.SendCommand(ACommand: string);
begin
  FTelnetSend.Send(ACommand + #13);
end;

procedure TSSHClient.PostCommand(ACommand: string);
begin
  FTelnetSend.Send(ACommand);
end;
 
end.

думаю, кому-нибудь это дело пригодится
P.S. Tnx to http://leonardorame.blogspot.com/2010/01/s...ssh-client.html

0 Пользователей читают эту тему (0 Гостей и 0 Скрытых Пользователей)
0 Пользователей:
« Предыдущая тема \| Delphi: WinAPI и системное программирование \| Следующая тема »