VPF::Задача про треугольгики - Форум программистов

zarogon

Дата 12.12.2005, 17:40 (ссылка)

(нет голосов)

Загрузка ...

Шустрый

Профиль
Группа: Участник
Сообщений: 62
Регистрация: 4.11.2005
Где: Украина, Киев

Репутация: нет
Всего: нет

Люди кто знает как решить такую задачку: Заданы координаты вершин двух треугольников, определить: 1) какой из них больше по площади; 2)находиться хотябы одна вершина первого треугольника внутри второго; 3)находиться ли второй треугольник внутри первого.

Премного благодарен

sergejzr

Дата 12.12.2005, 17:48 (ссылка)

(нет голосов)

Загрузка ...

Un salsero
Group Icon

Профиль
Группа: Админ
Сообщений: 13285
Регистрация: 10.2.2004
Где: Германия г .Ганновер

Репутация: 11
Всего: 360

Почитай, подумай. Выведи формулы, по которым можно решать. Затем выпиши формулы на языке программирования (кстати на каком?)

--------------------

Me.
FB.
LinkedIn.
ORCID.
YT.

darkart

Дата 12.12.2005, 23:33 (ссылка)

(нет голосов)

Загрузка ...

Опытный

Профиль
Группа: Участник
Сообщений: 379
Регистрация: 9.11.2005

Репутация: 26
Всего: 31

Вроде потестил, но ты ещё погоняй:

Код


program ZarTrian;
const
  VertexCount=3;{количество вершин}
type
  TPoint=record{орисание координат точки}
    x,y:integer;
  end;
  TTriangle=array[1..VertexCount] of TPoint;{орисание треугольника}
procedure InputDataForTriangle(var Triangle:TTriangle);
{ввод значений ккординат для треугольника}
var
  i:integer;
begin
  for i:=1 to VertexCount do
  begin
    writeln('Please enter x coordinate of ',i,' vertex:');
    readln(Triangle[i].x);
    writeln('Please enter y coordinate of ',i,' vertex:');
    readln(Triangle[i].y);
  end;
end;
function SquareOfTriangle(var T:TTriangle):real;
{вычисление площади треугольника}
var
  a,b,c,p:real;
begin
  a:=sqrt(sqr(T[2].x-T[3].x)+sqr(T[2].y-T[3].y));
  b:=sqrt(sqr(T[1].x-T[3].x)+sqr(T[1].y-T[3].y));
  c:=sqrt(sqr(T[1].x-T[2].x)+sqr(T[1].y-T[2].y));
  p:=(a+b+c)/2;
  SquareOfTriangle:=sqrt(p*(p-a)*(p-b)*(p-c));
end;
function IsPointInTriangle(var T:TTriangle;P:TPoint):boolean;
{ф-ция проверяет лежит ли точка в треугольнике}
const
  Eps=1e-6;{точность}
var
  i:integer;
  SBig:real;{площадь всего треугольника}
  tmp:TTriangle;{вспомогательный треугольник}
begin
  tmp:=T;
  Sbig:=SquareOfTriangle(tmp);
  for i:=1 to VertexCount do
  begin
    tmp[i]:=P;{замена вершины}
    SBig:=SBig-SquareOfTriangle(tmp);{минусуем площадь полученную в рез-те замены вершины}
    tmp[i]:=T[i];{обратная замена}
  end;
  IsPointinTriangle:=(abs(Sbig)<Eps);{если площадь равна 0 с точностью Eps}
end;
function IsHaveOnePoint(var T1,T2:TTriangle):boolean;
{имеется ли хотя бы одна вершина T2 в T1 }
var
  bolResult:boolean;
  i:integer;
begin
  bolResult:=False;
  for i:=1 to VertexCount do
    bolResult:=bolResult or (IsPointInTriangle(T1,T2[i]));
  IsHaveOnePoint:=bolResult;
end;
function IsTriangleInTriangle(var T1,T2:TTriangle):boolean;
{лежит ли T2 в T1}
var
  i:integer;
  bolResult:boolean;
begin
  bolResult:=True;
  for i:=1 to VertexCount do
    bolResult:=bolResult and (IsPointInTriangle(T1,T2[i]));
  IsTriangleInTriangle:=bolResult;
end;
var
  Triangle1,Triangle2:TTriangle;
begin
  writeln('Please enter data for 1 triangle');
  InputDataForTriangle(Triangle1);
  writeln('Please enter data for 2 triangle');
  InputDataForTriangle(Triangle2);
  writeln('1:');
  if SquareOfTriangle(Triangle1)>SquareOfTriangle(Triangle2) then
    writeln('Square of first triangle is bigger then square of second triangle')
  else if SquareOfTriangle(Triangle2)>SquareOfTriangle(Triangle1) then
         writeln('Square of second triangle is bigger then square of first triangle')
       else
         writeln('Square of first triangle = square of second triangle');
  writeln('2:');
  if IsHaveOnePoint(Triangle1,Triangle2) then
    writeln('You have point')
  else
    writeln('You have not point');
  writeln('3:');
  if IsTriangleInTriangle(Triangle1,Triangle2) then
    writeln('Second Triangle in first Triangle')
  else
    writeln('Second triangle no in first triangle');
  readln;
end.

0 Пользователей читают эту тему (0 Гостей и 0 Скрытых Пользователей)
0 Пользователей:
« Предыдущая тема \| Центр помощи \| Следующая тема »