VPF::Регулярные выражения в PL/SQL - Форум программистов

DimW

Дата 22.4.2010, 11:27 (ссылка)

(нет голосов)

Загрузка ...

Эксперт

Профиль
Группа: Завсегдатай
Сообщений: 1330
Регистрация: 24.2.2005
Где: Орёл

Репутация: 23
Всего: 44

Цитата(alt5000 @ 22.4.2010, 10:53

)

Я спросил

извини, я подумал это ответ - серьезно.

Zloxa

Дата 22.4.2010, 22:51 (ссылка)

(нет голосов)

Загрузка ...

Чо?

Профиль
Группа: Завсегдатай
Сообщений: 3473
Регистрация: 12.9.2008

Репутация: 37
Всего: 161

Цитата(corpsehunter @ 29.12.2007, 00:49

)

у меня Oracle 9i

owa_pattern

Цитата(alt5000 @ 22.4.2010, 10:53

)

в массив передать разделенные через сплит части строки

Можно сделать sql+регекспами, офигенски круто, лаконично - в одно выражение
А можно просто по пацански instr-ами, тупо, не интересно, но трошки-трошки шустрее...в пиццот раз лишто

Код


declare
  type varchar_table is table of varchar2(200);
  foo varchar_table;
  src varchar2(4000);
  start_time number;
 
  function regexp_split(src varchar2)
    return varchar_table
  is
    result varchar_table;
  begin
    select rtrim(regexp_substr(str,'[^,]+,?',1,level),',')
      bulk collect into result
      from (select src str from dual)
      connect by regexp_substr(str,'[^,]+,?',1,level) is not null;
    return result;
  end;
  function instr_split(src varchar2)
    return varchar_table
  is
    result varchar_table := varchar_table();
    cur_pos number := 1;
    next_pos number;
    len number := nvl(length(src),0);
  begin
    while cur_pos <= len loop
      next_pos := instr(src||',',',',cur_pos);
      result.extend(1);
      result(result.count):= substr(src,cur_pos,next_pos - cur_pos);
      cur_pos := next_pos + 1;
    end loop;
    return result;
  end;
begin
  src := '1';
  for i in 1..100
  loop
    src := src||','||sys_guid;
  end loop;
  start_time := dbms_utility.get_time;
  for i in 1..500
  loop
    foo := regexp_split(src);
  end loop;
  dbms_output.put_line('sql+regexp:'||(dbms_utility.get_time-start_time));
  start_time := dbms_utility.get_time;
  for i in 1..500
  loop
    foo := instr_split(src);
  end loop;
  dbms_output.put_line('pl/sql+instr:'||(dbms_utility.get_time-start_time));
end;
/
 
sql+regexp:4971
pl/sql+instr:10
 
PL/SQL procedure successfully completed

Цитата(DimW @ 22.4.2010, 10:40

)

а как насчет того, что тема обсуждалась два года назад

на то - пофиг, когда интересно

--------------------

Достоверно известно, что 89% людей доверяют статистике взятой с потолка smile

1 Пользователей читают эту тему (1 Гостей и 0 Скрытых Пользователей)
0 Пользователей:
« Предыдущая тема \| Oracle \| Следующая тема »