Модераторы: SoWa
  

Поиск:

Ответ в темуСоздание новой темы Создание опроса
> флеш галерии, нужен хелп 
:(
    Опции темы
palec
Дата 19.5.2005, 05:31 (ссылка) | (голосов: 0) Загрузка ... Загрузка ... Быстрая цитата Цитата


Unregistered
вопрос такой: может кто нить знает как создавать флешь галереи, они же флешь+хмл.
для примера сайт http://www.myflashxml.com
может кто нить делал что то подобное и поможет мне, или возможно кто нить знает где можно такое скачать.
буду сильно признателен.
с уважением палец!!!
  Вверх
AntonioBanderaz
Дата 19.5.2005, 12:56 (ссылка) | (нет голосов) Загрузка ... Загрузка ... Быстрая цитата Цитата


Velichko Anton
**


Профиль
Группа: Участник
Сообщений: 851
Регистрация: 28.4.2005
Где: Санкт-Петербург

Репутация: 1
Всего: 18
Да ничего сложного =)
1. Подключаешь и парсишь XML
2. Размножаешь мувики(рамки для фоток).
3. Грузишь туда картинки, с процентной подгрузкой конечно...
4. Добовляешь всякую анимашку
5. Делишь на страницы.

Вот например так:

ActionScript:

Код

import mx.transitions.*;

_global.thisX = 30;
_global.thisY = 30;

_global.stageWidth = 630;
_global.stageHeight = 430;

var gallery_xml:XML = new XML();
gallery_xml.ignoreWhite = true;
gallery_xml.onLoad = function(success:Boolean) {
    try {
        if (success) {
            var images:Array = this.firstChild.childNodes;
            var gallery_array:Array = new Array();
            for (var i = 0; i<images.length; i++) {
                gallery_array.push({src:images[i].firstChild.nodeValue});
            }
            displayGallery(gallery_array);
        } else {
            throw new Error("Unable to parse XML");
        }
    } catch (e_err:Error) {
        trace(e_err.message);
    } finally {
        delete this;
    }
};

gallery_xml.load("gallery_tween.xml");

function displayGallery(gallery_array:Array) {
    var galleryLength:Number = gallery_array.length;
    for (var i = 0; i<galleryLength; i++) {
        var thisMC:MovieClip = this.createEmptyMovieClip("image"+i+"_mc", i);
        mcLoader_mcl.loadClip(gallery_array[i].src, thisMC);
        preloaderMC = this.attachMovie("preloader_mc", "preloader"+i+"_mc", 5000+i);
        preloaderMC.bar_mc._xscale = 0;
        preloaderMC.progress_txt.text = "0%";
        thisMC._x = _global.thisX;
        thisMC._y = _global.thisY;
        preloaderMC._x = _global.thisX;
        preloaderMC._y = _global.thisY+20;
        if ((i+1)%5 == 0) {
            _global.thisX = 20;
            _global.thisY += 80;
        } else {
            _global.thisX += 80+20;
        }
    }
}

var mcLoader_mcl:MovieClipLoader = new MovieClipLoader();
var mclListener:Object = new Object();
mclListener.onLoadStart = function() {
};
mclListener.onLoadProgress = function(target_mc, loadedBytes, totalBytes) {
    var pctLoaded:Number = Math.round(loadedBytes/totalBytes*100);
    var preloaderMC = target_mc._parent["preloader"+target_mc.getDepth()+"_mc"];
    preloaderMC.bar_mc._xscale = pctLoaded;
    preloaderMC.progress_txt.text = pctLoaded+"%";
};
mclListener.onLoadInit = function(evt:MovieClip) {
    evt._parent["preloader"+evt.getDepth()+"_mc"].removeMovieClip();
    var thisWidth:Number = evt._width;
    var thisHeight:Number = evt._height;
    var borderWidth:Number = 2;
    var marginWidth:Number = 8;
    evt.scale = 20;
    evt.lineStyle(borderWidth, 0x000000, 100);
    evt.beginFill(0xFFFFFF, 100);
    evt.moveTo(-borderWidth-marginWidth, -borderWidth-marginWidth);
    evt.lineTo(thisWidth+borderWidth+marginWidth, -borderWidth-marginWidth);
    evt.lineTo(thisWidth+borderWidth+marginWidth, thisHeight+borderWidth+marginWidth);
    evt.lineTo(-borderWidth-marginWidth, thisHeight+borderWidth+marginWidth);
    evt.lineTo(-borderWidth-marginWidth, -borderWidth-marginWidth);
    evt.endFill();
    evt._xscale = evt.scale;
    evt._yscale = evt.scale;
    evt._rotation = Math.round(Math.random()*-10)+5;
    evt.onPress = function() {
        this.startDrag();
        this._xscale = 100;
        this._yscale = 100;
        this.origX = this._x;
        this.origY = this._y;
        this.origDepth = this.getDepth();
        this.swapDepths(this._parent.getNextHighestDepth());
        this._x = (_global.stageWidth-evt._width+30)/2;
        this._y = (_global.stageHeight-evt._height+30)/2;
        mx.transitions.TransitionManager.start(this, {type:mx.transitions.Photo, direction:0, duration:1, easing:mx.transitions.easing.Strong.easeOut, param1:empty, param2:empty});
    };
    evt.onRelease = function() {
        this.stopDrag();
        this._xscale = this.scale;
        this._yscale = this.scale;
        this._x = this.origX;
        this._y = this.origY;
    };
    evt.onReleaseOutside = evt.onRelease;
};
mcLoader_mcl.addListener(mclListener);


