VPF::TTabSet'a Delphi2006 и OnDoubleClick - Форум программистов

Delphist

Дата 14.3.2007, 14:44 (ссылка)

(нет голосов)

Загрузка ...

Delphist Эксперт

Профиль
Группа: Завсегдатай
Сообщений: 2145
Регистрация: 3.2.2004
Где: всегда в сети

Репутация: 2
Всего: 3

Как для TTabSet'a Delphi2006 сделать генератор события двойного клик по вкладке?

--------------------

ProcessInfo 1-ая моя программа (аналог spyxx.exe с гораздо большим функц-ом - внедрение dll в адр. простр. процесса, перехват API-функций, разбор приложения на окна мн.др).
Когда-то давным-давно использовал это...

ama_kid

Дата 14.3.2007, 15:08 (ссылка)

(нет голосов)

Загрузка ...

АСУТП-кодер

Профиль
Группа: Комодератор
Сообщений: 1460
Регистрация: 5.3.2007
Где: Москва

Репутация: 15
Всего: 95

Не знаю, чем отличается Д2006 от 7-го, но у меня проканывает так:

Код


var
   Old_Proc:pointer;


function TabSetProc(Window: HWnd; Message: Cardinal; wParam: WPARAM; lParam: LPARAM): LRESULT; stdcall;
begin
  case Message of
    WM_LBUTTONDBLCLK: begin
                        ShowMessage('Yo');
                      end;
  end;
  Result := CallWindowProc(old_proc, Window, Message, wParam, lParam);
end;
...
// Устанавливаем новую оконную процедуру
 Old_Proc:=pointer(GetWindowLong(TabSet1.Handle,GWL_WNDPROC));
 SetWindowLong(TabSet1.Handle,GWL_WNDPROC,integer(@TabSetProc));
...

Активную вкладку уж придется самому определять....

Это сообщение отредактировал(а) ama_kid - 14.3.2007, 15:09

--------------------

самурай без меча подобен самураю с мечом, но только без меча

Delphist

Дата 14.3.2007, 15:18 (ссылка)

(нет голосов)

Загрузка ...

Delphist Эксперт

Профиль
Группа: Завсегдатай
Сообщений: 2145
Регистрация: 3.2.2004
Где: всегда в сети

Репутация: 2
Всего: 3

Цитата(ama_kid @ 14.3.2007, 16:08

)

integer(@TabSetProc));

Из-за этого параметра Delphi выдает ошибку: Variable required.

--------------------

ama_kid

Дата 14.3.2007, 15:22 (ссылка)

(нет голосов)

Загрузка ...

АСУТП-кодер

Профиль
Группа: Комодератор
Сообщений: 1460
Регистрация: 5.3.2007
Где: Москва

Репутация: 15
Всего: 95

У меня в SDK написано:

Цитата

LONG SetWindowLong(
    HWND hWnd,    // handle of window
    int nIndex,    // offset of value to set
    LONG dwNewLong  // new value
   );

Посмотри, что написано у тебя и приведи к соответствующему типу... Если не прокатит - заведи переменную того типа, который указан для третьего параметра этой функции и присвой ей адрес оконной процедуры табсета и в SetWindowLong передавай эту переменную...

Это сообщение отредактировал(а) ama_kid - 14.3.2007, 15:23

--------------------

самурай без меча подобен самураю с мечом, но только без меча

VICTAR

Дата 14.3.2007, 15:31 (ссылка)

(нет голосов)

Загрузка ...

Эксперт

Профиль
Группа: Участник
Сообщений: 1108
Регистрация: 6.10.2006

Репутация: 37
Всего: 80

Код


unit Unit1;

interface

uses
  Windows, Messages, SysUtils, Variants, Classes, Graphics, Controls, Forms,
  Dialogs, Tabs;

type
  TForm1 = class(TForm)
    TabSet1: TTabSet;
    procedure FormCreate(Sender: TObject);
    Procedure NewTabCtrlWndProc( var AMessage: TMessage );
  private
    { Private declarations }
  public
    { Public declarations }
  end;

var
  Form1: TForm1;
  FOldTCWndProc: TWndMethod;

implementation

{$R *.dfm}

procedure TForm1.FormCreate(Sender: TObject);
begin
  FOldTCWndProc := TabSet1.WindowProc;
  TabSet1.WindowProc := NewTabCtrlWndProc;
end;

procedure TForm1.NewTabCtrlWndProc(var AMessage: TMessage);
var i: integer;
begin
  if AMessage.Msg = WM_LBUTTONDBLCLK then
  begin
    i:=TabSet1.ItemAtPos(Point(AMessage.LParamLo,AMessage.LParamHi));
    if i<>-1 then ShowMessage(Format('DblClick на %s',[TabSet1.Tabs[i]]));
  end;
  FOldTCWndProc(AMessage);
end;


end.

За основу взят этот топик

Delphist

Дата 14.3.2007, 15:39 (ссылка)

(нет голосов)

Загрузка ...

Delphist Эксперт

Профиль
Группа: Завсегдатай
Сообщений: 2145
Регистрация: 3.2.2004
Где: всегда в сети

Репутация: 2
Всего: 3

Цитата(ama_kid @ 14.3.2007, 16:22

)

У меня в SDK написано:

Проблема была в том, что я TabSetProс всунул в public-раздел формы. Если же данную процедуру обявить вне класса TMainForm моей главной формы, то проблем не возникает, но возникает трудность в работе с объектами объявленные внутри формы TMainForm. Поэтому возникает вопрос как узнать адресс процедуры объявленной внутри класса формы?

Добавлено @ 15:44

Цитата(VICTAR @ 14.3.2007, 16:31

)

За основу взят этот топик

Спасибо!

--------------------

VICTAR

Дата 14.3.2007, 15:57 (ссылка)

(нет голосов)

Загрузка ...

Эксперт

Профиль
Группа: Участник
Сообщений: 1108
Регистрация: 6.10.2006

Репутация: 37
Всего: 80

Цитата(Delphist @ 14.3.2007, 15:39

)

Спасибо!

И еще, на всякий случай:

Код


Old_Proc:=pointer(GetWindowLong(TabSet1.Handle,GWL_WNDPROC));
SetWindowLong(TabSet1.Handle,GWL_WNDPROC,integer(@TabSetProc));

Можно заменить на

Код


Old_Proc:=pointer(SetWindowLong(TabSet1.Handle,GWL_WNDPROC,integer(@TabSetProc)));

The SetWindowLong function
Return Values
If the function succeeds, the return value is the previous value of the specified 32-bit integer.
If the function fails, the return value is zero. To get extended error information, call GetLastError.

0 Пользователей читают эту тему (0 Гостей и 0 Скрытых Пользователей)
0 Пользователей:
« Предыдущая тема \| Delphi: Общие вопросы \| Следующая тема »