VPF::[Pascal] Математическая задача - Форум программистов

mishamusha

Дата 29.10.2013, 01:40 (ссылка)

(нет голосов)

Загрузка ...

Новичок

Профиль
Группа: Участник
Сообщений: 7
Регистрация: 29.10.2013

Репутация: нет
Всего: нет

Вот сама задачка:
Для заданого двумерного массива найти среднее арифметическое(я нашел его), среднее квадратное отклонение Б(это дельта) за формулами. + массив и формулы на картинке.
Мой код:

Код


var   i  , j:integer;
  a:array [1..2,1..4] of real;
  sum,av:real;
 
   begin
   for i:=1 to 2 do begin
   for j:=1 to 4 do begin
   write('a[',i,',',j,']='); read(a[i,j]);
   end;
   end;
   sum:=0;
   for i:=1 to 2 do
   begin
   for j:=1 to 4 do
   begin
    sum:=sum+A[i,j]; 
    end;
    end;
    av:=sum/(2*4);  
    writeln('average =',av);
    readln;
    end.

Я не могу найти квадратическое отклонение, прошу дополните мой код, пожалуйста средним квадратическим отклонением!
Вот картинки:
http://imageshack.us/photo/my-images/132/aqkn.png/
http://imageshack.us/photo/my-images/802/jugw.png/

darkart

Дата 5.11.2013, 12:47 (ссылка)

(нет голосов)

Загрузка ...

Опытный

Профиль
Группа: Участник
Сообщений: 379
Регистрация: 9.11.2005

Репутация: 26
Всего: 31

Код


uses
  crt;
const
  MATRIX_ROWS = 2;
  MATRIX_COLS = 4;
type
  TMatrix = array [ 1..MATRIX_ROWS, 1..MATRIX_COLS ] of real;

procedure ReadMatrix( var matrix : TMatrix; rows, cols : integer );
var
  i, j : integer;
begin
  for i := 1 to rows do
  begin
    for j := 1 to cols do
      read( matrix[ i ][ j ] );
    readln;
  end;
end;

procedure PrintMatrix( var matrix : TMatrix; rows, cols : integer );
var
  i, j : integer;
begin
  for i := 1 to rows do
  begin
    for j := 1 to cols - 1 do
      write( matrix[ i ][ j ] : 6 : 2, ' ' );
    writeln( matrix[ i ][ cols ] : 6 : 2 );
  end;
end;

function ArithmeticMean( var matrix : TMatrix; rows, cols : integer ) : real;
var
  i, j : integer;
  sum : real;
begin
  sum := 0;
  for i := 1 to rows do
    for j := 1 to cols do
      sum := sum + matrix[ i ][ j ];
  ArithmeticMean := sum / ( rows * cols );
end;

function StandardDeviation( var matrix : TMatrix; rows, cols : integer ) : real;
var
  i, j : integer;
  aMean, sum : real;
begin
  sum := 0;
  aMean := ArithmeticMean( matrix, rows, cols );
  for i := 1 to rows do
    for j := 1 to cols do
      sum := sum + sqr( matrix[ i ][ j ] - aMean );
  StandardDeviation := sqrt( 1 / ( rows * cols - 1 ) * sum );
end;

var
  x : TMatrix;
begin
  writeln( 'Matrix...' );
  ReadMatrix( x, MATRIX_ROWS, MATRIX_COLS );
  writeln( 'Source matrix:' );
  PrintMatrix( x, MATRIX_ROWS, MATRIX_COLS );
  writeln( 'Arithmetic mean = ', ArithmeticMean( x, MATRIX_ROWS, MATRIX_COLS ) : 6 : 2 );
  writeln( 'Standard deviation = ', StandardDeviation( x, MATRIX_ROWS, MATRIX_COLS ) : 6 : 2 );
  readln;
end.

0 Пользователей читают эту тему (0 Гостей и 0 Скрытых Пользователей)
0 Пользователей:
« Предыдущая тема \| Центр помощи \| Следующая тема »