VPF::список экспоритируемых ф-ций из подключаемой DLL

Max111

Дата 18.1.2006, 15:31 (ссылка)

(нет голосов)

Загрузка ...

Новичок

Профиль
Группа: Участник
Сообщений: 28
Регистрация: 18.1.2006

Репутация: нет
Всего: нет

Доброе утро,

Преамбула:
Долго ругались с заказчиком и выяснилось что, я использую
в своей программе вызовы устаревших ф-ций из DLL заказчика.

Вопрос:
Я знаю что, при помощи ф-ции “GetProcAddress”
можно получить адрес экспортируемой ф-ции из DLL и совершенно спокойно работать с ним. Но данная работа насколько я понимаю возможна только если знаешь имя экспортируемой ф-ции.
В связи с длительными спорами с заказчиком (он спокойно изменяет имена ф-ций в новых версиях DLL(s))
Возникла следующая мысль:

Можно ли получить в своей программе весь список экспоритируемых ф-ций,
Из подключаемой DLL?

С огромным вниманием выслушаю любые советы.

Максим

[email protected]

AndreyANM

Дата 18.1.2006, 15:37 (ссылка)

(нет голосов)

Загрузка ...

Шустрый

Профиль
Группа: Участник
Сообщений: 57
Регистрация: 4.1.2006

Репутация: нет
Всего: нет

Вот примеры процедур (Взяты из DelphiWorld)

Я сам их не проверял.

Код


{ **** UBPFD *********** by delphibase.endimus.com ****
>> Получение списка экспорта dll

Функция GetImageFunctionList возвращает список всех экспортируемых функций dll
FileName - имя dll
Strings - объетк, в который будут занесен список экспорта.
ВАЖНО! Тестировано только под NT4

Зависимости: Windows, ImageHlp
Автор:       Mystic, [email protected], ICQ:125905046, Харьков
Copyright:   Mystic
Дата:        21 апреля 2002 г.
***************************************************** }

function EnumSymbols(SymbolName: PChar; SymbolAddress, SymbolSize: ULONG;
  Strings: Pointer): Bool; stdcall;
begin
  TStrings(Strings).Add(SymbolName);
  Result := True;
end;

function GetImageFunctionList(const FileName: string; Strings: TStrings):
  Boolean;

var
  Handle: THandle;
  hProcess: THandle;
  VersionInfo: TOSVersionInfo;
begin
  Strings.Clear;
  Result := False;

  SymSetOptions(SYMOPT_UNDNAME or SYMOPT_DEFERRED_LOADS);

  VersionInfo.dwOSVersionInfoSize := SizeOf(VersionInfo);
  if not GetVersionEx(VersionInfo) then
    Exit;

  if VersionInfo.dwPlatformId = VER_PLATFORM_WIN32_WINDOWS then
    hProcess := GetCurrentProcessId
  else
    hProcess := GetCurrentProcess;

  if not SymInitialize(hProcess, nil, True) then
    Exit;
  try
    Handle := LoadLibrary(PChar(FileName));
    if Handle = 0 then
      Exit;
    try
      if not SymLoadModule(hProcess, 0, PChar(FileName), nil, Handle, 0) then
        Exit;
      try
        if not SymEnumerateSymbols(hProcess, Handle, EnumSymbols, Strings) then
          Exit;
      finally
        SymUnloadModule(hProcess, Handle);
      end;
    finally
      FreeLibrary(Handle);
    end;
  finally
    SymCleanup(hProcess);
  end;
  Result := True;
end;

Пример использования:

if not GetImageFunctionList('kernel32.dll', ListBox1.Items) then
raise Exception.Create('Произошла ошибка');

Код


if not GetImageFunctionList('kernel32.dll', ListBox1.Items) then
  raise Exception.Create('Произошла ошибка');

Код


uses
   ImageHlp;

 procedure ListDLLExports(const FileName: string; List: TStrings);
 type
   TDWordArray = array [0..$FFFFF] of DWORD;
 var
   imageinfo: LoadedImage;
   pExportDirectory: PImageExportDirectory;
   dirsize: Cardinal;
   pDummy: PImageSectionHeader;
   i: Cardinal;
   pNameRVAs: ^TDWordArray;
   Name: string;
 begin
   List.Clear;
   if MapAndLoad(PChar(FileName), nil, @imageinfo, True, True) then
   begin
     try
       pExportDirectory := ImageDirectoryEntryToData(imageinfo.MappedAddress,
         False, IMAGE_DIRECTORY_ENTRY_EXPORT, dirsize);
       if (pExportDirectory <> nil) then
       begin
         pNameRVAs := ImageRvaToVa(imageinfo.FileHeader, imageinfo.MappedAddress,
           DWORD(pExportDirectory^.AddressOfNames), pDummy);
         for i := 0 to pExportDirectory^.NumberOfNames - 1 do
         begin
           Name := PChar(ImageRvaToVa(imageinfo.FileHeader, imageinfo.MappedAddress,
             pNameRVAs^[i], pDummy));
           List.Add(Name);
         end;
       end;
     finally
       UnMapAndLoad(@imageinfo);
     end;
   end;
 end;

 procedure TForm1.Button1Click(Sender: TObject);
 var
   List: TStrings;
   i: Integer;
   s: string;
 begin
   List := TStringList.Create;
   try
     ListDLLExports('C:\WINDOWS\SYSTEM32\browseui.dll', List);
     ShowMessage(IntToStr(list.Count) + ' functions in dll');
     s := 'List of functions:';
     for i := 0 to List.Count - 1 do
       s := s + #13#10+List[i];
     ShowMessage(S);
   finally
     List.Free
   end;
 end;

