Модераторы: Poseidon, Snowy, bems, MetalFan

Поиск:

Ответ в темуСоздание новой темы Создание опроса
> перетаскивание в tringGrid 
:(
    Опции темы
Неопытный
Дата 6.12.2006, 09:36 (ссылка) | (нет голосов) Загрузка ... Загрузка ... Быстрая цитата Цитата


Шустрый
*


Профиль
Группа: Участник
Сообщений: 84
Регистрация: 21.11.2006

Репутация: нет
Всего: нет
Как организовать в компоненте StringGrid перетаскивание содержимого одной ячейки в другую? Может кто пробовал сделать...
PM MAIL   Вверх
x77
Дата 6.12.2006, 12:25 (ссылка) | (нет голосов) Загрузка ... Загрузка ... Быстрая цитата Цитата


Эксперт
***


Профиль
Группа: Участник Клуба
Сообщений: 1255
Регистрация: 25.3.2002

Репутация: 19
Всего: 22
в пустом проекте на форму кидаем стрингрид, и пишем:

Код

unit Unit1;

interface

uses
  Windows, Messages, SysUtils, Variants, Classes, Graphics, Controls, Forms,
  Dialogs, Grids;

type
  TForm1 = class(TForm)
    StringGrid1: TStringGrid;
    procedure FormCreate(Sender: TObject);
    procedure StringGrid1DragOver(Sender, Source: TObject; X, Y: Integer;
      State: TDragState; var Accept: Boolean);
    procedure StringGrid1DragDrop(Sender, Source: TObject; X, Y: Integer);
    procedure StringGrid1MouseDown(Sender: TObject; Button: TMouseButton;
      Shift: TShiftState; X, Y: Integer);
  private
    { Private declarations }
    StartCol,
    StartRow: integer;
  public
    { Public declarations }
  end;

var
  Form1: TForm1;

implementation

{$R *.dfm}

procedure TForm1.FormCreate(Sender: TObject);
var
  ACol, ARow: integer;
begin
  // Заполним StringGrid1 всякой мурой
  Randomize;
  with StringGrid1 do begin
    for ARow := FixedRows to RowCount - 1 do
      for ACol := FixedCols to ColCount - 1 do
        Cells [ACol, ARow] := IntToStr (Random (High (integer)));
  end;
end;

procedure TForm1.StringGrid1MouseDown(Sender: TObject;
  Button: TMouseButton; Shift: TShiftState; X, Y: Integer);
begin
  // Запоминаем ячейку и начинаем перетаскивать, если юзер двинул мыша на 10 пикселов
  StringGrid1.MouseToCell(X, Y, StartCol, StartRow);
  StringGrid1.BeginDrag(False, 10);
end;

procedure TForm1.StringGrid1DragOver(Sender, Source: TObject; X,
  Y: Integer; State: TDragState; var Accept: Boolean);
begin
  // Пока над StringGrid1 - всегда можно сбросить
  Accept := (Sender = Source);
end;

procedure TForm1.StringGrid1DragDrop(Sender, Source: TObject; X,
  Y: Integer);
var
  EndCol,
  EndRow: integer;
begin
  // Выясняем куда, и копируем ячейку, над которой началось перетаскивание  
  with StringGrid1 do begin
    MouseToCell (X, Y, EndCol, EndRow);
    Cells [EndCol, EndRow] := Cells [StartCol, StartRow];
  end;
end;

end.



--------------------
Я никогда не сопротивлялся искушению, поскольку узнал: что мне
не нравится, то меня не искушает. © Джордж Бернард Шоу (Ирландия)
PM MAIL ICQ   Вверх
Неопытный
Дата 6.12.2006, 12:55 (ссылка) | (нет голосов) Загрузка ... Загрузка ... Быстрая цитата Цитата


Шустрый
*


Профиль
Группа: Участник
Сообщений: 84
Регистрация: 21.11.2006

Репутация: нет
Всего: нет
Спасибо, попробую
PM MAIL   Вверх
Неопытный
Дата 6.12.2006, 13:26 (ссылка) | (нет голосов) Загрузка ... Загрузка ... Быстрая цитата Цитата


Шустрый
*


Профиль
Группа: Участник
Сообщений: 84
Регистрация: 21.11.2006

Репутация: нет
Всего: нет
Еще раз спасибо - попробовал работает. У меня сначала было затруднение в том, что я не знал что есть метод MouseToCell, писал свою проц преобразующую X,Y в Acol, Arow.
Еще вопросик: а как сделать чтобы в момент когда перетаскиваем в на курсоре отображалось, что перетаскиваем.
PM MAIL   Вверх
x77
Дата 6.12.2006, 14:07 (ссылка) | (нет голосов) Загрузка ... Загрузка ... Быстрая цитата Цитата


Эксперт
***


Профиль
Группа: Участник Клуба
Сообщений: 1255
Регистрация: 25.3.2002

Репутация: 19
Всего: 22
у меня есть подозрение, что для таких вещей нужно писать своего наследника от TDragObject (это если "по науке"). но я обычно делаю так:

Код

unit Unit1;

interface

uses
  Windows, Messages, SysUtils, Variants, Classes, Graphics, Controls, Forms,
  Dialogs, Grids, ExtCtrls;

type
  TForm1 = class(TForm)
    StringGrid1: TStringGrid;
    Panel1: TPanel;
    Image1: TImage;
    procedure FormCreate(Sender: TObject);
    procedure StringGrid1DragOver(Sender, Source: TObject; X, Y: Integer;
      State: TDragState; var Accept: Boolean);
    procedure StringGrid1DragDrop(Sender, Source: TObject; X, Y: Integer);
    procedure StringGrid1MouseDown(Sender: TObject; Button: TMouseButton;
      Shift: TShiftState; X, Y: Integer);
    procedure StringGrid1StartDrag(Sender: TObject;
      var DragObject: TDragObject);
    procedure StringGrid1EndDrag(Sender, Target: TObject; X, Y: Integer);
  private
    { Private declarations }
    StartCol,
    StartRow: integer;
    StartX,
    StartY: integer;
  public
    { Public declarations }
  end;

var
  Form1: TForm1;
  Image: TImage;

implementation

uses Types;

{$R *.dfm}

procedure TForm1.FormCreate(Sender: TObject);
var
  ACol, ARow: integer;
begin
  // Çàïîëíèì StringGrid1 âñÿêîé ìóðîé
  Randomize;
  with StringGrid1 do begin
    for ARow := FixedRows to RowCount - 1 do
      for ACol := FixedCols to ColCount - 1 do
        Cells [ACol, ARow] := IntToStr (Random (High (integer)));
  end;
end;

procedure TForm1.StringGrid1MouseDown(Sender: TObject;
  Button: TMouseButton; Shift: TShiftState; X, Y: Integer);
begin
  // Çàïîìèíàåì ÿ÷åéêó è íà÷èíàåì ïåðåòàñêèâàòü, åñëè þçåð äâèíóë ìûøà íà 10 ïèêñåëîâ
  StartX := X;
  StartY := Y;
  StringGrid1.MouseToCell(X, Y, StartCol, StartRow);
  StringGrid1.BeginDrag(False, 10);
end;

procedure TForm1.StringGrid1DragOver(Sender, Source: TObject; X,
  Y: Integer; State: TDragState; var Accept: Boolean);
begin
  // Ïîêà íàä StringGrid1 - âñåãäà ìîæíî ñáðîñèòü
  Accept := (Sender = Source);
  Panel1.Left := X + 20;
  Panel1.Top := Y + 20;
end;

procedure TForm1.StringGrid1DragDrop(Sender, Source: TObject; X,
  Y: Integer);
var
  EndCol,
  EndRow: integer;
begin
  // Âûÿñíÿåì êóäà, è êîïèðóåì ÿ÷åéêó, íàä êîòîðîé íà÷àëîñü ïåðåòàñêèâàíèå
  with StringGrid1 do begin
    MouseToCell (X, Y, EndCol, EndRow);
    Cells [EndCol, EndRow] := Cells [StartCol, StartRow];
  end;
end;

procedure TForm1.StringGrid1StartDrag(Sender: TObject;
  var DragObject: TDragObject);
var
  Rect: TRect;
  bmp: TBitmap;
begin
  bmp := TBitmap.Create;
  try
    Rect := StringGrid1.CellRect(StartCol, StartRow);
    bmp.Width := Rect.Right - Rect.Left;
    bmp.Height := Rect.Bottom - Rect.Top;
    BitBlt (bmp.Canvas.Handle, 0, 0, bmp.Width, bmp.Height,
      StringGrid1.Canvas.Handle, Rect.Left, Rect.Top, SRCCOPY);
    Image1.Picture.Bitmap.Assign(bmp);
  finally
    bmp.Free;
  end;
  Panel1.Left := StartX + 20;
  Panel1.Top := StartY + 20;
  Panel1.Visible := TRUE;
end;

procedure TForm1.StringGrid1EndDrag(Sender, Target: TObject; X,
  Y: Integer);
begin
  Panel1.Visible := FALSE;
end;

end.


здесь на форму кладётся TPanel (AutoSize := TRUE, Visible := FALSE) и TImage (AutoSize := TRUE). в момент начала перетаксивания в TImage копируется участок канвы грида, и в панельке таскается вслед за курсором (т.е. программного изменения курсора не происходит). когда перетаскивания окончено - панелька прячется. для пущей красоты имеет смысл выставить TStringGrid.DragCursor в crDefault.


--------------------
Я никогда не сопротивлялся искушению, поскольку узнал: что мне
не нравится, то меня не искушает. © Джордж Бернард Шоу (Ирландия)
PM MAIL ICQ   Вверх
Неопытный
Дата 6.12.2006, 14:35 (ссылка) | (нет голосов) Загрузка ... Загрузка ... Быстрая цитата Цитата


Шустрый
*


Профиль
Группа: Участник
Сообщений: 84
Регистрация: 21.11.2006

Репутация: нет
Всего: нет
Попробовал ваш последний вариант, к сожалению не работает. Визуально разницы между первым и вторым вариантом нет
PM MAIL   Вверх
x77
Дата 6.12.2006, 15:00 (ссылка) | (нет голосов) Загрузка ... Загрузка ... Быстрая цитата Цитата


Эксперт
***


Профиль
Группа: Участник Клуба
Сообщений: 1255
Регистрация: 25.3.2002

Репутация: 19
Всего: 22
Неопытный, проверьте ещё раз.... потому что у меня работает smile



Присоединённый файл ( Кол-во скачиваний: 15 )
Присоединённый файл  untitled.JPG 19,22 Kb


--------------------
Я никогда не сопротивлялся искушению, поскольку узнал: что мне
не нравится, то меня не искушает. © Джордж Бернард Шоу (Ирландия)
PM MAIL ICQ   Вверх
Неопытный
Дата 6.12.2006, 16:01 (ссылка) | (нет голосов) Загрузка ... Загрузка ... Быстрая цитата Цитата


Шустрый
*


Профиль
Группа: Участник
Сообщений: 84
Регистрация: 21.11.2006

Репутация: нет
Всего: нет
Блин проверил вроде все, не работает!

Присоединённый файл ( Кол-во скачиваний: 7 )
Присоединённый файл  ___________.rar 4,57 Kb
PM MAIL   Вверх
x77
Дата 6.12.2006, 16:12 (ссылка) | (нет голосов) Загрузка ... Загрузка ... Быстрая цитата Цитата


Эксперт
***


Профиль
Группа: Участник Клуба
Сообщений: 1255
Регистрация: 25.3.2002

Репутация: 19
Всего: 22
1. ни один обработчик для грида не  был назначен.
2. Image1 должен был лежать на Panel1, а не рядом smile

zip archive, почему-то, загрузить не могу smile


--------------------
Я никогда не сопротивлялся искушению, поскольку узнал: что мне
не нравится, то меня не искушает. © Джордж Бернард Шоу (Ирландия)
PM MAIL ICQ   Вверх
Неопытный
Дата 6.12.2006, 16:22 (ссылка) | (нет голосов) Загрузка ... Загрузка ... Быстрая цитата Цитата


Шустрый
*


Профиль
Группа: Участник
Сообщений: 84
Регистрация: 21.11.2006

Репутация: нет
Всего: нет
Цитата

1. ни один обработчик для грида не  был назначен.

простите это как
PM MAIL   Вверх
x77
Дата 6.12.2006, 16:26 (ссылка) | (нет голосов) Загрузка ... Загрузка ... Быстрая цитата Цитата


Эксперт
***


Профиль
Группа: Участник Клуба
Сообщений: 1255
Регистрация: 25.3.2002

Репутация: 19
Всего: 22
Неопытный, у меня D7, а не BDS. я подозреваю, что это из-за этого...  когда я открыл программу, у меня вкладка Events у Object Inspector'a для StringGrid1 была совершенно пуста. т.е. обработчики есть, но соответствующим событиям они не присвоены.


--------------------
Я никогда не сопротивлялся искушению, поскольку узнал: что мне
не нравится, то меня не искушает. © Джордж Бернард Шоу (Ирландия)
PM MAIL ICQ   Вверх
Неопытный
Дата 6.12.2006, 16:33 (ссылка) | (нет голосов) Загрузка ... Загрузка ... Быстрая цитата Цитата


Шустрый
*


Профиль
Группа: Участник
Сообщений: 84
Регистрация: 21.11.2006

Репутация: нет
Всего: нет
У меня у меня на вкладке Events, вроде все нормально. 
Цитата

Image1 должен был лежать на Panel1, а не рядом 

Это было, исправил - не помогло.
PM MAIL   Вверх
x77
Дата 6.12.2006, 16:37 (ссылка) | (нет голосов) Загрузка ... Загрузка ... Быстрая цитата Цитата


Эксперт
***


Профиль
Группа: Участник Клуба
Сообщений: 1255
Регистрация: 25.3.2002

Репутация: 19
Всего: 22
переименовал архив в txt. имейте в виду, что на самом деле он обжат 7z.

почему зипованные файлы загружать нельзя? smile

Это сообщение отредактировал(а) x77 - 6.12.2006, 16:37

Присоединённый файл ( Кол-во скачиваний: 4 )
Присоединённый файл  pr3.txt 1,76 Kb


--------------------
Я никогда не сопротивлялся искушению, поскольку узнал: что мне
не нравится, то меня не искушает. © Джордж Бернард Шоу (Ирландия)
PM MAIL ICQ   Вверх
Неопытный
Дата 6.12.2006, 16:47 (ссылка) | (нет голосов) Загрузка ... Загрузка ... Быстрая цитата Цитата


Шустрый
*


Профиль
Группа: Участник
Сообщений: 84
Регистрация: 21.11.2006

Репутация: нет
Всего: нет
Простите, что мне с ним делать, переименовать в Zip и расп-ть
PM MAIL   Вверх
x77
Дата 6.12.2006, 16:50 (ссылка) | (нет голосов) Загрузка ... Загрузка ... Быстрая цитата Цитата


Эксперт
***


Профиль
Группа: Участник Клуба
Сообщений: 1255
Регистрация: 25.3.2002

Репутация: 19
Всего: 22
Неопытный, угу. опять не выйдет - я просто вобью в пост dfm и pas файлы.


--------------------
Я никогда не сопротивлялся искушению, поскольку узнал: что мне
не нравится, то меня не искушает. © Джордж Бернард Шоу (Ирландия)
PM MAIL ICQ   Вверх
Ответ в темуСоздание новой темы Создание опроса
Правила форума "Delphi: Общие вопросы"
SnowyMetalFan
bemsPoseidon
Rrader

Запрещается!

1. Публиковать ссылки на вскрытые компоненты

2. Обсуждать взлом компонентов и делиться вскрытыми компонентами

  • Литературу по Дельфи обсуждаем здесь
  • Действия модераторов можно обсудить здесь
  • С просьбами о написании курсовой, реферата и т.п. обращаться сюда
  • Вопросы по реализации алгоритмов рассматриваются здесь
  • 90% ответов на свои вопросы можно найти в DRKB (Delphi Russian Knowledge Base) - крупнейшем в рунете сборнике материалов по Дельфи

Если Вам понравилась атмосфера форума, заходите к нам чаще! С уважением, Snowy, MetalFan, bems, Poseidon, Rrader.
 
0 Пользователей читают эту тему (0 Гостей и 0 Скрытых Пользователей)
0 Пользователей:
« Предыдущая тема | Delphi: Общие вопросы | Следующая тема »

Подписаться на тему | Подписка на этот форум | Скачать/Распечатать тему


 




[ Время генерации скрипта: 0.0567 ]   [ Использовано запросов: 22 ]   [ GZIP включён ]


Реклама на сайте     Информационное спонсорство

 
 По вопросам размещения рекламы пишите на vladimir(sobaka)vingrad.ru
Отказ от ответственности     Powered by Invision Power Board(R) 1.3 © 2003  IPS, Inc.