VPF::Всплывающая подсказка - Форум программистов

Disconnect

Дата 9.10.2005, 13:06 (ссылка)

(нет голосов)

Загрузка ...

Юрист & web-programmer

Профиль
Группа: Участник
Сообщений: 117
Регистрация: 13.6.2005
Где: Из неоткуда!& #33;!!!

Репутация: 1
Всего: 0

Народ помогите сделать так что б , при навидении на кнопку - рядом с ней появлялась подсказка(информация)

З.Ы Спа...............

--------------------

A permanent repe of the wistful elementa carnival elephant dancing on the cloudstwo times the killer thet created the betrayerhe stood there and watched it all.

NetWorm

Дата 9.10.2005, 16:31 (ссылка)

(нет голосов)

Загрузка ...

Шустрый

Профиль
Группа: Участник
Сообщений: 56
Регистрация: 20.9.2005
Где: Karaganda

Репутация: -1
Всего: нет

Создай символ кнопки и в ней во втором кадре (Over) помести мувиклип с информацией(Можешь зделать постепенно появляющимся)
Хочешь сделать чтобы он бегал за мышкой зайди внутрь (Этого клипа) выдели все что есть
нажми F8 -> поставь галочку на Movieclip и в экшене получившегося мувика напиши

Код


onClipEvent (enterFrame) {
    startDrag(this, true);
}

Таким образом должен получиться в кнопке мувик в мувике. (Button-> Movieclip-> Movieclip)Экшен в последнем.
Все это можно сделать прогамно. smile

Это сообщение отредактировал(а) NetWorm - 9.10.2005, 16:32

AlDev

Дата 9.10.2005, 16:39 (ссылка)

(нет голосов)

Загрузка ...

Опытный идиотъ

Профиль
Группа: Участник Клуба
Сообщений: 1927
Регистрация: 17.4.2005
Где: Irk, rus

Репутация: 9
Всего: 50

Код


/**
 * @author Alex Batsuev
 * Jul 28, 2005
 */
 
class com.batsuev.UI.hint
{
    public var border_enabled:Boolean;
    public var border_color:Number;
    public var background_enabled:Boolean;
    public var background_color:Number;
    
    private var hint_mc:MovieClip;
    private var hint_tf:TextField;
    
    public var hint_width:Number;
    public var hint_height:Number;
    
    public var text:String;
    public var horizontal_position:String;
    public var vertical_position:String;
    public var text_format:TextFormat;
    //----------------------------------------
    public function hint(target_mc:MovieClip)
    {
        this.background_enabled = true;
        this.background_color = 0xFFFFFF;
        this.border_enabled = true;
        this.border_color = 0x000000;
        this.text_format = new TextFormat();
        this.text_format.align = 'center';
        this.text_format.font = 'Verdana';
        this.horizontal_position = 'center';
        this.vertical_position = 'top';
        var i:Number = new Number();
        while (target_mc._parent['hintInstanceMovie_'+i.toString()]!=undefined)
        {
            i++;
        }
        this.hint_mc = target_mc._parent.createEmptyMovieClip('hintInstanceClip',target_mc._parent.getNextHighestDepth());
        var ths:Object = this;
        target_mc.onRollOver = target_mc.onDragOver = function():Void
        {
            ths.show();
        }
        target_mc.onRollOut = target_mc.onDragOut = function()
        {
            ths.hide();
        }
    }
    //----------------------------------------
    private function show():Void
    {
        var x_pos:Number = this.hint_mc._xmouse;
        var y_pos:Number = this.hint_mc._ymouse;
        var dx:Number = 0;
        var dy:Number = 0;
        var ths:Object = this;
        this.hint_mc.createTextField('hintTF',this.hint_mc.getNextHighestDepth(),x_pos,y_pos,this.hint_width,this.hint_height);
        this.hint_tf = this.hint_mc['hintTF'];
        if ((this.hint_width==undefined)||(this.hint_height==undefined))
        {
            this.hint_tf.autoSize = true;
        }
        this.hint_tf.selectable = false;
        this.hint_tf.text = this.text;
        this.hint_tf.background = this.background_enabled;
        this.hint_tf.backgroundColor = this.background_color;
        this.hint_tf.border = this.border_enabled;
        this.hint_tf.borderColor = this.border_color;
        this.hint_tf.setTextFormat(this.text_format);
        switch (this.horizontal_position)
        {
            case 'left':
              dx = -this.hint_tf._width;
            break;
            case 'center':
              dx = -0.5*this.hint_tf._width;
            break;
        }
        switch (this.vertical_position)
        {
            case 'top':
              dy = -this.hint_tf._height;
            break;
            case 'bottom':
              dy = 17;
            break;
        }

        this.hint_tf._x += dx;
        this.hint_tf._y += dy;
        this.hint_mc.onMouseMove = function()
        {
            ths.hint_tf._x = this._xmouse + dx;
            ths.hint_tf._y = this._ymouse + dy;
        }
    }
    //----------------------------------------
    private function hide():Void
    {
        this.hint_tf.removeTextField();
        delete this.hint_mc.onMouseMove;
    }
}

usage sample:

Код


import com.batsuev.UI.hint

var smth_mc:MovieClip = this['clip_bla'];
var hint_instance:hint = new hint(smth_mc);
hint_instance.text = 'Test';

давно писал... но вроде должно работать

настраивается:

Код


    border_enabled - вкл/выкл рамки
    border_color:Number - цвет рамки
    background_enabled:Boolean - вкл/выкл заливки
    background_color:Number - цвет заливки
    
    hint_width:Number - ширина подсказки
    hint_height:Number - высота подсказки
    
    text:String - текст подсказки
    horizontal_position:String - горизонтальная позиция по отношению к курсору ('left','center','right')
    vertical_position:String - ертикальная позиция по отношению к курсору ('top','bottom');
    text_format:TextFormat - формат текста подсказки

1 Пользователей читают эту тему (1 Гостей и 0 Скрытых Пользователей)
0 Пользователей:
« Предыдущая тема \| Flash \| Следующая тема »