Вот XML:

Код

<?xml version="1.0"?>
<gallery>
    <img><![CDATA[DCP_0730.jpg]]></img>
    <img><![CDATA[DCP_0731.jpg]]></img>
    <img><![CDATA[DCP_0732.jpg]]></img>
    <img><![CDATA[DCP_0733.jpg]]></img>
    <img><![CDATA[DCP_0734.jpg]]></img>
    <img><![CDATA[DCP_0735.jpg]]></img>
    <img><![CDATA[DCP_0736.jpg]]></img>
    <img><![CDATA[DCP_0737.jpg]]></img>
    <img><![CDATA[DCP_0738.jpg]]></img>
    <img><![CDATA[DCP_0739.jpg]]></img>
    <img><![CDATA[DCP_0740.jpg]]></img>
    <img><![CDATA[DCP_0741.jpg]]></img>
    <img><![CDATA[DCP_0742.jpg]]></img>
    <img><![CDATA[DCP_0743.jpg]]></img>
    <img><![CDATA[DCP_0744.jpg]]></img>
    <img><![CDATA[DCP_0745.jpg]]></img>
    <img><![CDATA[DCP_0746.jpg]]></img>
    <img><![CDATA[DCP_0747.jpg]]></img>
</gallery>


А вот и сам проектик smile smile smile


--------------------
ГЫ... 
PM MAIL ICQ   Вверх
Rollband
Дата 19.5.2005, 21:06 (ссылка) | (нет голосов) Загрузка ... Загрузка ... Быстрая цитата Цитата


Шустрый
*


Профиль
Группа: Участник
Сообщений: 53
Регистрация: 28.3.2005
Где: Германия

Репутация: нет
Всего: нет
AntonioBanderaz
У тебя внутри архива названия файлов кириллицой?
Любопытно взглянуть smile , а то мой немецкий винт ошибку формата выдаёт.
PM MAIL   Вверх
AntonioBanderaz
Дата 19.5.2005, 23:34 (ссылка) | (нет голосов) Загрузка ... Загрузка ... Быстрая цитата Цитата


Velichko Anton
**


Профиль
Группа: Участник
Сообщений: 851
Регистрация: 28.4.2005
Где: Санкт-Петербург

Репутация: 1
Всего: 18
Вот так попробуй, я только без картинок и xml... Проэктик


--------------------
ГЫ... 
PM MAIL ICQ   Вверх
Rollband
Дата 21.5.2005, 02:24 (ссылка) | (нет голосов) Загрузка ... Загрузка ... Быстрая цитата Цитата


Шустрый
*


Профиль
Группа: Участник
Сообщений: 53
Регистрация: 28.3.2005
Где: Германия

Репутация: нет
Всего: нет
Ни фига не читает. "Ошибка носителя при прочтении" - в переводе на русский.
Но я уже с кодом разобрался, что ты дал. Всё ясно. Лучше картинки через .xml или через .txt наводить? Есть разница?
PM MAIL   Вверх
AlDev
Дата 21.5.2005, 05:31 (ссылка) | (нет голосов) Загрузка ... Загрузка ... Быстрая цитата Цитата


Опытный идиотъ
***


Профиль
Группа: Участник Клуба
Сообщений: 1927
Регистрация: 17.4.2005
Где: Irk, rus

Репутация: 9
Всего: 50
удобнее через xml
PM MAIL WWW ICQ YIM MSN   Вверх
Rollband
Дата 21.5.2005, 23:18 (ссылка) | (нет голосов) Загрузка ... Загрузка ... Быстрая цитата Цитата


Шустрый
*


Профиль
Группа: Участник
Сообщений: 53
Регистрация: 28.3.2005
Где: Германия

