VPF::Работа с Clipboard - Форум программистов

Grol

Дата 9.5.2005, 01:58 (ссылка)

(нет голосов)

Загрузка ...

Бывалый

Профиль
Группа: Участник
Сообщений: 159
Регистрация: 5.5.2005
Где: Россия

Репутация: нет
Всего: нет

Здравствуйте уважаемы мастера Delphi!!! Хотел спросить у вас, как можно содержимое буфера обмена (ClipBoard) поместить в строковую переменную. Пример:

var stroka:string;
...
stroka:=Clipboard.....
...
Как это сделать я не знаю, вот и спрашиваю у вас! Заранее спасибо за ответ, буду очень благодарен.

--------------------

Живи так, как будто тебе предстоит умереть завтра...Учись так, как будто тебе предстоит жить вечно.........

Rrader

Дата 9.5.2005, 02:48 (ссылка)

(нет голосов)

Загрузка ...

Inspired =)

Профиль
Группа: Экс. модератор
Сообщений: 1535
Регистрация: 7.5.2005

Репутация: 29
Всего: 191

Код


uses ClipBrd;
...
var
  S: String;
begin
  S := Clipboard.AsText;
end;

;-)

Это сообщение отредактировал(а) Rrader - 28.11.2008, 14:56

--------------------

Let's do this quickly!
Rest in peace, Vit!

Alix

Дата 9.5.2005, 08:11 (ссылка)

(нет голосов)

Загрузка ...

L45

Профиль
Группа: Участник
Сообщений: 581
Регистрация: 4.5.2005
Где: Pskov/Spb

Репутация: 3
Всего: 23

Это самый простой способ. Однако, когда-то, мне нужна была маленькая программа, а модуль ClipBrd резко увеличивал ее объем (не помню уже на сколько, то ли на 75К, то ли на все 300К). А из него мне нужна была только вставка и копирование текста... Поэтому покромсав модуль ClipBrd я написал свой.

Код

unit ClipBoard;

interface

uses windows;

procedure Init (wnd : hWnd);
function SetText(const s : string) : boolean;
function GetText: string;

implementation

var window : hWnd;

procedure Init (wnd : hWnd);
begin
  window := wnd;
end;
                        
function GetText : string;
var
  Data: THandle;
begin
  if not OpenClipboard(window) then exit;
  Data := GetClipboardData(CF_TEXT);
  try
    if Data <> 0 then Result := PChar(GlobalLock(Data))
                 else Result := '';
  finally
    if Data <> 0 then GlobalUnlock(Data);
    CloseClipboard;
  end;
end;

function SetText(const s : string) : boolean;
var
  Data: THandle;
  DataPtr: Pointer;
begin
  result := false;
  if not OpenClipboard(window) then exit;
  try
    Data := GlobalAlloc(GMEM_MOVEABLE+GMEM_DDESHARE, Length(s)+1);
    try
      DataPtr := GlobalLock(Data);
      try
        Move(PChar(s)^, DataPtr^, Length(s)+1);
        EmptyClipboard;
        SetClipboardData(CF_TEXT, Data);
      finally
        GlobalUnlock(Data);
      end;
    except
      GlobalFree(Data);
      raise;
    end;
  finally
    result := CloseClipboard;
  end;
end;


end.

--------------------

Знание только тогда знание, когда оно приобретено усилиями своей мысли, а не памятью (с) Л. Толстой
High tech. Low live. (с) Gardner Dozois

0 Пользователей читают эту тему (0 Гостей и 0 Скрытых Пользователей)
0 Пользователей:
« Предыдущая тема \| Delphi: WinAPI и системное программирование \| Следующая тема »