Народ!
У меня проблемка. При клике по контролу формы (прямоугольнику!) надо вывести в MessageBox его имя. Но функция, которую я намалякал, выводит имя активного объекта, а не того, по которому кликаю. Я думал, что можно каким-то образом при том же клике этот контрол активировать, и тогда бы вывелось его имя... Но выяснилось, что я не представляю, как можно активировать прямоугольник.

Подскажите, плиз, как из этого выпутаться

Событие OnClick происходит абстрактно в приложении, и нельзя определить где именно (косвенно - по смещению фокуса, но не все контролы его получают).
В то же время события OnMouseDown, OnMouseUp, etc. получают в качестве параметров координаты события в окне приложения (внимательно следить за ед. изм.!). Следовательно, перебрав все контролы и сравнив, можно выяснить, в тело какого контрола попадает клик. Возможно, следует учитывать также Hidden.
Трудности возникнут, если есть несколько видимых контролов один над другим. Или, скажем, с закладками. Как вывернуться тут - пока не знаю... впрочем взаимное расположение контролов известно на стадии дизайна, а если оно потом программно изменяется - это можно отслеживать.

Событие Click здесь наступает (если речь о прямоугольнике) в случае щелчка по линии границы. Это надо?
Тогда все просто - пишем свой код в процедуре обработки события:

Код

Private Sub Прямоугольник0_Click() MsgBox "Прямоугольник0" End Sub

Если надо во всей области прямоугольника, то не знаю, что и посоветовать. Попробуй вместо прямоугольника использовать Label соответственно оформленный.

Большое спасибо!


Ещё вопросик. Почти по этой же теме.

Вот смотрите. У меня два контрола. При клике по одному из них должно определяться его имя и помещаться в функцию. Например, чтобы при клике по нему выводилось сообщение с его именем (но вообще для разных целей, конечно). Для чего я это спрашиваю? Просто представьте, что этих контролов штук 50, или тыща - и для каждого прописывать функцию. Это ведь ужасно! А если имя будет определяться и помещаться в функцию, то хватит и её одной - она просто станет универсальной

Подскажите, пожалуйста.
Наверное, не только мне это интересно.

Дело в том, что невозможно понять пока ЦЕЛЬ всей этой заморочки. Не локальную маленькую по получению имени контрола, а за нафига это потребовалось...
Озвучь. Вдруг окажется, что задача имеет иное решение? ведь не свою среду визуального построения макетов поди пишешь...

Да это во многом пригодится может
Мне бы пока решение этой задачки, если можно.

Всё дело в том, что для решения моей проблемки уже практически всё сделано, кроме вот того, о что я попросил объяснить А если искать другое решение, то всё переделывать придётся.
Когда сделаю, обязательно расскажу!

А пока... Нет, в общих чертах я сейчас расскажу Например, зрительный зал (или школьный класс, или автостоянка, или ещё что-нибудь). Определение, занято ли место (разными способами, в зависимости от того, зал это зрительный, или конференционный, или стоянка) и добавление данных о человеке, занимающим данное место (например, телефон его, ФИО и проч.) через отдельную форму.

Алгоритм примерно такой при клике по контролу, означающему какое-то место на плане зала:
1. Передача в функцию имени места, то, о чём я и спрашиваю - номера его (имя контрола на плане зала)
2. Определение, занято или свободно место
3. Затем, если свободно, открыть форму для заполнения именно этого места. После принятия данных место считается занятым
4. Если место занято, то открыть форму очистки (освобождения) места
5. Ну и, в конце концов, обновление формы-плана зала (окраска занятых-незанятых мест в разные цвета)

Вот такие пироги. Первый пункт - вот чего прошу объяснить
Добавлено @ 18:24
Кстати, чё значит

Цитата

не свою среду визуального построения макетов поди пишешь...

???
Всё моё Личное

Заранее благодарю за помощь