Репутация: нет
Всего: нет
Извини за наглость. Где ещё можно подобные галлерии надыбить?
PM MAIL   Вверх
AntonioBanderaz
Дата 22.5.2005, 11:49 (ссылка) | (нет голосов) Загрузка ... Загрузка ... Быстрая цитата Цитата


Velichko Anton
**


Профиль
Группа: Участник
Сообщений: 851
Регистрация: 28.4.2005
Где: Санкт-Петербург

Репутация: 1
Всего: 18
Сам напиши, если понял =))) Что Тебя именно интересует?


--------------------
ГЫ... 
PM MAIL ICQ   Вверх
AntonioBanderaz
Дата 22.5.2005, 13:20 (ссылка) | (нет голосов) Загрузка ... Загрузка ... Быстрая цитата Цитата


Velichko Anton
**


Профиль
Группа: Участник
Сообщений: 851
Регистрация: 28.4.2005
Где: Санкт-Петербург

Репутация: 1
Всего: 18
Можешь посмотреть, я помнится выкладывал в каком-то топе, галерейку, только она не доделаная, там тебе ещё XML надо подключать... Топ


--------------------
ГЫ... 
PM MAIL ICQ   Вверх
AlDev
Дата 22.5.2005, 14:13 (ссылка) | (нет голосов) Загрузка ... Загрузка ... Быстрая цитата Цитата


Опытный идиотъ
***


Профиль
Группа: Участник Клуба
Сообщений: 1927
Регистрация: 17.4.2005
Где: Irk, rus

Репутация: 9
Всего: 50
2AntonioBanderaz
Код

<gallery>
...
    <img><![CDATA[DCP_0747.jpg]]></img>
</gallery>

А зачем cdata?
Код

<?xml version='1.0'?>
<gallery>
  <img src='DCP_0747.jpg'/>
</gallery>
PM MAIL WWW ICQ YIM MSN   Вверх
Rollband
Дата 22.5.2005, 16:33 (ссылка) | (нет голосов) Загрузка ... Загрузка ... Быстрая цитата Цитата


Шустрый
*


Профиль
Группа: Участник
Сообщений: 53
Регистрация: 28.3.2005
Где: Германия

Репутация: нет
Всего: нет
AntonioBanderaz
Посмотрел. Директорию к картинкам изменил, на локальные. Открывает миниатюры и всё.
Хочет "lmc_tween.as". Что это значит?
PM MAIL   Вверх
AntonioBanderaz
Дата 23.5.2005, 02:25 (ссылка) | (нет голосов) Загрузка ... Загрузка ... Быстрая цитата Цитата


Velichko Anton
**


Профиль
Группа: Участник
Сообщений: 851
Регистрация: 28.4.2005
Где: Санкт-Петербург

Репутация: 1
Всего: 18
Rollband Там для flesha лежит файлик MXP...

Alex Batsuev Ну да, не нужен...


--------------------
ГЫ... 
PM MAIL ICQ   Вверх
  
 Ответ в темуСоздание новой темы Создание опроса
Правила форума "Flash"
AlDev
SoWa
  • Если вы хотите предложить кому-либо работу, то пишите или в личку, или оставляйте сообщения в специально предназначеном для этого форуме "Объявления о найме специалистов"
  • Один вопрос - одна тема. Не надо переходов от одного вопроса к другому.
  • Если вы хотите показать какой-нибудь ваш мульт, причём показать, а не предоставить исходник, то вам сюда
  • Вопросы про программирование на ActionScript 1,2 (Flash 8 и более ранние версии) пишите в форуме ActionScript 1,2
  • Вопросы по разработке интернет-приложений на Flex и вопросы по MXML пишите в раздел Flex
  • Смотрим в будущее. ActionScript 3 обсуждается в форуме ActionScript 3
  • Новости из мира Flash.
  • New! [code=ascript][/code] - подсветка ActionScript + wikipedia help

Если Вам понравилась атмосфера форума, заходите к нам чаще! С уважением, AlDev, SoWa.
 
1 Пользователей читают эту тему (1 Гостей и 0 Скрытых Пользователей)
0 Пользователей:
« Предыдущая тема | Flash | Следующая тема »

Подписаться на тему | Подписка на этот форум | Скачать/Распечатать тему


 




[ Время генерации скрипта: 0.0891 ]   [ Использовано запросов: 21 ]   [ GZIP включён ]


Реклама на сайте     Информационное спонсорство

 
 По вопросам размещения рекламы пишите на vladimir(sobaka)vingrad.ru
Отказ от ответственности     Powered by Invision Power Board(R) 1.3 © 2003  IPS, Inc.