VPF::Ошибка при компиляции - Форум программистов

splash666

Дата 19.7.2005, 12:52 (ссылка)

(нет голосов)

Загрузка ...

Новичок

Профиль
Группа: Участник
Сообщений: 27
Регистрация: 15.7.2005
Где: Россия, г.Самара

Репутация: нет
Всего: нет

Суь такова- при добавлении нового события, ЛЮБОГО- будь то реакция на мышку или что либо еще, вылетает ошибка- что то с чем то, не найдено INITIALIZATION в Unit Source. И это только для 3й формы. На 1й и 2й форме всё ок! С чем это может быть связано??

~FoX~

Дата 19.7.2005, 12:56 (ссылка)

(нет голосов)

Загрузка ...

НЕ рыжий!!!

Профиль
Группа: Участник Клуба
Сообщений: 2819
Регистрация: 8.10.2003
Где: Зеленоград

Репутация: 13
Всего: 68

splash666
Код в студию.....

--------------------

…множественность никогда не следует полагать без необходимости…

splash666

Дата 19.7.2005, 13:07 (ссылка)

(нет голосов)

Загрузка ...

Вот код полного юнита. На форме Image, Shape & Timer:

Код


unit Unit3;

interface

uses
  Jpeg,Windows, Messages, SysUtils, Variants, Classes, Graphics, Controls, Forms,
  Dialogs, ExtCtrls;

type
   TRGBArray = array[Word] of TRGBTriple;
   pRGBArray = ^TRGBArray;

  TForm3 = class(TForm)
    Image1: TImage;
    Shape1: TShape;
    Timer1: TTimer;
    procedure openfile(name:string);
    procedure SmoothResize(Src, Dst: TBitmap);
    procedure ResizeImage(MaxWidth: Integer);
    procedure FormShow(Sender: TObject);

  private
    { Private declarations }
  public
    position:integer
  end;

var
  Form3: TForm3;

implementation
uses unit1;
{$R *.dfm}



procedure TForm3.openfile(name:string);
var
  pich,picw:integer;
begin
  form1.GetParams;
  image1.Picture.LoadFromFile(name);

  pich:=form1.nh;
  picw:=round(pich*4/3);

  image1.Height:=form1.nh;
  image1.Width:=picw;

  clientHeight:=form1.Nh;
  clientWidth:=picw;

  resizeImage(round(form1.nh*4/3));
  shape1.Height:=form1.nh;
  shape1.Width:=form1.nw;
  shape1.Top:=0;
  shape1.left:=0;
end;

procedure Tform3.SmoothResize(Src, Dst: TBitmap);
 var
   x, y: Integer;
   xP, yP: Integer;
   xP2, yP2: Integer;
   SrcLine1, SrcLine2: pRGBArray;
   t3: Integer;
   z, z2, iz2: Integer;
   DstLine: pRGBArray;
   DstGap: Integer;
   w1, w2, w3, w4: Integer;
 begin
   Src.PixelFormat := pf24Bit;
   Dst.PixelFormat := pf24Bit;
   if (Src.Width = Dst.Width) and (Src.Height = Dst.Height) then
     Dst.Assign(Src)
   else
   begin
     DstLine := Dst.ScanLine[0];
     DstGap  := Integer(Dst.ScanLine[1]) - Integer(DstLine);
     xP2 := MulDiv(pred(Src.Width), $10000, Dst.Width);
     yP2 := MulDiv(pred(Src.Height), $10000, Dst.Height);
     yP  := 0;
     for y := 0 to pred(Dst.Height) do
     begin
       xP := 0;
       SrcLine1 := Src.ScanLine[yP shr 16];
       if (yP shr 16 < pred(Src.Height)) then
         SrcLine2 := Src.ScanLine[succ(yP shr 16)]
       else
         SrcLine2 := Src.ScanLine[yP shr 16];
       z2  := succ(yP and $FFFF);
       iz2 := succ((not yp) and $FFFF);
       for x := 0 to pred(Dst.Width) do
       begin
         t3 := xP shr 16;
         z  := xP and $FFFF;
         w2 := MulDiv(z, iz2, $10000);
         w1 := iz2 - w2;
         w4 := MulDiv(z, z2, $10000);
         w3 := z2 - w4;
         DstLine[x].rgbtRed := (SrcLine1[t3].rgbtRed * w1 +
           SrcLine1[t3 + 1].rgbtRed * w2 +
           SrcLine2[t3].rgbtRed * w3 + SrcLine2[t3 + 1].rgbtRed * w4) shr 16;
         DstLine[x].rgbtGreen :=
           (SrcLine1[t3].rgbtGreen * w1 + SrcLine1[t3 + 1].rgbtGreen * w2 +
           SrcLine2[t3].rgbtGreen * w3 + SrcLine2[t3 + 1].rgbtGreen * w4) shr 16;
         DstLine[x].rgbtBlue := (SrcLine1[t3].rgbtBlue * w1 +
           SrcLine1[t3 + 1].rgbtBlue * w2 +
           SrcLine2[t3].rgbtBlue * w3 +
           SrcLine2[t3 + 1].rgbtBlue * w4) shr 16;
         Inc(xP, xP2);
       end; {for}
       Inc(yP, yP2);
       DstLine := pRGBArray(Integer(DstLine) + DstGap);
     end; {for}
   end; {if}
 end; {SmoothResize}