Это сообщение отредактировал(а) АлексейМ - 29.8.2005, 18:20

И ты эту всю байду рисуешь ректанглами? да ты сам виноват - выбрал наихудший по реализации вариант. Замени просто кучу прямоугольников на массив (слышишь? МАССИВ!) лэйблов - и от твоих проблем ничего не останется... мало того что лабел принимает клик, так когда есть уцправляющий массив, он принимается как

Код

Private Sub Label1_Click(Index As Integer) ... End Sub

Так что не зря я с тебя тряс целю работы... а по коду от такой замены будет правка ну просто минимальная.

Спасибо огромное!

Когда я буду массив лэйблов использовать, всё-таки будет определятся имя конкретного лэйбла при клике по нему?

Цитата

Когда я буду массив лэйблов использовать, всё-таки будет определятся имя конкретного лэйбла при клике по нему?

Имя у них будет на всех одно. А вот индекс у каждого свой - и он передается обработчику события.

грубо - если у тебя 5 рядов по 5 лэйбаков, то

Код

Private Sub Label_Click(Index As Integer) ' Index может быть от 0 до 24 Row = Index \ 5 + 1 Col = Index MOD 5 + 1 End Sub

Ты эта... прежде чем спрашивать - попробуй...

Простейший способ создания массива контролов с управляющим массивом - это копирование-вставка в макете... при вставке второго экземпляра тебе будет предложено создать управляющий массив - согласись. Обработчики событий пиши ПОСЛЕ создания управляющего массива - иначе придется дописывать аргумент руками.

И не забудь отслеживать порядок расположения лэйблов по этому индексу. Да, индекс начинается с нуля.
Добавлено @ 09:29
Что еще удобно - достаточно в макете поместить 1 лабел с управляющим массивом, а остальные можно создавать из него в рантайме... но это потом, сперва со статическим массивом контролов разберись.

Спасибо!


P.S. Пробую прибамбасы форума

Эээ... Позвольте ещё вопросик - что такое лабел? В смысле по-русски...
А то чё-то в справке не нашёл
Я ещё немного новичок.

Label. Он же Надпись.

Понял.

Все хелпы перерыл, а как массив сделать, не нашёл. Подскажите, кто могет!

Чессно говоря, про массивы контролов в VB6 знаю, а в Access не встречал и есть большие сомнения, что они таки существуют.
Добавлено @ 08:07
Есть еще и такой вариант действий (не такой красивый, к сожалению, как с массивом) - создать функцию с параметром в общем модуле. Затем разместить Надписи на форме и в свойствах каждой на событие клик (или иное) прописать =ИмяФункции(Параметр). Зато здесь сам управляешь - какой лейбл какой параметр передает функции. При этом также как и с массивом изменения в алгоритм работы проги потребуется вносить только раз.

Спасибо!

Akina, правда ли можно массив лейблов в Access сделать? Если да, то как?
Заранее благодарю

АлексейМ
Это я дошел уже... одновременно модерю VB6 и Access - путаю... виноват, сорри.

Да, массив контролов действительно в Аксессе не создать.
Придется выворачиваться - у каждой надписи метод CLICK свой делать + единая процедура обработки:

Код

Private Sub Надпись0_Click()     Call Label_Click_Handler(0) End Sub Private Sub Надпись1_Click()     Call Label_Click_Handler(1) End Sub Private Sub Надпись2_Click()     Call Label_Click_Handler(2) End Sub ... Private Sub Label_Click_Handler(Index As Integer)     .... End Sub

Цитата(Akina @ 7.9.2005, 15:12)

Придется выворачиваться - у каждой надписи метод CLICK свой делать

Можно, конечно, и так тоже. Но =ИмяФункции(параметр) мне кажется проще и меньше кода

Цитата(Papirus @ 8.9.2005, 09:04)

Но =ИмяФункции(параметр) мне кажется проще и меньше кода

