Здравствуйте.
Есть полностью рабочий код, но чувствую что не до конца его понимаю
| Код |
move(state(X,X,G,C),state(Y,Y,G,C)):-opposite(X,Y). /* FARMER + WOLF */
move(state(X,W,X,C),state(Y,W,Y,C)):-opposite(X,Y). /* FARMER + GOAT */
move(state(X,W,G,X),state(Y,W,G,Y)):-opposite(X,Y). /*FARMER + CABBIDGE*/
move(state(X,W,G,C),state(Y,W,G,C)):-opposite(X,Y). /* ONLY FARMER */
opposite(east,west).
opposite(west,east).
unsafe( state(F,X,X,_) ):- opposite(F,X).
unsafe( state(F,_,X,X) ):- opposite(F,X).
path(S,G,L,L1):-
move(S,S1),
not( unsafe(S1) ),
not( member(S1,L) ),
path( S1,G,[S1|L],L1),!.
path(G,G,T,T):-!. /* The final state is reached */
go:- go(state(east,east,east,east),state(west,west,west,west)).
go(S,G):-
path(S,G,[S],L),
nl,write('A solution is:'),nl,
write_path(L),
fail.
go(_,_).
member(X,[X|_]).
member(X,[_|L]):-member(X,L).
write_move( state(X,W,G,C), state(Y,W,G,C) ) :-!,
write('The farmer crosses the river from '),
write(X),
write(' to '),
write(Y),nl.
write_move( state(X,X,G,C), state(Y,Y,G,C) ) :-!,
write('The farmer takes the Wolf from '),
write(X),
write(' of the river to '),
write(Y),nl.
write_move( state(X,W,X,C), state(Y,W,Y,C) ) :-!,
write('The farmer takes the Goat from' ),
write(X),
write(' of the river to '),
write(Y),nl.
write_move( state(X,W,G,X), state(Y,W,G,Y) ) :-!,
write('The farmer takes the cabbage from '),
write(X),
write(' of the river to '),
write(Y),nl.
write_path( [H1,H2|T] ) :- !,
write_move(H1,H2),write_path([H2|T]).
write_path( _ ).
|
Трудно выразить что именно мне непонятно поэтому, попробую описать ход своей мысли
| Цитата |
Нахождение решения начинается с ввода команды go.
После этого начинается проверка истинности предиката go.
go(_,_). - означает что он всегда будет истинным (зачем это нужно точно незнаю)
go(S,G) - берёт в качестве своих аргументов state(east,east,east,east),state(west,west,west,west) и является истинным в случае истинности предикатов
path(S,G,[S],L),
nl,write('A solution is:'),nl,
write_path(L),
fail.
Зачем тут нужен fail - тоже дял меня не ясно. (можен он связан с go(_,_). ?)
Проверяется истинность предиката path(S,G,[S],L), где L - это путь получаемый при выполнении проверки данного предиката?
Дальше проверяется на истинность предикат
path(S,G,L,L1):-
move(S,S1),
not( unsafe(S1) ),
not( member(S1,L) ),
path( S1,G,[S1|L],L1),!.
path(G,G,T,T):-!.
Но я что-то тут совсем запутался.
|
Может как-то кто-то может подсказать, вывести меня на истинное понимание этого примера?
Добавлено @ 13:18
Пример я сам взял http://www.mari.ru/mmlab/home/prolog/LECTION6/index.html если что. |
)
Это все-таки Пролог, а не императивный язык, и move в данном случае - нечто вроде булевой функции, проверяющей возможность выполнения той или иной перевозки. Конструкция с fail в предикате go заставляет цель path все время передоказываться, при этом пролог-машина перебирает различные варианты перемещений, а move отбирает из них допустимые.