procedure Tform3.ResizeImage(MaxWidth: Integer);
 var
   jpg:TJpegImage;
   OldBitmap: TBitmap;
   NewBitmap: TBitmap;
 begin
   jpg:=TJpegImage.Create;
   try
   jpg.Assign(image1.picture.Graphic);
   OldBitmap := TBitmap.Create;
     try
     oldBitmap.Assign(jpg);
     begin
        begin
         NewBitmap := TBitmap.Create;
         try
           NewBitmap.Width  := MaxWidth;
           NewBitmap.Height := MulDiv(MaxWidth, OldBitmap.Height, OldBitmap.Width);
           SmoothResize(OldBitmap, NewBitmap);
           jpg.Assign(NewBitmap);
           image1.Picture.Assign(jpg);
         finally
           NewBitmap.Free;
         end; {try}
       end; {if}
     end; {if}
   finally
     OldBitmap.Free;
   end; {try}
  finally
    jpg.Free;
  end;
end;

procedure TForm3.FormShow(Sender: TObject);
begin
  position:=0;
  openfile(form1.ListBox2.Items[0]);
end;

end.

Добавлено @ 13:11
Конкретный текст окна с ошибкой:

Could not find source location to add method Shape1ContextPopup. "END." or INITIALIZATION not found in unit source.
Добавлено @ 13:12
Прошу прошения за код. не знал как вставлять smile

Это сообщение отредактировал(а) Girder - 19.7.2005, 13:11

Rennigth

Дата 19.7.2005, 13:27 (ссылка)

(нет голосов)

Загрузка ...

Эксперт

Профиль
Группа: Участник Клуба
Сообщений: 1708
Регистрация: 21.6.2004
Где: Moscow

Репутация: 49
Всего: 76

А ты в VCLе (ExtCtrls) случайно не прибил какого-нибудь енда...

--------------------

(* Honesta mors turpi vita potior *)

splash666

Дата 19.7.2005, 13:42 (ссылка)

(нет голосов)

Загрузка ...

Rennigth, нет вроде. Всё начало глючить после того, как кинул на форму timer и перегрузил дельфи

~FoX~

Дата 19.7.2005, 14:56 (ссылка)

(нет голосов)

Загрузка ...

НЕ рыжий!!!

Профиль
Группа: Участник Клуба
Сообщений: 2819
Регистрация: 8.10.2003
Где: Зеленоград

Репутация: 13
Всего: 68

public
position:integer; '<----Точку с запятой не поставил!

Внимательнее надо быть smile

Это сообщение отредактировал(а) ~FoX~ - 19.7.2005, 14:56

--------------------

…множественность никогда не следует полагать без необходимости…

splash666

Дата 20.7.2005, 10:32 (ссылка)

(нет голосов)

Загрузка ...

~FoX~, СПАСИБО!!!! Я уж обмучался, искал ошибку. А оказалась такая мелочь)))) Спасибо!

~FoX~

Дата 20.7.2005, 11:07 (ссылка)

(нет голосов)

Загрузка ...

НЕ рыжий!!!

Профиль
Группа: Участник Клуба
Сообщений: 2819
Регистрация: 8.10.2003
Где: Зеленоград

Репутация: 13
Всего: 68

splash666
[off]Я сам такой же, просто когда нмежду двух языков прыгаешь автоматом синтаксис теряется, то в барсике строку заканчиваю ";", то в паскале for...next пишу [/off] smile

--------------------

…множественность никогда не следует полагать без необходимости…

0 Пользователей читают эту тему (0 Гостей и 0 Скрытых Пользователей)
0 Пользователей:
« Предыдущая тема \| Delphi: Общие вопросы \| Следующая тема »