Есть еще множество похожих функций..

Max111

Дата 22.1.2006, 18:34 (ссылка)

(нет голосов)

Загрузка ...

Новичок

Профиль
Группа: Участник
Сообщений: 28
Регистрация: 18.1.2006

Репутация: нет
Всего: нет

Большое спасибо

Получение списка экспортируемых ф-ций произошло.

Но остался один не выясненый вопрос:
можно ли получить данный список с параметрами и типами этих ф-ций?

Void

Дата 22.1.2006, 19:25 (ссылка)

(нет голосов)

Загрузка ...

λcat.lolcat

Профиль
Группа: Участник Клуба
Сообщений: 2206
Регистрация: 16.11.2004
Где: Zürich

Репутация: нет
Всего: 173

Цитата(Max111 @ 22.1.2006, 20:34

)

можно ли получить данный список с параметрами и типами этих ф-ций?

Если коротко: нет.

Такую информацию иногда вставляют в имя экспортируемой функции компиляторы C++, но это не ваш случай.

Для таких целей COM прекрасно подходит, но DLL не ваша...

--------------------

“Coming back to where you started is not the same as never leaving.” — Terry Pratchett

Max111

Дата 22.1.2006, 19:28 (ссылка)

(нет голосов)

Загрузка ...

Новичок

Профиль
Группа: Участник
Сообщений: 28
Регистрация: 18.1.2006

Репутация: нет
Всего: нет

Доброе утро,

Уважаемый Void, если можно поподробнее с этого.

Правда
Я даже не знаю как правильно задать вопрос:
но проблемма в следующем.

А на каком принципе основано импортирование библиотек в среде Дельфи.
может быть мне пойти этим путем?

Fin

Дата 22.1.2006, 19:38 (ссылка)

(нет голосов)

Загрузка ...

Дракон->Спать();

Профиль
Группа: Участник
Сообщений: 687
Регистрация: 4.1.2006

Репутация: 1
Всего: 10

Таким же способом, как и на других языках. Если библиотека подключена статически, то винда грузит ее во время загрузки программы. Если подключение динамическое, то программа грузит по мере надобности. Потом идет настройка линков на открытые функции. И запуск DllMain с параметром DLL_PROCESS_ATTACH.

В самой библиотеке не хранятся данные о параметрах функции. Хотя если функцию писать с параметром stdcall, компилятор изврашается и пишет в имя функции длину всех параметров. Как правило это стараются убить, так как такие надписи зависят очень сильно от компилятора. И это не удобно в дальнейшем использовании.
Добавлено @ 19:41
В любом случае, тебе должны предоставлятся загаловочные файлы библиотеки. Иначе все это изобретание велосипеда.

--------------------

Пролетал мимо.

rsm

Дата 23.1.2006, 14:16 (ссылка)

(нет голосов)

Загрузка ...

Опытный

Профиль
Группа: Участник Клуба
Сообщений: 999
Регистрация: 16.3.2005

Репутация: 1
Всего: 62

В теории, определение количества аргументов функции производится так - с самого начала функции ищем инструкции вида:

Код


     mov reg,[ebp+Z]

где: reg - некоторый регистр (eax, ebx...), Z - число от 8 и до N. Просматривая все такие инструкции, смотрим, где число N максимально. Затем делим это число на 4 - получаем количество параметров функции. Данный способ универсален для всех типов функций кроме fastcall. Однако в нем есть еще несколько хитростей (о них я не написал).

Для stdcall & pascal способ проще - ищем в конце функции инструкцию вида:

Код


     ret Z

Делим Z на 4 - получаем количество аргументов.

Для cdecl количество параметров определяется по инструкции вида:

Код


     add esp,Z
     ; или
     sub esp,-Z

, идущей следом за вызовом функции. Делим Z на 4 - получаем количество аргументов.

Это сообщение отредактировал(а) rsm - 23.1.2006, 14:19

0 Пользователей читают эту тему (0 Гостей и 0 Скрытых Пользователей)
0 Пользователей:
« Предыдущая тема \| Delphi: WinAPI и системное программирование \| Следующая тема »