VPF::Прога на паскале - Форум программистов

Гость_Евгений

Дата 22.11.2005, 15:59 (ссылка)

(голосов: 0)

Загрузка ...

Unregistered

Дана целочисленная матрица 5х10. Вывести номер её первой/последней строки/столбца, содержащего равное кол-во положительных и отрицательных элементов(нулевые элементы не учитываются). Если таких строк/столбцов нет, то вывести 0.

kent

Дата 22.11.2005, 18:46 (ссылка)

(нет голосов)

Загрузка ...

Шустрый

Профиль
Группа: Участник
Сообщений: 83
Регистрация: 6.5.2005
Где: Russia

Репутация: 1
Всего: 1

Делал для первой строки и последнего столбца, остальное сделаешь по аналогии...

Код


uses Crt;
const
     M = 5;
     N = 10;
type
    TMatrix = array [1..M,1..N] of Integer;

{------------------------------------------------------}
Procedure ReadMatrix(var A : TMatrix);
var i,j : Integer;
begin
     for i := 1 to M do
        for j := 1 to N do begin
           Write('Element[',i,',',j,']:');
           ReadLn(A[i,j]);
        end;
end;
{------------------------------------------------------}

{------------------------------------------------------}
Procedure WriteMatrix(A : TMatrix);
var i,j : Integer;
begin
     for i := 1 to M do begin
        for j := 1 to N do
           Write(A[i,j]:4);
        WriteLn;
     end;
end;
{------------------------------------------------------}

{------------------------------------------------------}
Function FirstString(A : TMatrix) : Integer;
var i,j : Integer;
    count_pos,count_neg : Integer;
begin
     FirstString := 0;
     for i := 1 to M do begin
        count_pos := 0;
        count_neg := 0;
        for j := 1 to N do begin
           if (A[i,j] > 0) then
             inc(count_pos)
           else if (A[i,j] < 0) then
             inc(count_neg);
        end;
        if (count_pos = count_neg) then begin
          FirstString := i;
          Exit;
        end;
     end;
end;
{------------------------------------------------------}

{------------------------------------------------------}
Function LastColumn(A : TMatrix) : Integer;
var i,j : Integer;
    count_pos,count_neg : Integer;
begin
     LastColumn := 0;
     for j := 1 to N do begin
        count_pos := 0;
        count_neg := 0;
        for i := 1 to M do begin
           if (A[i,j] > 0) then
             inc(count_pos)
           else if (A[i,j] < 0) then
             inc(count_neg);
        end;
        if (count_pos = count_neg) then
          LastColumn := j;
     end;
end;
{------------------------------------------------------}

var A : TMatrix;
begin
     Clrscr;
     WriteLn('Input Matrix:');
     ReadMatrix(A);
     WriteLn;
     WriteLn('Sources Matrix:');
     WriteMatrix(A);
     WriteLn;
     WriteLn('First String:',FirstString(A),';');
     WriteLn('Last Column:',LastColumn(A),';');
     ReadKey;
end.

Guest

Дата 23.11.2005, 13:01 (ссылка)

(голосов: 0)

Загрузка ...

Unregistered

спасибо!!! примного благодарен...

0 Пользователей читают эту тему (0 Гостей и 0 Скрытых Пользователей)
0 Пользователей:
« Предыдущая тема \| Центр помощи \| Следующая тема »