VPF::Как записать содежимое DBGrid в текстовый файл

AstalaVista

Дата 25.4.2005, 20:20 (ссылка)

(голосов: 0)

Загрузка ...

Unregistered

Подскажите плиз как записать в файл txt все, что есть в данный момент в DBGrid.

Alex

Дата 26.4.2005, 00:00 (ссылка)

(нет голосов)

Загрузка ...

Эксперт

Профиль
Группа: Экс. модератор
Сообщений: 4147
Регистрация: 25.3.2002
Где: Москва

Репутация: 17
Всего: 162

Код


function DBGridToCsv(Grid: TDBGrid; aFile: String): Boolean;
var
  i, cnt: Integer;
  rLst: TStringList;
begin
  Result:= False;
  if (aFile = ''                           ) or
     (not Assigned(Grid)                   ) or
     (not Assigned(Grid.DataSource)        ) or
     (not Assigned(Grid.DataSource.DataSet)) or
     (not Grid.DataSource.DataSet.Active   ) then Exit;

  rLst:= TStringList.Create;
  try
    with Grid do try
      DataSource.DataSet.DisableControls;
      cnt:= FieldCount-1; // для ускорения алгоритма
      // Запомним название колонок
      with TStringList.Create do try
        Delimiter:= ';';
        for i:= 0 to cnt do Add(Columns[i].Title.Caption);
        rLst.Add(DelimitedText);
      finally
        Free;
      end;
      // Запоминаем содержимое колонок
      while not DataSource.DataSet.Eof do begin
        with TStringList.Create do try
          Delimiter:= ';';
          for i:= 0 to cnt do Add(Fields[i].AsString);
          rLst.Add(DelimitedText);
        finally
          Free;
        end;
        DataSource.DataSet.Next;
      end;
      rLst.SaveToFile(aFile); // Сохраняем результат
    finally
      DataSource.DataSet.EnableControls;
    end;
  finally
    rLst.Free;
  end;
  Result:= True;
end;

--------------------

Написать можно все - главное четко представлять, что ты хочешь получить в конце.

AstalaVista

Дата 26.4.2005, 12:39 (ссылка)

(голосов: 0)

Загрузка ...

Unregistered

Спасибо

0 Пользователей читают эту тему (0 Гостей и 0 Скрытых Пользователей)
0 Пользователей:
« Предыдущая тема \| Delphi: Базы данных и репортинг \| Следующая тема »