VPF::[Delphi] строки, процедуры, циклы - Форум программистов

Sannyore

Дата 9.3.2010, 16:19 (ссылка)

(нет голосов)

Загрузка ...

Новичок

Профиль
Группа: Участник
Сообщений: 10
Регистрация: 9.3.2010

Репутация: нет
Всего: нет

1. Обработать матрицу, элементами которой являются случайные значения функции f(x); вывести на экран исходную матрицу и полученные результаты.
Для матрицы A[1..M,1..M] найти наименьший элемент каждого столбца и поменять его местами соответствующим элементом побочной диагонали; вывести матрицу и сумму элементов побочной диагонали.
Функция: F(x)=x*x*x + 1
-8<x<9
(эту задачу сделать с помощью процедур и функций)

2. вычислить значение суммы или произведения бесконечного ряда с заданной точностью e , для всех Х изменяющихся от Х начального до Х конечного с шагом h. Правильность вычисленного выражения в точках Xi проверить с помощью аналитического выражения ряда
Х нчальное = 0,6
Х конечное = 1,5
h = 0,1
e=10 в -4 степени
Y=lnx=(x-1)-(x-1)*(x-1) / 2+(x-1)*(x-1)*(x-1) /3-...+(-1)в степени n+1 * (x-1) в степени n / n+...

3. Найти последнее вхождение заданной подстроки в строку.

пожалуйста помогите составить эти программы! Заранее благодарен!

Это сообщение отредактировал(а) Sannyore - 9.3.2010, 16:52

ИванМ

Дата 9.3.2010, 22:45 (ссылка)

(нет голосов)

Загрузка ...

Эксперт

Профиль
Группа: Завсегдатай
Сообщений: 1260
Регистрация: 19.6.2006
Где: СПб

Репутация: 13
Всего: 23

Цитата(Sannyore @ 9.3.2010, 16:19

)

3. Найти последнее вхождение заданной подстроки в строку.

стандартными функциями или придумать свою?

Sannyore

Дата 9.3.2010, 23:10 (ссылка)

(нет голосов)

Загрузка ...

Новичок

Профиль
Группа: Участник
Сообщений: 10
Регистрация: 9.3.2010

Репутация: нет
Всего: нет

да, стандартными

ИванМ

Дата 9.3.2010, 23:27 (ссылка)

(нет голосов)

Загрузка ...

Эксперт

Профиль
Группа: Завсегдатай
Сообщений: 1260
Регистрация: 19.6.2006
Где: СПб

Репутация: 13
Всего: 23

Для 3го задания (я сделал в консольном режиме):

Код


program Project1;

{$APPTYPE CONSOLE}
//подключаем нужные модули (в SysUtils - процедура writeln и readln, в StrUtils функция PosEx)
uses
  SysUtils, StrUtils;
//объявляем функцию LastPost (str - строка, в которой ищем, substr - подстрока, которую ищем)
function LastPos(str, substr: string): integer;
//локальные переменные i и j
var
  i, j: integer;
begin
  i:=1;
  j:=-1;
//бесконечный цикл
  while true do
  begin
    //ищем вхождение подстроки substr в строку str, начиная с индекса i в str
    j:=PosEx(substr, str, i);
    //если j=0, выходим из цикла 
    if j=0 then break;
    {i=j+1 - т.е. в следующей итерации цикла будем искать уже начиная c j+1 - т.е. после найденного значения в предыдущий раз}
    i:=j+1;
  end;
  //возвращаем значение = i-1 - т.е. последнее успешно найденное
  LastPos:=i-1;
end;

begin
  //выводим результат функции LastPos
  writeln(LastPos('ABCqweDEFqweRTYqweAB', 'qwe'));
  //ждем нажатия клавиши
  readln;
end.

Это сообщение отредактировал(а) ИванМ - 10.3.2010, 00:05

ИванМ

Дата 10.3.2010, 00:45 (ссылка)

(нет голосов)

Загрузка ...

Эксперт

Профиль
Группа: Завсегдатай
Сообщений: 1260
Регистрация: 19.6.2006
Где: СПб

Репутация: 13
Всего: 23

1 задача:

Код


program Project2;

{$APPTYPE CONSOLE}

uses
  SysUtils;

const
  M=5;
//тип - матрица
type
  matrix = array[1..M, 1..M] of integer;

  //функция F
function F(x: integer): integer;
begin
  F:=x*x*x + 1
end;

//заполнение матрицы случ. числами
procedure randomMatrix(var mat: matrix);
var i, j: integer;
begin
  for i:=1 to M do
  for j:=1 to M do
    //элемент матрицы = F(x), где -8<x<9
    mat[i,j]:=F(random(16)-7);
end;

//вывод матрицы
procedure outMatrix(var mat: matrix);
var i, j: integer;
begin
  for i:=1 to M do
  begin
    for j:=1 to M do
    begin
      write(mat[i, j], #9)
    end;
    writeln;
  end;
end;

//нахожение индекса минимального элемента
function minColumnIndex(var mat: matrix; col: integer): integer;
var i, minv, mini: integer;
begin
  minv:=mat[1, col];
  mini:=1;
  for i:=1 to M do
  begin
    if (mat[i, col]<minv) then
    begin
      minv:=mat[i, col];
      mini:=i;
    end;
  end;
  Result:=mini;
end;

//перемена местами минимального элемента и элемента побочной диагонали
procedure replace(var mat: matrix);
var
  i, ind, diagind, temp: integer;
begin
  for i:=1 to M do
  begin
    ind:=minColumnIndex(mat, i);
    diagind:=(M-i+1);
    temp:=mat[ind, i];
    mat[ind, i]:=mat[diagind, i];
    mat[diagind, i]:=temp;
  end;
end;

//сумма жлементов побочной диагонали
function sum(var mat: matrix): integer;
var
  i: integer;
begin
  Result:=0;
  for i:=1 to M do
  begin
    inc(Result, mat[(M-i+1), i]);
  end;
end;

var
  matr: matrix;
begin
//инициация генератора случю чисел
  randomize;
//запонение матрицы случ. числами
  randomMatrix(matr);
//вывод исходной матрицы
  outMatrix(matr);
//перемена мест элементов
  replace(matr);
//вывод обработанной матрицы
  writeln('New matrix:');
  outMatrix(matr);
//вывод суммы элементов побочной диагонали
  writeln('Sum of diagonal elements:');
  writeln(sum(matr));
//ждать нажатия клавиши
  readln;
end.

0 Пользователей читают эту тему (0 Гостей и 0 Скрытых Пользователей)
0 Пользователей:
« Предыдущая тема \| Центр помощи \| Следующая тема »