Именно это в моем примере и эмулируется... в Аксессе это невозможно, ибо не VB, а VBA. Так что не понял, к чему это ты сказал...

Цитата(Akina @ 8.9.2005, 10:07)

Цитата (Papirus @ 8.9.2005, 09:04) Но =ИмяФункции(параметр) мне кажется проще и меньше кода Именно это в моем примере и эмулируется... в Аксессе это невозможно, ибо не VB, а VBA. Так что не понял, к чему это ты сказал...

=ИмяФункции(параметр) - это прописывается в СВОЙСТВАХ надписи в поле "Нажатие клавиши" ВМЕСТО [процедура обработки события] и не требует создавать процедуру

Цитата(Akina @ 7.9.2005, 15:12)

Private Sub Надпись2_Click()     Call Label_Click_Handler(2) End Sub

Papirus
Это абсолютно то же самое по коду и по скорости... впрочем с точки зрения простоты ты совершенно прав...
Однако автоматизировать это будет не совсем просто... хотя в каждом контроле (надписи) можно указать свой параметр.

Цитата(Akina @ 8.9.2005, 14:11)

хотя в каждом контроле (надписи) можно указать свой параметр.

Вот именно. А автоматизировать разработку в любом случае здесь не удастся

Спасибо!!!!!

Цитата(Papirus @ 9.9.2005, 10:15)

А автоматизировать разработку в любом случае здесь не удастся

Хотя возможно именно в этом случае я и не прав. Ведь есть возможность указать в процедуре, например, создания лейбла:

Код

Dim I as Integer I=11 MyForm.MyLabel.OnClick = "=MyProcName(" & I & ")" .....

Цитата(Guest @ 11.9.2005, 11:38)

возможность указать в процедуре, например, создания лейбла:

Какая разница, в какой точке писАть индивидуальный для каждого контрола код?

Цитата(Akina @ 11.9.2005, 21:05)

Какая разница, в какой точке писАть индивидуальный для каждого контрола код?

Мож я чё не понял, но при создании коллекции лейблов программно, такой подход очень даж поможет добавить обработчики событий этим лейблам (текстбоксам, комбо, лист и т.д.)

Даа, ребята. прикольные советы даёте. А если придется 764 прямоугольника автоматом нарисовать и у всех их одно и то же событие обрабатывать? Например MouseMove? Написать в каждом контроле обработчик и потом чего-то куда-то какой-то функции скармливать? Как говориться, "легких путей не ищем" ))
А про модули классов кто-нибудь вообще слышал? Это так, подсказка.
))

А если поподробнее?
А то я уж задолбался к каждому контролу свою процедуру обработки прописывать - там не одна тыща строк получается.... Неужели всё-таки можно сделать что-то универсальное?

Полностью поддерживаю Papirusa . Просто и со вкусом, пусть и не очень круто. Главное что бы Леха сообразил. И вопрос к Akine : расскажи поподробнее как сделать такой массив, чтобы у всех надписей было одно имя. если не тяжело опубликуй кусок работающей проги, для размещения надписей с одним именем на обычной форме. Или ты имел в виду все надписи будут восприниматься как один объект? Тогда тем более интересно глянуть код программы. Лично я как ни крутил - но увы две надписи с одим и тем же именем не смог прилепить на форму. один объект - одно имя, это же его идентификация. Я не прав? Если да, то в чем? И опять же хочу пример

Ладно, девочки, вот вам пример. Естественно, вопреки пожеланиям трудящихся , никаких извращений вроде макросов не будет. Одинаковых имен контролов тоже - в VBA Access это невозможно, это возможно в простом VB.

К примеру, очень нам захотелось обрабатывать кучу одинаковых контролов. Пусть это будут надписи. Мы хотим, чтобы при наведении на надпись она меняла свой стиль, а при двойном клике - выводила своё имя. Хотим, чтобы имя оно в себе самой и писала. Естественно, на вечер у нас запланирована пьянка, но её нам придется пропустить, если нужно будет писать к каждому контролу обработчик. Не говоря уже о случае, когда произвольное количество контролов создаётся программно.

