Цитата(Bulat @ 2.10.2007, 06:00  ) | | Я так понял, объявление переменных внутри класса, инкапсулирует их ??? |
Как сказал cerf_machine, инкапсуляция отсутсвует, как таковая, это философия Perl. Но, Perl позволяет сделать закрытость ещё более надёжную, чем другие языки программирования, разумеется, если это нужно. 
Например можно таким образом изменить класс Person, который я приводил выше.
| Код |
package Person;
# Конструктор класса Person
sub new {
my $check = shift;
my $class = ref($check) || $check;
# Поля класса
my $fields = {
NAME => "",
FAMILY => "",
AGE => 0, @_
};
my $self = sub {
my $field = shift;
my $f = (caller)[1];
# Если запрос сделан не из текущего файла, умираем с музыкой
die "This class using only private fields. For get or set value to " .
"private fields, use access methods get/setName(), " .
"get/setFamily(), get/setAge()." unless $f eq __FILE__;
$fields->{$field} = shift if (@_);
return $fields->{$field};
};
# Посвящаем ссылку в объект и возвращаем его
bless($self, $class);
return $self;
}
################################################################################
# Методы доступа #
################################################################################
# Метод возвращает имя человека
sub getName {
shift->("NAME");
}
# Метод возвращает фамилию человека
sub getFamily {
return shift->("FAMILY");
}
# Метод возвращает возраст человека
sub getAge {
return shift->("AGE");
}
# Метод меняет имя человека
sub setName {
my $self = shift;
$self->("NAME", @_) if scalar @_;
}
# Метод меняет фамилию человека
sub setFamily {
my $self = shift;
$self->("FAMILY", @_) if scalar @_;
}
# Метод меняет возраст человека
sub setAge {
my $self = shift;
$self->("AGE", @_) if scalar(@_) && $_[0] > 0;
}
################################################################################
# Имитируем перегруженный метод. Если метод получает число, оно прибавляется #
# к возрасту, если же метод был вызван без параметров, то добавляем к возрасту #
# единицу. #
################################################################################
sub addAge {
my $self = shift;
my $add = (scalar(@_) && ($_[0] =~ /^\d+$/) && ($_[0] > 0)) ? shift : 1;
$self->("AGE", $self->("AGE") + $add);
}
1;
|
Вот собственно мы и закрылись, теперь поля доступны только внутри файла Person.pm, т.е. мы получили private поля. Можно так же сделать и protected, ну или что-то похожее на protected поля в Java, если изменить условие в конструкторе:
| Код |
my $f = (caller)[1];
# Если запрос сделан не из текущего файла, умираем с музыкой
die "This class using only private fields. For get or set value to " .
"private fields, use access methods get/setName(), " .
"get/setFamily(), get/setAge()." unless $f eq __FILE__;
|
на такое:
| Код |
my($p,$f) = caller;
# Если запрос сделан не из текущего пакета или не из наследника, умираем с музыкой
die "This class using only protected fields. For get or set value to " .
"private fields, use access methods get/setName(), " .
"get/setFamily(), get/setAge()." if (($p ne __PACKAGE__) || !$p->isa(__PACKAGE__))
|
Т.е. напрямую к полям теперь можно будет обращаться только из текущего пакета или же из классов наследников. Можно так же реализовать и закрытые методы, опять же, если это нужно.
| Цитата(Bulat @ 2.10.2007, 06:00 ) | | и тут главное соблюдат правильную последовательность переменных... При таком объявлении, возможно не соблюдение последовательности ??? |
Абсолютно верно, потому использовать анонимный хеш гораздо удобнее, не следует думать о перегрузке конструктора. Если же хочешь создать аналог создания Java или C++ объекта, то вместо анонимного хеша используй анонимный массив:
Вот так теперь будет выглядеть наш класс Person.pm
| Код |
package Person;
# Конструктор класса Person
sub new {
my $check = shift;
my $class = ref($check) || $check;
my $self = [ @_ ];
return bless($self,$class);
}
################################################################################
# Методы доступа #
################################################################################
# Метод возвращает имя человека
sub getName {
shift->[0];
}
# Метод возвращает фамилию человека
sub getFamily {
return shift->[1];
}
# Метод возвращает возраст человека
sub getAge {
return shift->[2];
}
# Метод меняет имя человека
sub setName {
my $self = shift;
$self->[0] = shift if scalar @_;
}
# Метод меняет фамилию человека
sub setFamily {
my $self = shift;
$self->[1] = shift if scalar @_;
}
# Метод меняет возраст человека
sub setAge {
my $self = shift;
$self->[2] = shift if scalar(@_) && $_[0] > 0;
}
################################################################################
# Имитируем перегруженный метод. Если метод получает число, оно прибавляется #
# к возрасту, если же метод был вызван без параметров, то добавляем к возрасту #
# единицу. #
################################################################################
sub addAge {
my $self = shift;
my $add = (scalar(@_) && ($_[0] =~ /^\d+$/) && ($_[0] > 0)) ? shift : 1;
$self->[2] += $add;
}
1;
|
а вот программа, которая его использует:
| Код |
#!/usr/bin/perl -w
use strict;
use Person;
# Создаём массив объектов Person
my @people = (
new Person("Вася", "Пупкин", 16),
new Person("Коля", "Герасимов", 12),
new Person("Валя", "Брусникина", 20)
);
# Пройдём по всему массиву и покажем информацию о каждом человеке
foreach my $person (@people) {
print "Имя: " . $person->getName() . "\n";
print "Фамилия: " . $person->getFamily() . "\n";
print "Возраст: " . $person->getAge() . "\n\n";
}
# Следующая строка, просто разделитель
print "=" x 80, "\n";
################################################################################
# Теперь можно добавим каждому по одному году используюя метод addAge() без #
# параметров. И снова покажем весь список. #
################################################################################
for (my $i=0; $i < scalar(@people); $i++) {
# Я намеренно использовал цикл for с переменной - счётчиком,
# так, для разнообразия.
$people[$i]->addAge();
}
################################################################################
# Покажем заново всех людей из нашего массива, так как нам массив дальше не #
# понадобится, то обнуляем массив и попутно выводим информацию окаждом клиете #
################################################################################
while (my $person = shift @people) {
print "Имя: " . $person->getName() . "\n";
print "Фамилия: " . $person->getFamily() . "\n";
print "Возраст: " . $person->getAge() . "\n\n";
}
|
Кстати, можно так же заюзать псевдо-хеш, хотя они сейчас помечены как depricated, но в Perl можно реализовать что-то похожее на псевдо-хеш вручную, а можно так же и не вручную, например заюзав прагму компилятора fields 
| Цитата(Bulat @ 2.10.2007, 06:17 ) | | М-дя, и в догонку очень важный вопрос о деструкторах... В яве-то их ручками писать не надо, а как насчет перла ?? |
В Perl сборка мусора происходит тоже автоматически, примерно так же, как и в Java, потому деструкторы нужно юзать, как сказал nitr, только в исключительных случаях. |
переопределение функций не собственно-написных модулей или классов, а чего-нить из более стандартного.. Например какая-нить функция из того же DBI или CGI..