VPF::Обновить ресурсы (таблица строк) программы

artmaestro

Дата 14.3.2015, 01:21 (ссылка)

(нет голосов)

Загрузка ...

Шустрый

Профиль
Группа: Участник
Сообщений: 80
Регистрация: 8.11.2010

Репутация: нет
Всего: 1

Здравствуйте

Ребята, пожалуйста подскажите как обновить ресурсы программы, а именно таблицу строк.

Я понимаю, что нужно использовать
BeginUpdateResource, UpdateResource, EndUpdateResource.

мне не понятно как совладать с UpdateResource чтобы обновить таблицу строк.

Пример

Код


STRINGTABLE
LANGUAGE 25, 1
{
101, "1"
102, "2"
103, "3"
}

надо поменять 1 на 0 в строке 101 или например, строку 103... 3 поменять на 0.

Пожалуйста подскажите как это сделать. Спасибо.

Illusion Dolphin

Дата 17.3.2015, 20:11 (ссылка)

(нет голосов)

Загрузка ...

Эксперт

Профиль
Группа: Участник Клуба
Сообщений: 1198
Регистрация: 3.5.2003

Репутация: 36
Всего: 63

Вот так http://stackoverflow.com/questions/2608775...d-in-a-exe-file

Код


const
  LibName = 'TestLib.dll';
  ID_FIRST  = 1000;
  ID_SECOND = 1001;

function StringIDToGroupID(ID: UINT): UINT; inline;
begin
  Result := (ID shr 4) + 1;
end;

procedure UpdateStrings(const NewFirst, NewSecond: string);
var
  Handle: THandle;
  GroupID: UINT;
  Stream: TCustomMemoryStream;
  GroupStrings: array[0..15] of string;
  StrLen: Word;
  I: Integer;
begin
  GroupID := StringIDToGroupID(ID_FIRST);
  //get existing data...
  Handle := LoadLibraryEx(LibName, 0, LOAD_LIBRARY_AS_DATAFILE);
  if Handle = 0 then RaiseLastOSError;
  try
    Stream := TResourceStream.CreateFromID(Handle, GroupID, RT_STRING);
    try
      for I := Low(GroupStrings) to High(GroupStrings) do
      begin
        Stream.ReadBufferData(StrLen);
        SetLength(GroupStrings[I], StrLen);
        Stream.ReadBuffer(PChar(GroupStrings[I])^, StrLen * SizeOf(Char));
      end;
    finally
      Stream.Free;
    end;
  finally
    FreeLibrary(Handle);
  end;
  //update the strings we're interested in...
  GroupStrings[ID_FIRST mod Length(GroupStrings)] := NewFirst;
  GroupStrings[ID_SECOND mod Length(GroupStrings)] := NewSecond;
  Stream := TMemoryStream.Create;
  try
    for I := Low(GroupStrings) to High(GroupStrings) do
    begin
      StrLen := Length(GroupStrings[I]);
      Stream.WriteData(StrLen);
      Stream.WriteBuffer(PChar(GroupStrings[I])^, StrLen * SizeOf(Char));
    end;
    //update DLL...
    Handle := BeginUpdateResource(LibName, False);
    if Handle = 0 then RaiseLastOSError;
    try
      UpdateResource(Handle, RT_STRING, PChar(GroupID),
        MAKELANGID(LANG_ENGLISH, SUBLANG_ENGLISH_UK), Stream.Memory, Stream.Size);
    finally
      EndUpdateResource(Handle, False);
    end;
  finally
    Stream.Free;
  end;
end;

--------------------

В мире всего две бесконечности: вселенная и человеческая глупость... На счёт вселенной я не уверен.
Шифрование и организация фотографий - Photo Database 4.5

artmaestro

Дата 17.3.2015, 23:34 (ссылка)

(нет голосов)

Загрузка ...

Шустрый

Профиль
Группа: Участник
Сообщений: 80
Регистрация: 8.11.2010

Репутация: нет
Всего: 1

Спасибо огромное. Эту функцию находил.. может я не до конца разобрался, но в результате ее использования создается ЕЩЕ одна таблица строк в ресурсах, правда в ней данные меняются, те которые меня интересуют.

Illusion Dolphin

Дата 21.3.2015, 08:37 (ссылка)

(нет голосов)

Загрузка ...

Эксперт

Профиль
Группа: Участник Клуба
Сообщений: 1198
Регистрация: 3.5.2003

Репутация: 36
Всего: 63

Цитата

создается ЕЩЕ одна таблица строк в ресурсах,

Возможно дело в языке

Код


MAKELANGID(LANG_ENGLISH, SUBLANG_ENGLISH_UK)

Может у вас ресурсы в другом языке?

--------------------

1 Пользователей читают эту тему (1 Гостей и 0 Скрытых Пользователей)
0 Пользователей:
« Предыдущая тема \| Delphi: Общие вопросы \| Следующая тема »