VPF::REG_MULTI_SZ - Форум программистов

Basя

Дата 7.4.2003, 12:09 (ссылка)

(голосов: 0)

Загрузка ...

Unregistered

Привет!
Как считать из реестра REG_MULTI_SZ?
Спасибо!

stab

Дата 7.4.2003, 17:43 (ссылка)

(нет голосов)

Загрузка ...

Эксперт

Профиль
Группа: Экс. модератор
Сообщений: 1839
Регистрация: 1.1.2003

Репутация: 14
Всего: 48

может TRegistry подойдет

--------------------

6, 6, 6 - the number of the beast.

Basя

Дата 7.4.2003, 19:34 (ссылка)

(голосов: 0)

Загрузка ...

Unregistered

Может и подойдет, но я не знаю как.

((((((((

Pakshin A. S.

Дата 7.4.2003, 20:14 (ссылка)

(нет голосов)

Загрузка ...

Эксперт

Профиль
Группа: Участник Клуба
Сообщений: 5056
Регистрация: 16.2.2003

Репутация: 21
Всего: 61

Всё о TRegisty можно узнать либо из Helpa, либо щёлкнув по нему с нажатой клавишей Ctrl кнопкой мыши, только добавь uses Registry;, там всё описание процедур и типов, жаль без коментариев.

Alex

Дата 8.4.2003, 07:22 (ссылка)

(нет голосов)

Загрузка ...

Эксперт

Профиль
Группа: Экс. модератор
Сообщений: 4147
Регистрация: 25.3.2002
Где: Москва

Репутация: 80
Всего: 162

Код


uses Types;

function RegReadMultiStr(Rkey: HKEY; Key: String; Param: String): String;
// Чтение мульти строк из реестра
// В случаи ошибки функция возвращает пустую строку
var
  r: TRegistry;
  tmp: array[0..4095] of Char;
  len, i, n: Integer;
  tmpStr: String;
  tmpResult: TStringDynArray;
begin
  Result:= '';
  SetLength(tmpResult, 0);
  r:= TRegistry.Create;
  n:= 0;
  try
    try
      r.RootKey:= Rkey;
      r.OpenKeyReadOnly(Key);
      if not r.ValueExists(Param) then exit;
      if r.GetDataType(Param) <> rdUnknown then exit; // Не мульти строка
      r.ReadBinaryData(Param, tmp, SizeOf(tmp));
      len:= r.GetDataSize(Param);
      for i:= 0 to len-2 do begin
        if tmp[i]<> #0 then
          tmpStr:= tmpStr + CharStr(tmp[i], 1)
        else begin
          SetLength(tmpResult, Length(tmpResult)+1);
          tmpResult[n]:= tmpStr;
          Inc(n);
          tmpStr:= '';
        end;
      end;
      Result:= DelimitedText(tmpResult);
    except on ERegistryException do
      Exit;
    end;
  finally
    FreeAndNil(r);
  end;
end;

--------------------

Написать можно все - главное четко представлять, что ты хочешь получить в конце.

stab

Дата 11.4.2003, 16:00 (ссылка)

(нет голосов)

Загрузка ...

Эксперт

Профиль
Группа: Экс. модератор
Сообщений: 1839
Регистрация: 1.1.2003

Репутация: 14
Всего: 48

я б лучше так сделал:

Код



unit RegistryEx;

interface

uses Windows, Classes, Registry;

type

  TRegistryEx = class(TRegistry)
  public
    procedure ReadStrings(const Name: String; List: TStrings);
    procedure WriteStrings(const Name: String; List: TStrings);
  end;


implementation

uses RTLConsts;

{ TRegistryEx }

procedure TRegistryEx.ReadStrings(const Name: String; List: TStrings);
var
  Data: String;
  Info: TRegDataInfo;
  i: Integer;
begin
  if GetDataInfo(Name, Info) then begin
    if Info.DataSize <> 0 then begin
      SetLength(Data, Info.DataSize);
      ReadBinaryData(Name, Pointer(Data)^, Info.DataSize);
      SetLength(Data, Info.DataSize - 2);
      for i := 1 to Length(Data) do
        if Data[i] = #0 then Data[i] := #13;
      List.Text := Data;
    end
    else
      List.Text := '';
  end
  else
    List.Text := '';
end;

procedure TRegistryEx.WriteStrings(const Name: String; List: TStrings);
var
  i: Integer;
  Data: String;
begin
  Data := '';
  for i := 0 to List.Count - 1 do
    Data := Data + List[i] + #13;
  if Data = '' then
    Data := #13#13
  else
    Data := Data + #13;
  for i := 1 to Length(Data) do
    if Data[i] = #13 then Data[i] := #0;

  if RegSetValueEx(CurrentKey, PChar(Name), 0, REG_MULTI_SZ, Pointer(Data), Length(Data)) <> ERROR_SUCCESS then
    raise ERegistryException.CreateResFmt(@SRegSetDataFailed, [Name]);
end;

end.

--------------------

6, 6, 6 - the number of the beast.

stab

Дата 11.4.2003, 16:03 (ссылка)

(нет голосов)

Загрузка ...

Эксперт

Профиль
Группа: Экс. модератор
Сообщений: 1839
Регистрация: 1.1.2003

Репутация: 14
Всего: 48

И использовал бы так:

Код




uses RegistryEx;

var
  reg: TRegistryEx;
begin
  reg := TRegistryEx.Create;

  ...

  reg.ReadStrings('Value1', Memo1.Lines);

  ...

  reg.WriteStrings('Value2', ListBox2.Items);

  ...

  reg.Free;
end;

--------------------

6, 6, 6 - the number of the beast.

0 Пользователей читают эту тему (0 Гостей и 0 Скрытых Пользователей)
0 Пользователей:
« Предыдущая тема \| Delphi: Общие вопросы \| Следующая тема »