VPF::Создание компонентов во время работы программы

ylana

Дата 8.5.2005, 11:12 (ссылка)

(нет голосов)

Загрузка ...

Новичок

Профиль
Группа: Участник
Сообщений: 3
Регистрация: 8.5.2005

Репутация: нет
Всего: нет

Здравствуйте! Помогите, пожалуйста. Не могу создать компоненты во время работы программы, в частности, нужно создать столько CheckBox, сколько строк таблицы.

z-END

Дата 8.5.2005, 11:16 (ссылка)

(нет голосов)

Загрузка ...

прафесар™

Профиль
Группа: Комодератор
Сообщений: 3014
Регистрация: 13.3.2003
Где: Венья, Пиетари

Репутация: 11
Всего: 102

поиск -> "создание компонента" -> Искать "Delphi" ->найти

--------------------

Каждый чилавек пасвоему праф...а памоему НЕТ!

Негодяй

Дата 8.5.2005, 16:00 (ссылка)

(нет голосов)

Загрузка ...

Порядочный

Профиль
Группа: Завсегдатай
Сообщений: 1513
Регистрация: 13.2.2005
Где: Kazakhstan, Almat y

Репутация: нет
Всего: 32

Вот из какой-то давно скаченной статьи:

Создание "кнопки" во время работы приложения:

1. Для начала необходимо объявить переменную класса TButton.
2. Затем необходимо указать владельца кнопки.
3. Необходимо указать родителя кнопки.
затем можно указать координаты, ширину, высоту и т.д. и необходимо указать саму процедуру, выполняемую с помощью созданного компонента. Код:

Код


unit ButtonPAS;

interface

uses
  Windows, Messages, SysUtils, Variants, Classes, Graphics, Controls, Forms,
  Dialogs, StdCtrls;

type
  TForm1 = class(TForm)
    procedure Click1(Sender:TObject);
    procedure FormCreate(Sender: TObject);

  private
    { Private declarations }
  public
  Btn:TButton; //Объявление переменной типа TButton
    { Public declarations }
  end;

var
  Form1: TForm1;

implementation

{$R *.dfm}

procedure TForm1.Click1(Sender: TObject);
begin
  Form1.Caption:='Yahoo!'
end;

procedure TForm1.FormCreate(Sender: TObject);
begin
btn:=TButton.Create(Self); //Объявление владецльца компонента
  Btn.Parent:=Self; //Объявление родителя компонента
  //Объявление координат компонента на форме:
  btn.Left:=10;
  Btn.Top:=2;
  Btn.Width:=80; // Установление длины компонента
  Btn.Caption:='Click here!'; // Установление надписи компонента
  Btn.OnClick:=Click1; // Присвоение процедуры компоненту
end;

end.

А также код для создания множества компонентов:

Код


unit ArrayOfButtonPAS;

interface

uses
  Windows, Messages, SysUtils, Variants, Classes, Graphics, Controls, Forms,
  Dialogs, StdCtrls;

type
  TForm1 = class(TForm)
  procedure Click1(Sender:TObject); // Объявление процедуры для массива компонентов
  procedure Click2(Sender:TObject); // Объявление процедуры для первого компонента
  procedure FormCreate(Sender: TObject);


  private
    { Private declarations }
  public
  Btn:TButton; //Объявление переменной
  Btns:array[1..10] of TButton; // Объявление массива компонентов
    { Public declarations }
  end;

var
  Form1: TForm1;

implementation

{$R *.dfm}
procedure TForm1.Click1(Sender: TObject);
var Name:string;
begin
  Name:=(Sender as TComponent).Name;
  Form1.Caption:='Щелчок по кнопке '+Name;
end;

procedure TForm1.Click2(Sender: TObject);
var I:integer; // Объявляем счетчик цикла
begin
  For I:=1 to 10 do begin // Создаем в цикле компоненты
  btns[I]:=TButton.Create(Self); // Объявляем владельца компонента
  Btns[I].Parent:=Self; // Объявление родителя компонента
  Btns[I].Left:=10; // Установка координат компонен6та
  Btns[I].Top:=I*35;
  Btns[I].Width:=80; // Установка длины компонента
  Btns[I].Caption:='New button '+inttostr(I); // Установка надписи компонента
  Btns[I].OnClick:=Click1; // Присвоение процедуры компоненту
  Btns[I].Name:='NewButton'+inttostr(I); // Присвоение имени компоненту
end;
end;


procedure TForm1.FormCreate(Sender: TObject);
begin
btn:=TButton.Create(Self); //Объявление владецльца компонента
  Btn.Parent:=Self; //Объявление родителя компонента
  btn.Left:=10; //Объявление координат компонента на форме
  Btn.Top:=2; // ==============
  Btn.Width:=80; // Установление длины компонента
  Btn.Caption:='Click here!'; // Установление надписи компонента
  Btn.OnClick:=Click2; // Присвоение процедуры компоненту