Подход такой:
1. Создаем свой собственный класс, в котором опишем всё желаемое, что должна делать наша надпись.
2. В каком-нибудь событии нашей формы (Open вполне подойдет) , содержащей надписи, напишем процедуру, просматривающую все контролы этой формы и для всех встретившихся надписей создающая объект нашего собственноручно написанного в п.1. класса. Эти объекты все запихиваются в какую-нибудь коллекцию и там будут храниться, пока существует наша форма.
3. Наслаждаемся.

Поехали. Начнем с формы.

Пишем в модуле нашей формы:
Option Explicit

' Наше событие Open
Private Sub Form_Open(Cancel As Integer)
Dim ctl As Control, oLbLst As LabelListener
Set cllControls = New Collection 'создаем коллекцию где будем хранить
'обработчики событий
For Each ctl In Me.Controls ' просматриваем все контролы формы
If ctl.ControlType = acLabel Then ' нужны только надписи
Set oLbLst = New LabelListener 'создаем наш объект
'самописного класса LabelListener
oLbLst.Init ctl 'вызываем событие объекта,
'обозначающее те события контрола
' которые нам приспичило обрабатывать '
cllControls.Add oLbLst 'добавляем обработчик в коллекцию
End If
Next ctl
End Sub

' Это событие формы просто восстанавливает стиль отображения
' контрола когда если мы уводим с него мышку. DataField - это имя основного раздела нашей формы.
Private Sub DataField_MouseMove(Button As Integer, Shift As Integer, X As Single, Y As Single)
On Error Resume Next
lastControl.SpecialEffect = 3
End Sub

'При выгрузке формы хотим очищать коллекцию и уничтожать ссылку на неё,
'чтобы не засирать память компа
Private Sub Form_Unload(Cancel As Integer)
Dim q As Long, i As Long
q = cllControls.Count
For i = 1 To q
cllControls.Remove 1
Next
Set cllControls =Nothing
End Sub

Далее создадим обычный модуль в котором только объявим публичные ссылки
Public lastControl As Control, cllControls As Collection
(lastControl нам нужен, чтобы восстанавливать его отображение при уводе мышки с контрола (и на lastControl и на cllControls есть ссылки и из модуля формы и из нашего самописного модуля класса))

Далее создадим модуль класса, присваиваем ему имя LabelListener и пишем в нем следующее
Option Explicit

Private WithEvents ctlMntr As Label 'объявили переменную с событиями
'типа Надпись

' Обозначаем сам факт наличия соответствующих событий контрола
' Нас интересуют события MouseDown, MouseMove и DblClick
Public Sub Init(ByRef monitorControl As Label)
Set ctlMntr = monitorControl
ctlMntr.OnMouseDown = "[Event Procedure]"
ctlMntr.OnMouseMove = "[Event Procedure]"
ctlMntr.OnDblClick = "[Event Procedure]"
End Sub

' Далее описываем сами события, обратите внимание на специфику их имен
Private Sub ctlMntr_MouseDown(Button As Integer, Shift As Integer, X As Single, Y As Single)
lastControl.SpecialEffect = 3
Set lastControl = ctlMntr
ctlMntr.SpecialEffect = 2
End Sub

Private Sub ctlMntr_MouseMove(Button As Integer, Shift As Integer, X As Single, Y As Single)
On Error Resume Next
lastControl.SpecialEffect = 3
Set lastControl = ctlMntr
ctlMntr.SpecialEffect = 1
End Sub

Private Sub ctlMntr_DblClick(Cancel As Integer)
lastControl.SpecialEffect = 3
Set lastControl = ctlMntr
ctlMntr.Caption = ctlMntr.Name
End Sub

