VPF::[турбо паскаль] одномерный массив вещественных чис

Gorpik

Дата 8.11.2011, 01:19 (ссылка)

(нет голосов)

Загрузка ...

Новичок

Профиль
Группа: Участник
Сообщений: 2
Регистрация: 8.11.2011

Репутация: нет
Всего: нет

Помогите, пожалуйста. Задача:

Цитата

Ввести одномерный массив вещественных чисел A(N) (N<=50) и выдать его на печать. Все его положительные элементы разделить на произведение положительных элементов массива и записать в массив Y. Выдать на печать массив Y или сообщение о невозможности его создания.

t_gran

Дата 9.11.2011, 10:37 (ссылка)

(нет голосов)

Загрузка ...

Опытный

Профиль
Группа: Участник
Сообщений: 621
Регистрация: 13.11.2007
Где: г.Усть-Илимск

Репутация: 33
Всего: 37

Код


const
    CSize = 50;

type
    TArray = array [1..CSize] of real;

{-----------------------------------------------}
{Процедура заполняет массив случайными числами}
procedure Fill(var theArray: TArray; theSize: word);
var
    i: word;
begin
    randomize;
    
    for i := 1 to theSize do
        theArray[i] := random(1000) / 100 - 5;
end;
{-----------------------------------------------}
{Процедура выводит все элементы массива}
procedure Print(theArray: TArray; theSize: word);
var
    i: word;
begin
    for i := 1 to theSize do
        write(theArray[i]:2:4, ' ');
end;
{-----------------------------------------------}
{Функция находит произведение всех положителльных элементов}
function ProductOfNumbers(theArray: TArray; theSize: word): real;
var
    i: word;
    result: real;
begin
    result := 1;
    
    for i := 1 to theSize do
        if (theArray[i] > 0) then
            result := result * theArray[i];
    
    ProductOfNumbers := result;
end;
{-----------------------------------------------}
{Процедура копирует элементы с одного массива в другой,
 при этом делит все положительные элменты на заданное число}
procedure CopyWithDivision(theArrayA: TArray; var theArrayY: TArray;
                                    theSize: word; theNumber: real);
var
    i: word;
begin
    for i := 1 to theSize do
        if (theArrayA[i] > 0) then
            theArrayY[i] := theArrayA[i] / theNumber
        else
            theArrayY[i] := theArrayA[i];
end;
{-----------------------------------------------}

var
    a, y: TArray;
    n: word;
    product: real;
    
begin
    write('input size array (max=', CSize, '): ');
    readln(n);
    
    if (n > CSize) then
    begin
        writeln('error: max < ', n);
        exit;
    end;

    Fill(a, n);
    write('a: ');
    Print(a, n);
    writeln;

    product := ProductOfNumbers(a, n);
    writeln('product=', product:2:4);
    
    CopyWithDivision(a, y, n, product);
    
    write('y: ');
    Print(y, n);
end.

Бинарник с исходником ниже

Присоединённый файл ( Кол-во скачиваний: 0 )

prog.7z 24,02 Kb

--------------------

Я знаю, что ничего не знаю© Сократ
user posted image

Gorpik

Дата 12.11.2011, 00:45 (ссылка)

(нет голосов)

Загрузка ...

Новичок

Профиль
Группа: Участник
Сообщений: 2
Регистрация: 8.11.2011

Репутация: нет
Всего: нет

t_gran, благодарю. Спасибо огромное!

0 Пользователей читают эту тему (0 Гостей и 0 Скрытых Пользователей)
0 Пользователей:
« Предыдущая тема \| Центр помощи \| Следующая тема »