end;

end.

Alex

Дата 8.5.2005, 22:07 (ссылка)

(нет голосов)

Загрузка ...

Эксперт

Профиль
Группа: Экс. модератор
Сообщений: 4147
Регистрация: 25.3.2002
Где: Москва

Репутация: 80
Всего: 162

http://forum.vingrad.ru/index.php?act=modu...faq§ion=627

--------------------

Написать можно все - главное четко представлять, что ты хочешь получить в конце.

Payne

Дата 9.5.2005, 09:29 (ссылка)

(нет голосов)

Загрузка ...

Детектив

Профиль
Группа: Участник
Сообщений: 247
Регистрация: 6.4.2005
Где: Петербург

Репутация: 4
Всего: 10

Цитата(ylana @ 8.5.2005, 11:12)

нужно создать столько CheckBox, сколько строк таблицы

Зависит от того, какую таблицу ты собираешься юзать. Могу предложить тебе пример для простой таблицы StringGrid:

Код


unit Unit1;

interface

uses
  Windows, Messages, SysUtils, Variants, Classes, Graphics, Controls, Forms,
  Dialogs, Grids, StdCtrls;
  //не забудь объявить модуль StdCtrls, иначе компоненты создать не получится

type
  TForm1 = class(TForm)
    StringGrid1: TStringGrid;
    procedure FormCreate(Sender: TObject);
    procedure FormDestroy(Sender: TObject);
  private
    { Private declarations }
  public
    { Public declarations }
  end;

var
  Form1: TForm1;
  cb: array of TCheckBox;
  {cb - это массив CheckBox'ов. Как видишь, массив динамический - потому, что тебе не известно...}
  {...сколько строк будет в таблице}

implementation

{$R *.dfm}

{я создаю компоненты при создании формы, но ты можешь использовать тот обработчик...}
{...который более удобен.}
procedure TForm1.FormCreate(Sender: TObject);
var
  i: integer;
begin
  SetLength (cb, StringGrid1.RowCount); //устанавливаем длину массива - она равна кол-ву строк таблицы
  for i := 0 to StringGrid1.RowCount-1 do //и организуем цикл создания элементов CheckBox.
  begin
    cb[i] := TCheckBox.Create(self);
    cb[i].Parent := Self;
    cb[i].Left := 10;
    cb[i].Top := i*20;
    cb[i].Caption := 'CheckBox' + ' ' + IntToStr(i+1);
    cb[i].Name := 'CheckBox' + IntToStr(i+1);
  end;
end;

procedure TForm1.FormDestroy(Sender: TObject);
var
  i: integer;
begin
  for i := 0 to StringGrid1.RowCount-1 do cb[i].Destroy; //это не обязательно, хотя лучше освободить память
end;

end.

З.Ы. Заметь, что динамический массив имеет индексы, начинающиеся с нуля, а не с единицы, как у обычных массивов.

z-END

Дата 9.5.2005, 10:11 (ссылка)

(нет голосов)

Загрузка ...

прафесар™

Профиль
Группа: Комодератор
Сообщений: 3014
Регистрация: 13.3.2003
Где: Венья, Пиетари

Репутация: 11
Всего: 102

Цитата(Payne @ 9.5.2005, 10:29)

З.Ы. Заметь, что динамический массив имеет индексы, начинающиеся с нуля, а не с единицы, как у обычных массивов

это как?! Тоесть такой вариант не прокатит?!

Код


var i: Array [0..254] of Char;
...
i[0] := 'A';

--------------------

Каждый чилавек пасвоему праф...а памоему НЕТ!

Payne

Дата 9.5.2005, 11:40 (ссылка)

(нет голосов)

Загрузка ...

Детектив

Профиль
Группа: Участник
Сообщений: 247
Регистрация: 6.4.2005
Где: Петербург

Репутация: 4
Всего: 10

z-END: да, что-то я глуманул, согласен smile

. Просто привычка уже - всегда задавать массив как array [1..n] of .... Ладно, будем считать, что я имел в виду, что динамический массив всегда имеет индексы, начинающиеся с нуля, в отличие от статических массивов, которые можно индексировать так, как удобнее программисту. smile

Гость_ylana

Дата 10.5.2005, 11:07 (ссылка)

(голосов: 0)

Загрузка ...

Unregistered

Всем большое спасибо за ответы!

0 Пользователей читают эту тему (0 Гостей и 0 Скрытых Пользователей)
0 Пользователей:
« Предыдущая тема \| Delphi: Общие вопросы \| Следующая тема »