Всё, программирование закончили. Далее в нашей форме, любым доступным нам способом создаем столько надписей, сколько хотим (в форме максимум 754 контрола можно добавить не вызывая ругательных сообщений). Для пущего эффекта пусть свойство Caption наших надписей изначально будет содержать пустую строку .

Запускаем форму, наслаждаемся, уходим на пьянку.

Цитата

Ладно, девочки, вот вам пример.

Была такая рубрика в журнале "Техника молодежи" - "Зачем просто, когда можно сложно"

Просто просто вам кажется сложно, а то, что сложно на самом деле и есть просто. Адекватный подходец должен быть, таварисчи, адекватный.

З.Ы. А еще есть такой девиз, "в жопу нищих!" Не слышали, нет?

Не оспариваю, дорогой Гость, Ваш подход. Но рекомендую прочитать первый пост топика. Автору надо было, с моей точки зрения, конкретное, и, отнюдь, не универсальное решение. Чему соответствовали (были адекватны) рекомендации практически всех товарисчей, отвечавших в пределах заданного вопроса. Если вы предложили нечто более универсальное - это Ваше право. Но оно (решение) напоминает мне попытку ввинтить массу лишних наворотов, куда ни попадя. Т.е. каждый раз разрабатывать свою операционку там, где просят простенький АРМ. Сие ИМХО, конечно.
А, так... Не хватает Вам существующих классов - делайте свои. Мериться... э-э-м... крутизной и объемом кода не намерен. Ваш подход - для Ваших задач, а мой - для моих. Если автору удалось помочь - значит сайт сделал свое доброе дело. И для меня лично совершенно не важно, кто лучше помог. Главное, что я и для себя нечто полезное получил. "Век живи - век учись...!"

ПыСы. Про жопу и нищих, пардон, не понял.

Цитата

При выгрузке формы хотим очищать коллекцию и уничтожать ссылку на неё

позволю себе добавить еще один вариант уничтожения коллекции:

Код

Set cllControls = New Collection Set cllControls = Nothing

Это сообщение отредактировал(а) likhobory - 29.11.2005, 15:53

2Papirus. Конечно, конечно, тока вопрос был про массив лэйблов, а ответы - про что-то другое, что в Access явно не работает.
Хотя, честно говоря, подкуплен Вашим умиротворяющим тоном, к которому присоединяюсь с фразой "мне ведь тоже по большому счету без разницы".
З.Ы. Про жопу и нищих - есть у меня один знакомый, контора которого торгует каким-то дорогущим немецким производственным оборудованием. У них эта поговорка относится к клиенту и примерно означает - "не можешь себе позволить - дело твоё, дорабатывай болванки напильником". Я хотел этим сказать - "если не можете себе позволить (из-за лени или еще чего) простое и надежное решение - извращайся с имеющимися заготовками".
Но всё равно-риспект всем присутствующим

Цитата

тока вопрос был про массив лэйблов,

Вопрос был... читаем тему: "Вывод имени контрола в MsgBox..." и не более того. И ответы были именно об этом. Это Ваши ответы, имхо, опять же:

Цитата

а ответы - про что-то другое

И рекомендации прекрасно работают без дополнительных наворотов...

Цитата

что в Access явно не работает.

Учите Access.

Ну а если есть желание копать ямку в цветочном горшке карьерным экскаватором... Ваше глобальное программистское право.

Цитата

"не можешь себе позволить - дело твоё, дорабатывай болванки напильником".

А на КОНКРЕТНОМ заводе при выполнении КОНКРЕТНЫХ задач вполне возможно в 10 раз надежнее, качественнее, быстрее и дешевле болванки обрабатывать именно напильником.

Вполне возможно всё.
Бог с Вами, дерзайте. Не будем устраивать перепалку.

Дерзать автору - не мне. И выбирать подходящий вариант - тоже ему.

Да уж
Главное, что есть из чего!
Всем огромное спасибо!