VPF::[Pascal] Двумерные массивы, матрицы, процедуры

SkipperOk

Дата 15.11.2013, 21:22 (ссылка)

(нет голосов)

Загрузка ...

Новичок

Профиль
Группа: Участник
Сообщений: 5
Регистрация: 15.11.2013

Репутация: нет
Всего: нет

Долго ломаю голову и никак ничего не влезет. Нужно написать программу, которая выводит те строки матрицы, элементы которых образуют геометрическую прогрессию, при этом используя процедуры... матрица произвольная, имеет размер N на M. Значение матрицы пользователь сам вводит после запуска.
мои наработки:

Код


Program p2;
var
n, m : integer;
matrix : array[1..n, 1..m] of integer;
procedure init;
var
i, j : integer;
begin
writeln('Enter the dimensions of matrix:' );
readln(n,m);
check(m); check(n);
for i:=1 to n do begin
writeln('Enter the', i, 'row of matrix: ' );
for j:=1 to m do
read(matrix[i,j]);
end;
end;

darkart

Дата 16.11.2013, 00:18 (ссылка)

(нет голосов)

Загрузка ...

Опытный

Профиль
Группа: Участник
Сообщений: 379
Регистрация: 9.11.2005

Репутация: 26
Всего: 31

Код


program matr;
uses
  crt, math;
const
  N = 3;
  M = 4;
type
  TMatrixRow = array[ 1..M ] of real;
  TMatrix = array [ 1..N ] of TMatrixRow;

procedure ReadMatrix( var matrix: TMatrix; rows, cols: integer );
var
  i, j: integer;
begin
  for i := 1 to rows do
  begin
    for j := 1 to cols - 1 do
      read( matrix[ i ][ j ] );
    readln( matrix[ i ][ cols ] );
  end;
end;

procedure WriteRow( var row: TMatrixRow; cols: integer );
var
  i: integer;
begin
  for i := 1 to cols - 1 do
    write( row[ i ]: 6: 2, ' ' );
  writeln( row[ cols ]: 6: 2 );

end;

procedure WriteMatrix( var matrix: TMatrix; rows, cols: integer );
var
  i: integer;
begin
  for i := 1 to rows do
    WriteRow( matrix[ i ], cols );
end;

function TestRow( var row: TMatrixRow; cols: integer ): boolean;
var
  i: integer;
  scale: real;
  res: boolean;
begin
  if ( cols < 2 ) or ( row[ 1 ] = 0 ) or ( row[ 2 ] = 0 ) then
    res := false
  else if cols < 3 then
    res := true
  else
  begin
    i := 2;
    scale := row[ i ] / row[ i - 1 ];

    repeat
      inc( i );
      res := ( row[ i - 1] <> 0 ) and ( abs( row[ i ] / row[ i - 1 ] - scale ) < 1e-4 );
    until( not res or ( i >= cols ) );

  end;
  TestRow := res;
end;


var
  i: integer;
  matrix: TMatrix;

begin
  clrscr;

  writeln( 'Please enter a matrix[ ', N, 'x', M, ' ]:' );
  ReadMatrix( matrix, N, M );

  writeln( 'Source matrix:' );
  WriteMatrix( matrix, N, M );

  writeln( 'Result rows...' );
  for i := 1 to N do
    if TestRow( matrix[ i ], M ) then
    begin
      write( 'Row No. ', i, ' :' );
      WriteRow( matrix[ i ], M );
    end;
end.

SkipperOk

Дата 17.11.2013, 22:44 (ссылка)

(нет голосов)

Загрузка ...

Новичок

Профиль
Группа: Участник
Сообщений: 5
Регистрация: 15.11.2013

Репутация: нет
Всего: нет

Отлично! Спасибо вам огромное! Но в самой программе мне непонятно, что значит

Код


type
  TMatrixRow = array[ 1..100 ] of real;
  TMatrix = array [ 1..100 ] of TMatrixRow;

можно ли как-то его под это переделать типа этого

Код


matrix:array[1..10, 1..100] of real;

дальше

Код


procedure ReadMatrix( var matrix: TMatrix; rows, cols: integer );

Код


rows

- это строки,

Код


cols

- столбцы?

Код


function TestRow( var row: TMatrixRow; cols: integer ): boolean;
var
  i: integer;
  scale: real;
  res: boolean;
begin
  if ( cols < 2 ) or ( row[ 1 ] = 0 ) or ( row[ 2 ] = 0 ) then
    res := false
  else if cols < 3 then
    res := true
  else
  begin
    i := 2;
    scale := row[ i ] / row[ i - 1 ];
    repeat
      inc( i );
      res := ( row[ i - 1] <> 0 ) and ( abs( row[ i ] / row[ i - 1 ] - scale ) < 1e-4 );
    until( not res or ( i >= cols ) );
  end;
  TestRow := res;
end;

Немного непонятная функция...

Код


 res, scale и 1e-4

и можно ли переделать программу так, чтобы она у меня запрашивала размерность матрицы?

darkart

Дата 17.11.2013, 23:08 (ссылка)

(нет голосов)

Загрузка ...

Опытный

Профиль
Группа: Участник
Сообщений: 379
Регистрация: 9.11.2005

Репутация: 26
Всего: 31

N, M - максимальный размер матрицы( N - строк, M - столбцов );

Код


TMatrixRow = array[ 1..M ] of real;//строка матрицы, состоящая из вещественных чисел
TMatrix = array [ 1..N ] of TMatrixRow;//массив строк( см. выше ) - собственно матрица

Переделать - можно.

rows - количество используемых строк матрицы, cols - количество используемых столбцов.

Непонятная функция, проверяет, являются ли элементы строки матрицы геометрической прогрессией, для чего вычисляется знаменатель прогрессии - по первым 2 элементам, если один из двух первых элементов - 0, то либо невозможно вычислить знаменатель - деление на 0, или первый член - 0, что не верно по определению прогрессии. Далее считаю, что если элемент 1, то это не прогрессия. Если элементов 2 и они не нули, то это прогрессия.

res - переменная логического типа - результат функции.
scale - знаменатель прогрессии, равный отношению второго элемента на первый.
Для элементов, начиная с третьего проверяем, равняется ли отношение текущего элемента к предыдущему знаменателю прогрессии scale.
1e-4 - точность вычисления.

Про переделать, чтобы спрашивала - заведи 2 переменных( константы N,M - максимально возможный размер матрицы ), попроси пользователя ввести их, прочитай, и передавай в процедуры/функции на места аргументов rows и cols.

Это сообщение отредактировал(а) darkart - 17.11.2013, 23:08

0 Пользователей читают эту тему (0 Гостей и 0 Скрытых Пользователей)
0 Пользователей:
« Предыдущая тема \| Центр помощи \| Следующая тема »